FPGA学习专栏-串口通信（xinlinx）

最新推荐文章于 2024-05-31 09:00:00 发布
最新推荐文章于 2024-05-31 09:00:00 发布
阅读量2k 收藏 27
点赞数 1
分类专栏： FPGA 文章标签： fpga开发 学习
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_51390088/article/details/126228195
版权

FPGA学习专栏-串口通信

本系列文章基于开发板黑金A309，FPGA芯片为Xilinx公司的spartan6，本系列文章记录FPGA学习历程。

文章目录

一、串口通信原理

通用异步收发传输器，通常称为UART。本文采用的是RS232接口标准。串口通信原理在网上很容易搜到，串口通信是双机通信中最先学到的通信方式，是异步串行通信。
串口通信的连接图如下所示：
在这里插入图片描述
串行通信中消息桢组成为：
在这里插入图片描述
本实验传输不用校验位。
串行通信中，波特率非常重要，是数据能否正确传输的重要保障，波特率即一秒钟传输多少字。本文选用波特率为115200。
波特率相当于异步串行通信中的时基单元，所以非常重要。

二、硬件设计

硬件上，AX309采用了USB转串口芯片CP2102。
在这里插入图片描述

三、verilog代码编写

1.发送模块

采用状态转移图方式编写代码，发送模块的状态转换图如下所示：
在这里插入图片描述

发送模块的方框图如下：
在这里插入图片描述

module uart_tx
#(
		parameter	CLK_FRE		= 50,
		parameter	BAUD_RATE	= 115200
)
(
	input		clk,
	input		rst,
	input[7:0]	tx_data,//发送数据
	input		tx_data_valid,//发送数据有效标志
	
	output		tx_pin,
	output	reg	tx_data_ready
);
localparam		CYCLE = CLK_FRE * 1000000/BAUD_RATE;

localparam		S_IDLE		= 1;
localparam		S_START		= 2;
localparam		S_SEND_BYTE	= 3;
localparam		S_STOP		= 4;

reg[2:0]		state;
reg[2:0]		next_state;
reg[15:0]		cycle_cnt;
reg[2:0]		bit_cnt;
reg[7:0]		tx_data_latch;
reg				tx_reg;

assign	tx_pin = tx_reg;

