motor joint

昨天我们学习了 Box2D 的"距离关节"b2DistanceJoint ，并用它模拟了一个简单的自行车。今天我们来学习"马达关节" b2RevoluteJoint 。

"马达关节"b2RevoluteJoint同样连接了两个刚体bodyA和bodyB。不过和"马达关节"不同的是，它只有一个节点anchor，所以两个刚体都只能围绕这一个节点选择。另外，我们可以在这个节点anchor位置施加一个作用力maxMotorTorque，这样节点就会想马达一样转起来，所以我把它叫做"马达关节"。

还是不好理解，对吧！那就再打个比方，我把b2RevoluteJoint关节比作....电风扇。风扇叶是bodyA，马达是anchor，底座是bodyB，下面的图可以更好的解释这一点：

 
如上图所示，因为节点anchor在bodyA的圆心处，所以bodyA会围绕着节点anchor旋转。

b2RevoluteJoint的initialize方法结构如下：

1.     public function Initialize(
   
2.         bA:b2Body,
   
3.         bB:b2Body,
   
4.         anchor:b2Vec2
   
5.     ) : void

复制代码

bA即bodyA，bB即bodyB，anchor即节点，具体的功能，我在前面都讲过了，就不再赘述了。
另外，如前面提到的，通过设置b2RevoluteJointDef的maxMotorTorque、motorSpeed和enableMotor，可以模拟马达旋转。这三个参数的作用分别如下：

• enableMotor：决定是否使用
• motormotorSpeed：设置最大的角速度
• maxMotorTorque：要达到角速度应用的扭矩力这三个属性是让节点转起来的必要条件，缺一不可！记住哦。
  

用b2RevoluteJoint实现风扇的效果如下：

完整的代码和注释如下：

1. package
   
2. {
   
3.     import Box2D.Collision.Shapes.b2PolygonShape;
   
4.     import Box2D.Collision.Shapes.b2Shape;
   
5.     import Box2D.Common.Math.b2Vec2;
   
6.     import Box2D.Dynamics.b2Body;
   
7.     import Box2D.Dynamics.b2BodyDef;
   
8.     import Box2D.Dynamics.b2FixtureDef;
   
9.     import Box2D.Dynamics.b2World;
   
10.     import Box2D.Dynamics.Joints.b2RevoluteJoint;
    
11.     import Box2D.Dynamics.Joints.b2RevoluteJointDef;
    
12.     import flash.display.Sprite;
    
13.     import flash.events.Event;
    
14.     import flash.events.MouseEvent;
    
15.     import flash.geom.Point;
    
16. 
    
17.     /**
    
18.      * http://www.ladeng6666.com
    
19.      * @author ladeng6666
    
20.      */
    
21.     public class RevoluteJointTest extends Sprite
    
22.     {
    
23.         private var world:b2World;
    
24.         private var debugSprite:Sprite;
    
25.         private var bodyA:b2Body, bodyB:b2Body;
    
26.         private var posA:Point, posB:Point;
    
27. 
    
28.         public function RevoluteJointTest()
    
29.         {
    
30.             LDEasyBox2D.stage = stage;
    
31.             world=LDEasyBox2D.createWorld();
    
32.             debugSprite=LDEasyBox2D.createDebug(world);
    
33.             addChild(debugSprite);
    
34. 
    
35.             //创建地面，
    
36.             LDEasyBox2D.createWrapWall(world, stage);
    
37.             createBodies();
    
38. 
    
39.             createRevoluteJoint();
    
40. 
    
41.             addEventListener(Event.ENTER_FRAME, loop);
    
42.             stage.addEventListener(MouseEvent.MOUSE_DOWN, onStageMouseDown);
    
43.             stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
    
44.         }
    
45. 
    
46.         private function createRevoluteJoint():void
    
47.         {
    
48.             //创建马达关节需求
    
49.             var revoluteJoint:b2RevoluteJointDef = new b2RevoluteJointDef();
    
50.             //用bodyA、bodyB和anchor节点初始化马达关节
    
51.             revoluteJoint.Initialize( bodyA, bodyB, new b2Vec2(posA.x / 30, posA.y / 30));
    
52.             //设置连接的两个刚体之间不进行碰撞检测
    
53.             revoluteJoint.collideConnected = false;
    
54.             //开启马达
    
55.             revoluteJoint.enableMotor = true;
    
56.             //设置马达的最大角速度，单位为 弧度/秒，如设置为Math.PI，即每秒钟转180度
    
57.             revoluteJoint.motorSpeed = Math.PI;
    
58.             //设置最大的扭力值
    
59.             revoluteJoint.maxMotorTorque = 500;
    
60.             //创建马达关节
    
61.             world.CreateJoint(revoluteJoint);
    
62.         }
    
63.         //创建bodyA和bodyB刚体
    
64.         private function createBodies():void
    
65.         {
    
66.             //设置两个刚体的坐标位置
    
67.             posA = new Point(275, 100);
    
68.             posB = new Point(275, 300);
    
69.             //创建一个十字刚体，赋值给bodyA
    
70.             var bodyDef:b2BodyDef = new b2BodyDef();
    
71.             bodyDef.type = b2Body.b2_dynamicBody;
    
72.             bodyDef.position.Set(posA.x / 30, posA.y / 30);
    
73.             bodyA = world.CreateBody(bodyDef);
    
74.             //设置刚体属性
    
75.             var fixtureDef:b2FixtureDef = new b2FixtureDef();
    
76.             fixtureDef.density = 3;
    
77.             fixtureDef.restitution = .2;
    
78.             fixtureDef.friction = .2;
    
79. 
    
80.             //设置刚体形状，并赋值给fixtureDef
    
81.             //一个横着的矩形
    
82.             var shape:b2PolygonShape = new b2PolygonShape();
    
83.             shape.SetAsBox(50/30, 5/30);
    
84.             fixtureDef.shape = shape;
    
85.             bodyA.CreateFixture(fixtureDef);
    
86.             //加一个竖着的矩形
    
87.             shape.SetAsBox(5 / 30, 50 / 30);
    
88.             fixtureDef.shape = shape;
    
89.             //生成刚体bodyA的形状
    
90.             bodyA.CreateFixture(fixtureDef);
    
91. 
    
92.             //创建bodyB刚体
    
93.             bodyB = LDEasyBox2D.createBox(world, posB.x, posB.y, 200, 50);
    
94.         }
    
95. 
    
96.         private function onStageMouseDown(e:MouseEvent):void
    
97.         {
    
98.             var dragBody:b2Body = LDEasyBox2D.getBodyAtMouse(world);
    
99.             if (dragBody != null) {
    
100.                 LDEasyBox2D.startDragBody(world,dragBody,10000*dragBody.GetMass());
     
101.             }
     
102. 
     
103.         }
     
104. 
     
105.         private function onStageMouseUp(e:MouseEvent):void
     
106.         {
     
107.             LDEasyBox2D.stopDragBody(world);
     
108.         }
     
109. 
     
110.         private function loop(e:Event):void
     
111.         {
     
112.             LDEasyBox2D.updateWorld(world);
     
113. 
     
114.         }
     
115. 
     
116.     }
     
117. 
     
118. }

复制代码

代码中用到了我写的静态类LDEasyBox2D，可以有效的简化代码，具体请参考 这里 。

点击刚体，还可以进行拖动，如果对鼠标拖动刚体，我建议你看看之前的 让刚体听我的——鼠标拖动刚体 。  OK 2012-08-28 b2RevoluteJoint关节.rar (340.1 KB, 下载次数: 106)