前言
本文是基于B站上的《SCL核心应用课项目实战》课程,所做的笔记,主要包括程序代码和自己的理解注释。课程链接:SCL核心应用课项目实战(21课全)
陆杰锋老师讲得非常好,有理论讲解也有实战演练,需要具备一定的梯形图编程基础。
有空我会持续更新。
十五、1200PLC与串口设备自由通讯
1.需求分析
功能要求:
本系统下位机系统控制核心部分采用西门子S7-1200系列CPU,扩展1个RS232模块和一个RS485模块用于扫码枪设备及空调主板的通讯,依托本身的I/O模块处理逻辑动作,扩展AI模块用于采集外围温湿度传感器数据,扩展A0模块用于模拟温度;上位机采用VS2015平台进行开发,通过上位机系统控制系统的启停,监控当前检测结果,完成数据的归档功能,并支持查询、导出等功能。系统示意图如下图所示:
分析:
1.主控制器由1200PLC组成,外接两个通讯模块,一个232串口,一个485串口,232接扫码枪,485接空调;
2.串口通讯传递到PLC中的形式是字符Char;
3.上位机用于对采集到的数据进行监控和归档;
4.本例程主要完成:自由通讯、数据Char转String、Socket通讯发送给上位机等步骤;
5.串口通讯负责被动接收串口上的信息;
6.TCP通讯用于将接收到的数据发送给上位机。
2.程序编写
编程步骤:
1.组态硬件;
注意硬件标识符,编程时要用到。
2.新建一个DB块“通信”;
添加一个数组变量,数据类型为Char,作为接收存储区。
3.新建一个FB块“串口通信”;
添加Receive_P2P指令。
//PtP通信
#RCV("PORT":=267, //属性-系统常数-硬件标识符
BUFFER:="通信".RCV); //接收存储区
注意:下一次接收到的字符串不会把上一次接收到的字符串完全清空。比如上一次接收到20个字符,下一次接收到8个字符,则只会覆盖掉前8个字符,后面存储的数据不会清空。
4.将采集到的数据提取出来;
使用Chars_TO_Strg指令将接收到的字符转换成字符串,通过上一步用到的Receive_P2P指令的输出引脚NDR触发转换命令。
注意:不支持转换中文。
在DB块“通信”中添加如下变量:
编写如下程序:
IF #RCV.NDR THEN //接收完成信号,当收到字符时,会接通一个扫描周期
Chars_TO_Strg(Chars := "通信".RCV,
pChars := 0, //从第几个字符开始转换
Cnt := #RCV.LENGTH, //要转换多少个字符(收到多少字符转换多少字符)
Strg => "通信".RCV_STR); //将字符串传递给新的变量
END_IF;
5.利用开放式用户通信,将接收到的数据传递给上位机;
PLC是主站,主动给上位机发送数据,调用TSEND_C指令,可选择“多重实例”。
然后进行组态,
//开放式用户通信
#TCP_SEND(CONNECT := "PLC_1_Send_DB",
DATA := "通信".RCV,
CONT := TRUE,
LEN := #RCV.LENGTH,
REQ := #RCV.NDR);
6.程序拓展,将字符串转换为数值;
在DB块“通信”中添加如下变量:
调用STRG_VEL指令,编写如下程序:
//将字符串转换为数值
STRG_VAL(IN := "通信".RCV_STR,
FORMAT := 0,//0或1表示小数格式
P := 1,//从第几位开始转换
OUT => "通信".RCV_DINT);
//将字符串转换为数值
STRG_VAL(IN := "通信".RCV_STR,
FORMAT := 1,
P := 1,
OUT => "通信".RCV_REAL);
7.完整程序如下:
//PtP通信
#RCV("PORT":=267, //属性-系统常数-硬件标识符
BUFFER:="通信".RCV); //接收存储区
//将字符转换为字符串
IF #RCV.NDR THEN //接收完成信号,当收到字符时,会接通一个扫描周期
Chars_TO_Strg(Chars := "通信".RCV,
pChars := 0, //从第几个字符开始转换
Cnt := #RCV.LENGTH, //要转换多少个字符(收到多少字符转换多少字符)
Strg => "通信".RCV_STR); //将字符串传递给新的变量
//将字符串转换为数值
STRG_VAL(IN := "通信".RCV_STR,
FORMAT := 0,//0或1表示小数格式
P := 1,//从第几位开始转换
OUT => "通信".RCV_DINT);
//将字符串转换为数值
STRG_VAL(IN := "通信".RCV_STR,
FORMAT := 1,
P := 1,
OUT => "通信".RCV_REAL);
END_IF;
//开放式用户通信
#TCP_SEND(CONNECT := "PLC_1_Send_DB",
DATA := "通信".RCV,
CONT := TRUE,
LEN := #RCV.LENGTH,
REQ := #RCV.NDR);
8.在主程序块Main中,调用FB块“串口通信”。
总结
关于SCL核心应用课项目实战(21课全)的全部笔记已更新完毕,我省略了部分内容,总结了大部分项目的分析思路和程序代码,感谢各位大佬批评指正!