always@(posedge clk or negedge rst)
begin
	if(rst == 1'b0)
		state <= S_IDLE;
	else
		state <= next_state;
end
//状态转移
always@(*)
begin
	case(state)
		S_IDLE:
			if(tx_data_valid == 1'b1)
				next_state <= S_START;
			else
				next_state <= S_IDLE;
		
		S_START:
			if(cycle_cnt == CYCLE-1)
				next_state <= S_SEND_BYTE;
			else
				next_state <= S_START;
		S_SEND_BYTE:
			if(cycle_cnt == CYCLE-1 && bit_cnt == 3'd7)
				next_state <= S_STOP;
			else
				next_state <= S_SEND_BYTE;
		S_STOP:
			if(cycle_cnt == CYCLE-1)
				next_state <= S_IDLE;
			else
				next_state <= S_STOP;
		default:next_state <= S_IDLE;
	endcase
end
//发送标志位
always@(posedge clk or negedge rst)
begin
	if(rst == 1'b0)
		tx_data_ready <= 1'b0;
	else if(state == S_IDLE)
		if(tx_data_valid == 1'b1)
			tx_data_ready <= 1'b0;
		else
			tx_data_ready <= 1'b1;
	else if(state == S_STOP && cycle_cnt == CYCLE-1)
		tx_data_ready <= 1'b1;
end

always@(posedge clk or negedge rst)
begin
	if(rst == 1'b0)
		tx_data_latch <= 8'd0;
	else if(state == S_IDLE && tx_data_valid == 1'b1)
		tx_data_latch <= tx_data;
end


//数据输出
always@(posedge clk or negedge rst)
begin
	if(rst == 1'b0)
		tx_reg <= 1'b0;
	else 
		case(state)
			S_IDLE,S_STOP:
					tx_reg <= 1'b1;
			S_START:
					tx_reg <= 1'b0;
			S_SEND_BYTE:
					tx_reg <= tx_data_latch[bit_cnt];
			default:
				tx_reg <= 1'b1;
		endcase
end
//比特位计数
always@(posedge clk or negedge rst)
begin 
if(rst == 1'b0)
	bit_cnt <= 3'd0;
else if(state == S_SEND_BYTE)
	if(cycle_cnt == CYCLE-1)
		bit_cnt <= bit_cnt +1'b1;
	else
		bit_cnt <= bit_cnt;
else
	bit_cnt <= 3'd0;
end
//波特率计数
always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	cycle_cnt <= 16'd0;
else if((state == S_SEND_BYTE && cycle_cnt == CYCLE-1)|| next_state != state)
	cycle_cnt <= 16'd0;
else
	cycle_cnt <= cycle_cnt + 16'd1;
end

endmodule

modelsim仿真

发送模块仿真波形图，如下所示：
在这里插入图片描述

2.接收模块

接收模块的状态转换图：
在这里插入图片描述

接收模块的方框图：
在这里插入图片描述

module uart_rx
#(
	parameter	CLK_FRE	=	50,
	parameter	BAUD_RATE = 115200
)
(
	input				clk,
	input				rst,
	input				rx_pin,
	input				rx_ready,
	
	output	reg		rx_valid,
	output	reg[7:0]	rx_data
	);
	
localparam	CYCLE = (CLK_FRE * 1000000)/BAUD_RATE;

localparam	S_IDLE 		= 0;
localparam	S_START		= 1;
localparam	S_RX_CYCLE 	= 2;
localparam	S_DATA		= 3;
localparam	S_STOP 		= 4;

reg[2:0]		state;
reg[2:0]		next_state;
reg			rx_d0;
reg			rx_d1;
wire			rx_negedge;
reg[7:0]		rx_bits;
reg[2:0]		bit_cnt;
reg[15:0]	cycle_cnt;

assign	rx_negedge = ~rx_d0 && rx_d1;
//消息桢起始位，下降沿
always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	begin
	rx_d0 <= 1'b0;
	rx_d1 <= 1'b0;
	end
else 
	begin
	rx_d0 <= rx_pin;
	rx_d1 <= rx_d0;
	end
end

always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	state <= S_IDLE;
else
	state <= next_state;
end 
//状态转移
always@(*)
begin
	case(state)
		S_IDLE:
			if(rx_negedge)
				next_state <= S_START;
			else
				next_state <= S_IDLE;
		S_START:
			if(cycle_cnt == CYCLE-1)
				next_state <= S_RX_CYCLE;
			else
				next_state <= S_START;
		S_RX_CYCLE:
			if(cycle_cnt == CYCLE-1 && bit_cnt == 3'd7)
				next_state <= S_STOP;
			else
				next_state <= S_RX_CYCLE;
		S_STOP:
			if(cycle_cnt == CYCLE/2-1)
				next_state <= S_DATA;
			else
				next_state <= S_STOP;
		S_DATA:
			if(rx_ready)
				next_state <= S_IDLE;
			else
				next_state <= S_DATA;
		default:
			next_state <= S_IDLE;
	endcase
end
//波特率计数器	
always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	cycle_cnt <= 16'd0;
else if((state == S_RX_CYCLE && cycle_cnt == CYCLE-1)||next_state != state)
	cycle_cnt <= 16'd0;
else
	cycle_cnt <= cycle_cnt + 16'd1;
end
//比特位计数器
always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	bit_cnt <= 3'd0;
else if(state == S_RX_CYCLE )
	if(cycle_cnt == CYCLE-1)
		bit_cnt <= bit_cnt + 3'd1;
	else
		bit_cnt <= bit_cnt;
else
	bit_cnt <= 3'd0;
end
//串行数据转为并行数据
always@(posedge clk or negedge rst)
begin 
if(rst == 1'b0)
	rx_bits <= 8'd0;
else if(state == S_RX_CYCLE && cycle_cnt == CYCLE/2-1)
	rx_bits[bit_cnt] <= rx_pin;
else
	rx_bits <= rx_bits;
end
//数据接收有效标志位
always@(posedge clk or negedge rst)
begin
if(rst == 1'b0)
	rx_valid <= 1'b0;
else if(state == S_STOP && next_state != state)
	rx_valid <= 1'b1;
else if(state == S_DATA && rx_ready)
	rx_valid <= 1'b0;
end
//数据接收
always@(posedge clk or negedge rst)
begin 
if(rst == 1'b0)
	rx_data <= 8'd0;
else if(state == S_STOP && next_state != state)
	rx_data <= rx_bits;
else
	rx_data <= rx_data;
end
		
endmodule

modelsim仿真

模块整体波形图如下所示
在这里插入图片描述
采用两个寄存器，利用非阻塞赋值，对输入数据进行打拍，进而获得消息桢的下降沿。如下图所示：
在这里插入图片描述
内部状态转移和寄存器的波形图如下所示：
在这里插入图片描述

3.顶层模块

设计一个顶层程序，让FPGA每隔1秒发送一段字符串，并在等待时间里可接收计算机发送的数据，并将接收数据发送至PC端。
在这里插入图片描述
结构方框图如下所示：
在这里插入图片描述
FPGA每接收到一次数据就对LED进行电平翻转，所以增加了LED输出口，控制LED0。
代码如下：

module uart_test
#(
	parameter		CLK_FRE = 50,
	parameter		BAUD_RATE = 115200
)
(
	input		clk,
	input		rst,
	input		rx,
	output	tx,
	output reg	led
	);
	
localparam		IDLE = 0;
localparam		SEND = 1;
localparam		WAIT = 2;	

reg[1:0]		state;
reg[1:0]		next_state;

reg[7:0]		tx_data;
reg[7:0]		tx_str;
reg				tx_data_valid;
wire			tx_data_ready;

wire				rx_ready;
wire[7:0]		rx_data;
wire			rx_valid;	

reg[3:0]		tx_cnt;
reg[31:0]		wait_cnt;			

assign rx_ready = 1'b1;

always@(posedge clk or negedge rst)
begin
	if(rst == 1'b0)
		begin
			wait_cnt <= 32'd0;
			tx_cnt <= 8'd0;
			state <= IDLE;
			tx_data <= 8'd0;
			tx_data_valid <= 1'b0;
			led <= 1'b0;
		end
	else
		case(state)
			IDLE:
				state <= SEND;
			SEND:
				begin
					wait_cnt <= 32'd0;
					tx_data <= tx_str;
					if(tx_data_valid == 1'b1 && tx_data_ready == 1'b1 && tx_cnt < 4'd12)//发送字符串"I LOVE YOU"
					begin
						tx_cnt <= tx_cnt + 4'd1;
					end
					else if(tx_data_valid && tx_data_ready)//等待最后一个字节发送完
					begin
						tx_cnt <= 8'd0;
						tx_data_valid <= 1'b0;
						state <= WAIT;
					end
					else if(~tx_data_valid)
					begin
						tx_data_valid <= 1'b1;
					end
				end
			WAIT://等待1s的间隔，等待时间里可接收字符串，并送至发送模块
			begin
				wait_cnt <= wait_cnt +1'b1;
				if(rx_valid == 1'b1)
				begin
					tx_data_valid <= 1'b1;
					tx_data <= rx_data;
					led <= ~led;
				end
				else if(tx_data_valid && tx_data_ready)
				begin
					tx_data_valid <= 1'b0;
				end
				else if(wait_cnt >= CLK_FRE * 1000000)
				begin
					state <= SEND;
				end
			end
			default:
					state <= IDLE;
		endcase
	end
//要发送的字符串	
always@(*)
begin
	case(tx_cnt)
	4'd0:tx_str <= "I";
	4'd1:tx_str <= " ";
	4'd2:tx_str <= "L";
	4'd3:tx_str <= "O";
	4'd4:tx_str <= "V";
	4'd5:tx_str <= "E";
	4'd6:tx_str <= " ";
	4'd7:tx_str <= "Y";
	4'd8:tx_str <= "O";
	4'd9:tx_str <= "U";
	4'd10:tx_str <= "\r";
	4'd11:tx_str <= "\n";
	default:tx_str <= 8'd0;
	endcase
end

uart_tx 
#(
		.CLK_FRE	(CLK_FRE),
		.BAUD_RATE	(BAUD_RATE)
)uart_tx
(
	.clk(clk),
	.rst(rst),
	.tx_data(tx_data),
	.tx_data_valid(tx_data_valid),
	
	.tx_pin(tx),
	.tx_data_ready(tx_data_ready)
);

uart_rx 
#(
	.CLK_FRE	(CLK_FRE),
	.BAUD_RATE 	(BAUD_RATE)
)uart_rx
(
	.clk(clk),
	.rst(rst),
	.rx_pin(rx),
	.rx_ready(rx_ready),
	
	.rx_valid(rx_valid),
	.rx_data(rx_data)
	);
	
endmodule

四、实验结果

使用UCF文件对FPGA端口进行定义：

NET "clk" LOC = T8 | TNM_NET = sys_clk_pin;
TIMESPEC TS_sys_clk_pin = PERIOD sys_clk_pin 50000 kHz;

##
NET "rst"                  LOC = L3 | IOSTANDARD = "LVCMOS33";         ## reset pushbutton

##################################################################################
#USB Serial RS232 Pin define
##################################################################################
NET "rx"                LOC = C11 | IOSTANDARD = "LVCMOS33";   	## Uart RXD:U4_TXD
NET "tx"                LOC = D12 | IOSTANDARD = "LVCMOS33"; 	## Uart TXD:U4_RXD
##################################################################################
#LED Pin define
##################################################################################
NET "led"               LOC = P4 | IOSTANDARD = "LVCMOS33";       ## LED1

1、代码调试

1、ERROR:HDLCompiler:1511 - “C:\Users\HP\Desktop\FPGA_demo\04_uart\rtl\uart_rx.v” Line 29: Mix of blocking and non-blocking assignments to variable <rx_bits> is not a recommended coding practice.
错误原因：阻塞赋值与非阻塞赋值同时使用
2、锁存器警告，case语句需要写完整，一定要写”default“，负责就会产生不需要的锁存器，对后续的时序设计带来影响。定义的寄存器一定要给定初值，负责也会产生锁存器。

2、实验结果

串口结果如图所示：
在这里插入图片描述

桃子丫
关注
  • 1
    点赞
  • 踩
  • 27
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
FPGA零基础学习：UART协议驱动设计
07-15 581
本系列将带来FPGA的系统性学习，从最基本的数字电路基础开始，最详细操作步骤，最直白的言语描述，手把手的“傻瓜式”讲解，让电子、信息、通信类专业学生、初入职场小白及打算进阶提升的职业开发者都可以有系统性学习的机会。 系统性的掌握技术开发以及相关要求，对个人就业以及职业发展都有着潜在的帮助，希望对大家有所帮助。后续会陆续更新 Xilinx 的 Vivado、ISE 及相关操作软件的开发的相关内容，学习FPGA设计方法及设计思想的同时，实操结合各类操作软件，会让你在技术学习道路上无比的顺畅，告别技术学习小BU
基于Xilinx System Generator的PID算法快速硬件实现
10-19
介绍了利用Xilinx System Generator平台构建模型化数字PID控制算法，并通过FPGA将数字PID算法结合传感器与实际硬件控制对象快速建立控制模型，构成完整的闭环控制。通过对控制效果的实验验证,证明了其控制方法的可行性。
干货 | 基于FPGA实现PID控制算法
最新发布
dpwkj的博客
05-31 506
相信大家对于PID控制算法，都不感到陌生了，平衡车就是靠它平衡起来的，还有飞控的平衡算法也是它，以及FOC中的闭环控制中也是用的它，它不仅简单，而且易于理解。那么本篇文章将简要介绍一下算法的原理，然后带大家使用FPGA来实现(C语言实现过程特别简单)。
RS485串口通信实验（使用两块开发板通过RS-485串口通信，由各自开发板上的四个按键分别控制对方开发板上四个LED灯的亮灭。）
qq_43811597的博客
10-26 2999
RS485只有两根数据线，只能实现半双工传输 系统框图 1.按键模块 module key_debounce( //按键消抖 input sys_clk, //外部50M时钟 input sys_rst_n, //外部复位信号，低有效 input [3:0] key, //外部按键输入 output reg k.
FPGA-串口通信
qq_43409587的博客
03-10 3228
串口
FPGA入门 —— FPGA UART 串口通信
ppqppl的博客
06-06 4915
FPGA入门 —— FPGA UART 串口通信 串口简介 UART 通用异步收发传输器( Universal Asynchronous Receiver/Transmitter) ，通常称作 UART。 UART 是一种通用的数据通信协议，也是异步串行通信口(串口)的总称，它在发送数据时将并行数据转换成串行数据来传输，在接收数据时将接收到的串行数据转换成并行数据。 它包括了ch340、 RS2...
FPGA（二）串口通信
热门推荐
weixin_41678913的博客
02-20 1万+
通信过程分为3个步骤：首先，发送方按照信息编码方式对有效信息进行编码（编成可以在通信线路上传输的信号形态）；然后，编码后的信息在传输介质上进行传输，输送给接收方；最后，接收方接到编码信息后进行解码，解码后得到可以理解的有效信息。
杜勇-数字通信同步技术的MATLAB与FPGA实现Xilinx/VHDL版（2013版）电子书与源码
09-05
《数字通信同步技术的MATLAB与FPGA实现Xilinx/VHDL版》是杜勇老师在2013年出版的一本专著，主要聚焦于如何利用MATLAB和FPGA技术来实现数字通信系统的同步功能。这本书对于深入理解数字通信系统和实践工程应用具有极...
数字通信同步技术的MATLAB与FPGA实现杜勇
06-12
《数字通信同步技术的MATLAB与FPGA实现》是一本由杜勇老师编著的专业教材，专注于探讨在数字通信系统中至关重要的同步技术，并通过MATLAB和FPGA这两种工具进行实际操作和验证。这本书旨在帮助通信工程的学习者深入...
htliujy#notebook-hardware#Xinlinx_原语1
07-25
Xinlinx_原语IBUFDS：This design element is an input buffer that supports low-voltag
xilinx A7系列FPGA 串口更新方案
08-19
Xilinx A7系列FPGA 串口更新方案 在FPGA开发中，串口更新是一种常用的更新方式，通过串口可以实现FPGA程序的更新，下面将详细介绍Xilinx A7系列FPGA的串口更新方案。 串口更新工作流程 串口更新工作流程可以分为...
FPGA.A-B.zip_VHDL/FPGA/Verilog_C/C++_
08-12
描述提到“电子式合并单元中，fpga的程序，fpga型号为XINLINX”，这意味着这个压缩包可能包含了一个特定的FPGA项目，其目标是实现一个电子系统的合并单元。Xilinx是全球知名的FPGA制造商之一，提供了一系列的FPGA...
FPGA串口原理及实现
qq_41864425的博客
01-25 2515
本文章主要讲述了RS232串口原理，代码实现以及上板情况。通用异步收发传输器，英文全称Universal Asynchronous Receiver/Transmitter，简称UART。UART是一种通用的数据通信协议，也是异步串行通信口（串口）的总称，它在发送数据时将并行数据转换成串行数据来传输，在接收数据时将接收到的串行数据转换成并行数据。包括RS232、RS499、RS423、RS422和RS485等接口标准规范和总线标准规范。
002-FPGA之手把手教你写串口协议解析（STM32与FPGA数据互传）
qq_44858397的博客
05-13 6315
实现STM32和FPGA的串口通信，并将STM32传输过来的频率信息和波形信息解析存入定义的reg变量中。后续其他外设需要调用频率信息或者波形信息只需要实例化此串口模块即可。有什么不懂的可以在下方留言，只要学会了方法，对于串口数据的解析会变得很简单。这个仅仅是对数据进行处理，后续会发一篇DDS信号发生器的总代码，告诉大家如何调用PLL和ROM核生成特定频率的波形。
（五）零基础学懂FPGA中的串口通信（UART）
ChinaRyan666（蔡杰涛）的博客
09-22 6327
超级详细的讲解！手把手带你手撕FPGA UART！看完就会！
FPGA学习之串口篇
pikaqiu的博客
04-05 1917
FPGA 串口通信
FPGA学习3：串口通信
weixin_44977812的博客
06-30 4875
串口、FPGA
FPGA开发(1)——串口通信
qq_40995480的博客
06-24 3237
FPGA开发之串口通信
FPGA学习-9-串口通信
406156440的博客
06-19 576
系统:win10 软件编辑和程序下载平台:Quartus II 仿真平台:modelsim FPGA:EP4CE6 1 串口通信基础知识: 处理器与外部设备通信的两种方式: 并行通信和串行通信 速度快但占用引脚多–并行 串行通信的通信方式: 同步通信和异步通信 同步带时钟线,异步不带时钟,只能自觉遵从协议 串行通信的传输方向: 单工:数据只能沿着一个方向传输 半双工:数据两个方向,但是需要分时 全...
数字通信同步技术的matlab与fpga实现——xinlinx/vhdl版
10-26
数字通信同步技术是实现高速、可靠数字通信的关键技术之一。而在数字通信系统中，数字通信同步技术的MATLAB与FPGA实现，特别是基于Xilinx/VHDL进行开发的方式，具有重要的意义。 首先，MATLAB作为一个强大的数学计算工具，可以方便地进行算法的设计与验证。在数字通信同步技术中，使用MATLAB进行算法设计和仿真可以更加直观地观察到系统的性能和特性，并且可以快速地进行系统性能指标的评估和优化。同时，MATLAB还提供了丰富的工具箱和函数库，包括通信系统工具箱、信号处理工具箱等，可以方便地调用和实现数字通信同步技术中的各种功能模块。 其次，FPGA作为一种可编程逻辑器件，可以实现数字通信同步技术中的各种算法和功能模块。基于Xilinx平台和VHDL语言进行FPGA开发，具有较高的灵活性和可扩展性。可以通过编写VHDL代码，将MATLAB中设计好的算法直接转换为硬件逻辑，在FPGA芯片上进行运行。这样可以实现更高的运行速度和更低的系统延迟，并且可以大大提高系统的实时性和并行计算能力。 通过将数字通信同步技术的MATLAB与FPGA实现进行结合，可以充分发挥两者的优势，提高数字通信系统的运行速度和性能。实现MATLAB算法到FPGA芯片的转化需要使用HDL Coder工具。该工具可以将MATLAB中的算法转换为HDL代码（如VHDL），并为FPGA开发提供数学功能密集型模块。与传统的软件实现相比，基于FPGA的实现可以更好地满足高速、实时和并行计算的需求，并且能够方便地进行系统的调试和优化。 综上所述，数字通信同步技术的MATLAB与FPGA实现，尤其是基于Xilinx/VHDL的开发方式，可以极大地提高数字通信系统的性能和可靠性，对数字通信领域的研究和应用具有重要的意义。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值