【FPGA零基础学习之旅#9】状态机基础知识

最新推荐文章于 2024-05-21 14:50:39 发布
最新推荐文章于 2024-05-21 14:50:39 发布
阅读量844 收藏 8
点赞数 17
分类专栏： FPGA学习之旅 文章标签： fpga开发 学习 状态机 Verilog HDL FPGA 例程分析
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_56262476/article/details/130778338
版权

🎉欢迎来到FPGA专栏~状态机基础知识

  • ☆* o(≧▽≦)o *☆嗨~我是小夏与酒🍹
  • ✨博客主页：小夏与酒的博客
  • 🎈该系列文章专栏：FPGA学习之旅
  • 文章作者技术和水平有限，如果文中出现错误，希望大家能指正🙏
  • 📜 欢迎大家关注！ ❤️
    FPGQ2

CSDN

🎉 目录-状态机基础知识

遇见未来

一、效果演示

🔸Hello状态机例程：
RTL视图：
RTL1
状态转移：
状态转移1

🔸 流水灯状态机例程：
使用小精灵V2实现的效果：
流水灯
小精灵V2基础使用记录：【FPGA-Spirit_V2】小精灵V2开发板初使用。
RTL视图：
RTL2状态转移：
状态转移2

🔸循迹小车pwm状态机例程：
pwm

二、状态机基础知识

状态机全称是有限状态机（Finite State Machine，FSM），是表示有限个状态以及在这些状态之间的转移和动作等行为的数学模型。

状态机分为摩尔（Moore）型有限状态机与米利（Mealy）型有限状态机。摩尔状态机的输出只由输入确定（不直接依赖于当前状态）。米利有限状态机的输出不止与其输入有关，还与它的当前状态相关，这也是与摩尔有限状态机的不同之处。

对于状态机的描述方式，可分为一段式、两段式以及三段式。
一段式：整个状态机写到一个 always 模块里面。在该模块中既描述状态转移，又描述状态的输入和输出。
两段式：用两个 always 模块来描述状态机。其中一个 always 模块采用同步时序描述状态转移，另一个模块采用组合逻辑判断状态转移条件，描述状态转移规律及其输出。
三段式：在两个 always 模块描述方法基础上，使用三个 always 模块。一个 always 模块采用同步时序描述状态转移，一个 always 采用组合逻辑判断状态转移条件，描述状态转移规律，另一个 always 模块描述状态输出(可以用组合电路输出，也可以时序电路输出)。

本篇文章主要以三个简单案例为主入门状态机，需要深入学习状态机相关的知识可以参考大佬的文章：FPGA状态机（一段式、二段式、三段式）、摩尔型（Moore）和米勒型（Mealy）。

三、Hello例程分析

Hello例程说明：使用状态机对“Hello”字符串进行检测，当检测到完整的“Hello”字符串时，改变led的电平。

状态转移过程说明：在状态H时，当检测到字符H，跳转到状态e，否则，一直保持在H状态；在状态e时，当检测到字符e，跳转到状态l，否则，跳转回H状态；…同理，在状态o时，当检测到字符o，跳转到状态H，同时改变led的电平，否则，跳转回H状态且不改变led电平。

为了便于转移过程的分析，使用独热码对状态进行编码：

localparam ST_H 	= 5'b00001;
localparam ST_e 	= 5'b00010;
localparam ST_la 	= 5'b00100;
localparam ST_lb 	= 5'b01000;
localparam ST_o 	= 5'b10000;

同时，需要定义一个状态机寄存器，用于判断当前的状态：

//状态机寄存器
reg[4:0] curr_st;

由于对“Hello”字符串的检测分为5个状态，使用独热码进行编码占用了5个位宽，因此也需要定义一个5个位宽的状态机寄存器。

为了便于模块的维护和管理，在此定义好led的亮和灭：

//定义led状态
parameter led_on  = 1'b0;
parameter led_off = 1'b1;

根据上述状态转移的说明分析，编写状态机主程序：

//状态机主程序
always@(posedge Clk or negedge Rst_n)begin
	if(!Rst_n)
		curr_st <= ST_H;
	else begin 
		case(curr_st)
			ST_H:begin
				if(data == "H")
					curr_st <= ST_e;
				else
					curr_st <= ST_H;
			end
			ST_e:begin
				if(data == "e")
					curr_st <= ST_la;
				else
					curr_st <= ST_H;
			end
			ST_la:begin
				if(data == "l")
					curr_st <= ST_lb;
				else
					curr_st <= ST_H;
			end
			ST_lb:begin
				if(data == "l")
					curr_st <= ST_o;
				else
					curr_st <= ST_H;
			end
			ST_o:begin
				if(data == "o")
					curr_st <= ST_H;
				else
					curr_st <= ST_H;
			end
			default:curr_st <= ST_H;
		endcase
	end
end

“Hello”例程的完整代码：

FSM_Hello.v：

/
//模块：状态机例程-Hello
//作者：CSDN-小夏与酒

module FSM_Hello(
	input 			Clk,
	input 			Rst_n,
	input 		 	[7:0]data,
	output 	reg 	led
);

	//状态机状态定义
	//使用独热码的编码方式
	//写法一：
	localparam ST_H 	= 5'b00001;
	localparam ST_e 	= 5'b00010;
	localparam ST_la 	= 5'b00100;
	localparam ST_lb 	= 5'b01000;
	localparam ST_o 	= 5'b10000;

	//写法二：
	//	localparam
	//			ST_H 	= 5'b00001,
	//          ST_e 	= 5'b00010,
	//          ST_la 	= 5'b00100,
	//          ST_lb 	= 5'b01000,
	//			ST_o 	= 5'b10000;
				
	//状态机寄存器
	reg[4:0] curr_st;
	
	//定义led状态
	parameter led_on  = 1'b0;
	parameter led_off = 1'b1;
	
	//状态机主程序
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			curr_st <= ST_H;
		else begin 
			case(curr_st)
				ST_H:begin
					if(data == "H")
						curr_st <= ST_e;
					else
						curr_st <= ST_H;
				end
				ST_e:begin
					if(data == "e")
						curr_st <= ST_la;
					else
						curr_st <= ST_H;
				end
				ST_la:begin
					if(data == "l")
						curr_st <= ST_lb;
					else
						curr_st <= ST_H;
				end
				ST_lb:begin
					if(data == "l")
						curr_st <= ST_o;
					else
						curr_st <= ST_H;
				end
				ST_o:begin
					if(data == "o")
						curr_st <= ST_H;
					else
						curr_st <= ST_H;
				end
				default:curr_st <= ST_H;
			endcase
		end
	end

	//给led赋值，如果进入ST_o状态，并且data = "o"，则led电平改变
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led <= led_off;
		else if(curr_st == ST_o && data == "o")
			led <= led_on;
		else
			led <= led_off;
	end

endmodule

RTL视图：

RTL33
状态转移333

编写测试激励文件：

FSM_Hello_tb.v：

`timescale 1ns/1ns
`define clock_period 20

module FSM_Hello_tb;

	reg Clk;
	reg Rst_n;
	reg [7:0]ASCII;
	
	wire led;
	
	FSM_Hello FSM_Hello0(
		.Clk(Clk),
		.Rst_n(Rst_n),
	 	.data(ASCII),
	 	.led(led)
	);

	initial Clk = 1;
	always #(`clock_period/2) Clk = ~Clk;
	
	initial begin
		Rst_n = 0;
		ASCII = 0;
		#(`clock_period*20);
		Rst_n = 1;
		#(`clock_period*20 + 1);
		
		ASCII = "I";
		#(`clock_period);
		ASCII = "A";
		#(`clock_period);
		ASCII = "M";
		#(`clock_period);
		ASCII = "X";
		
		#(`clock_period);
		ASCII = "H";
		#(`clock_period);
		ASCII = "E";
		#(`clock_period);
		ASCII = "M";
		#(`clock_period);
		ASCII = "l";
		#(`clock_period);

		ASCII = "H";
		#(`clock_period);
		ASCII = "E";
		#(`clock_period);
		ASCII = "L";
		#(`clock_period);
		ASCII = "L";
		#(`clock_period);
		ASCII = "O";
		#(`clock_period);
		
		ASCII = "H";
		#(`clock_period);
		ASCII = "e";
		#(`clock_period);
		ASCII = "l";
		#(`clock_period);
		ASCII = "l";
		#(`clock_period);
		ASCII = "o";
		
		#(`clock_period);
		ASCII = "l"; 
		#(`clock_period);
		
		ASCII = "H";
		#(`clock_period);
		ASCII = "e";
		#(`clock_period);
		ASCII = "l";
		#(`clock_period);
		ASCII = "l";
		#(`clock_period);
		ASCII = "o";
		
		#(`clock_period);
		ASCII = "l"; 
		
		#(`clock_period);
		
		$stop;
	end		

endmodule

仿真结果：

仿真结果

四、简单例程分析

4.1 使用状态机实现流水灯

使用Verilog实现一个流水灯并不难，但是使用状态机的方式实现，就提供了新的编程思路。

在状态机的文章中加入流水灯的实现，主要是为了学习 【小月电子】 大佬的状态机写法风格，大佬博客主页链接：Moon_3181961725。

先上完整代码：

FSM_01_led.v：

/
//模块：状态机例程-LED-分析
//作者：CSDN-小夏与酒

module FSM_01_led(
	input 		Clk,
	input 		Rst_n,
	output reg 	led1,
	output reg 	led2,
	output reg 	led3
	);
	
	//定义状态机
	parameter	ST1		= 1;
	parameter	ST2		= 2;
	parameter	ST3		= 3;
	
	reg[3:0]	curr_st;//状态机寄存器
	reg[7:0]	cnt1;//定义计数寄存器
	reg[7:0]	cnt2;//定义计数寄存器
	reg[7:0]	cnt3;//定义计数寄存器
	
	//状态机主程序
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			curr_st <= ST1;
		else case(curr_st)
			ST1:begin
				if(cnt1 == 8'd9)
					curr_st <= ST2;
				else;	
			end
			ST2:begin
				if(cnt2 == 8'd9)
					curr_st <= ST3;
				else;	
			end
			ST3:begin
				if(cnt3 == 8'd9)
					curr_st <= ST1;
				else;	
			end
			default:;
		endcase
	end
	
	//状态机ST1的计数器，当状态机等于ST1时，cnt1加1，否则cnt1等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt1 <= 8'b0;
		else if(curr_st == ST1)
			cnt1 <= cnt1 + 1'b1;
		else
			cnt1 <= 8'b0;	
	end
	
	//状态机ST2的计数器，当状态机等于ST2时，cnt2加1，否则cnt2等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt2 <= 8'b0;
		else if(curr_st == ST2)
			cnt2 <= cnt2 + 1'b1;
		else
			cnt2 <= 8'b0;	
	end
	
	//状态机ST3的计数器，当状态机等于ST3时，cnt3加1，否则cnt3等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt3 <= 8'b0;
		else if(curr_st == ST3)
			cnt3 <= cnt3 + 1'b1;
		else
			cnt3 <= 8'b0;	
	end
	
	//给LED1赋值，当状态等于ST1时，LED1等于0，即点亮LED灯，否则LED1等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led1 <= 1'b1;
		else if(curr_st == ST1)
			led1 <= 1'b0;
		else
			led1 <= 1'b1;	
	end
	
	//给LED2赋值，当状态等于ST2时，LED2等于0，即点亮LED灯，否则LED2等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led2 <= 1'b1;
		else if(curr_st == ST2)
			led2 <= 1'b0;
		else
			led2 <= 1'b1;	
	end
	
	//给LED3赋值，当状态等于ST3时，LED3等于0，即点亮LED灯，否则LED3等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led3 <= 1'b1;
		else if(curr_st == ST3)
			led3 <= 1'b0;
		else
			led3 <= 1'b1;	
	end
	
endmodule

RTL视图与状态转移：

RTL1
状态转移

FSM_01_led_tb.v：

`timescale 1ns/1ns
`define clock_period 20

module FSM_01_led_tb;
	
	reg Clk;
	reg Rst_n;
	
	wire led1;
	wire led2;
	wire led3;
	
	FSM_01_led FSM_01_led0(
		.Clk(Clk),
		.Rst_n(Rst_n),
		.led1(led1),
		.led2(led2),
		.led3(led3)
	);
	
	initial Clk = 1;
	always #(`clock_period/2) Clk = ~Clk;
	
	initial begin
	Rst_n = 0;
	
	#(`clock_period*30);
	Rst_n = 1;
	
	#(`clock_period*300);
	
	$stop;
	
	end
	
endmodule

仿真结果：

仿真结果

实现效果：

在上板验证前记得修改计数器的计数值，即：

/
//模块：状态机例程-LED
//作者：CSDN-小夏与酒

module FSM_01_led(
	input 		Clk,
	input 		Rst_n,
	output reg 	led1,
	output reg 	led2,
	output reg 	led3
	);
	
	//定义状态机
	parameter	ST1		= 1;
	parameter	ST2		= 2;
	parameter	ST3		= 3;
	
	reg[3:0]	curr_st;//状态机寄存器
	reg[24:0]	cnt1;//定义计数寄存器
	reg[24:0]	cnt2;//定义计数寄存器
	reg[24:0]	cnt3;//定义计数寄存器
	
	//定义计数值范围
	parameter cnt_max = 25'd24_999_999;	//定时器最大值
	parameter cnt_min = 25'd0;			//定时器最小值
	parameter cnt_add = 1'b1;			//定时器定时增量
	
	//定义led状态
	parameter led_on  = 1'b0;
	parameter led_off = 1'b1;
	
	//状态机主程序
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			curr_st <= ST1;
		else case(curr_st)
			ST1:begin
				if(cnt1 == cnt_max)
					curr_st <= ST2;
				else;	
			end
			ST2:begin
				if(cnt2 == cnt_max)
					curr_st <= ST3;
				else;	
			end
			ST3:begin
				if(cnt3 == cnt_max)
					curr_st <= ST1;
				else;	
			end
			default:;
		endcase
	end
	
	//状态机ST1的计数器，当状态机等于ST1时，cnt1加1，否则cnt1等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt1 <= cnt_min;
		else if(curr_st == ST1)
			cnt1 <= cnt1 + cnt_add;
		else
			cnt1 <= cnt_min;	
	end
	
	//状态机ST2的计数器，当状态机等于ST2时，cnt2加1，否则cnt2等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt2 <= cnt_min;
		else if(curr_st == ST2)
			cnt2 <= cnt2 + cnt_add;
		else
			cnt2 <= cnt_min;	
	end
	
	//状态机ST3的计数器，当状态机等于ST3时，cnt3加1，否则cnt3等于0
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			cnt3 <= cnt_min;
		else if(curr_st == ST3)
			cnt3 <= cnt3 + cnt_add;
		else
			cnt3 <= cnt_min;	
	end
	
	//给LED1赋值，当状态等于ST1时，LED1等于0，即点亮LED灯，否则LED1等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led1 <= led_off;
		else if(curr_st == ST1)
			led1 <= led_on;
		else
			led1 <= led_off;	
	end
	
	//给LED2赋值，当状态等于ST2时，LED2等于0，即点亮LED灯，否则LED2等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led2 <= led_off;
		else if(curr_st == ST2)
			led2 <= led_on;
		else
			led2 <= led_off;	
	end
	
	//给LED3赋值，当状态等于ST3时，LED3等于0，即点亮LED灯，否则LED3等于1，关闭LED灯
	always@(posedge Clk or negedge Rst_n)begin
		if(!Rst_n)
			led3 <= led_off;
		else if(curr_st == ST3)
			led3 <= led_on;
		else
			led3 <= led_off;	
	end
	
endmodule

实现效果

学习方法：

将状态机主程序分割开来单独写，会使整个程序思路清晰。状态机主程序部分：

//状态机主程序
always@(posedge Clk or negedge Rst_n)begin
	if(!Rst_n)
		curr_st <= ST1;
	else case(curr_st)
		ST1:begin
			if(cnt1 == 8'd9)
				curr_st <= ST2;
			else;	
		end
		ST2:begin
			if(cnt2 == 8'd9)
				curr_st <= ST3;
			else;	
		end
		ST3:begin
			if(cnt3 == 8'd9)
				curr_st <= ST1;
			else;	
		end
		default:;
	endcase
end

4.2 使用状态机实现循迹小车的pwm

关于FPGA实现简单的循迹小车链接：【FPGA-Spirit_V2】基于FPGA的循迹小车-小精灵V2开发板。

现在讲解小车中的pwm模块：

关于模块的端口列表：

module ctrl_moto_pwm(
	input				clk,//时钟50M
	input				rst_n,//复位，低电平有效
	input	[7:0]		spd_high_time,//输入高电平持续时间
	input	[7:0]		spd_low_time,//输入低电平持续时间
	output				period_fini,//一个pwm周期结束的标志位
	output	reg			pwm//脉冲信号									
);

该模块需要输入时钟信号、复位信号、高电平持续时间和低电平持续时间；输出一个pwm周期结束的标志位和pwm信号。

定义pwm产生的三个状态：

//状态机
parameter	idle		= 8'h0;//空闲状态
parameter	step_high 	= 8'h1;//脉冲高电平状态，当为该状态时，pwm为高电平
parameter	step_low  	= 8'h2;//脉冲低电平状态，当为该状态时，pwm为低电平

为了debug的方便，在模块中加入判断产生了一个pwm的标志位：

//产生一个pwm周期的标志位，当一个pwm产生后，输出高电平，否则输出低电平
assign period_fini = (step_low_cnt == step_low_time)?1'b1:1'b0;

同样，与上文相同，为了编程思路的清晰，将状态机主程序单独写：

//状态机主程序
always@(posedge clk or negedge rst_n)begin
	if(!rst_n)
		curr_st <= idle;
	else case(curr_st)
		idle:curr_st <= step_high;
		step_high:begin
				//当高电平计数时间到达输入值时，进行状态跳转
				if(step_high_cnt == step_high_time)
					curr_st <= step_low;
				else;
		end
		step_low:begin
				//当低电平计数时间到达输入值时，进行状态跳转
				if(step_low_cnt == step_low_time)
					curr_st <= step_high;
				else;
		end
		default:;
	endcase
end

在不同的状态下（空闲、高电平、低电平），pwm的信号输出：

//该always块描述pwm的输出
always@(posedge clk or negedge rst_n)begin
	if(!rst_n)
		pwm <= 0;
	else if(curr_st == idle)
		pwm <= 0;
	else if(curr_st == step_high)
		pwm <= 1;
	else if(curr_st == step_low)
		pwm <= 0;
	else
		pwm <= 1;
end

完整代码如下：

ctrl_moto_pwm.v：

//脉冲生成模块，通过控制输出脉冲频率及占空比来控制小车的速度
module ctrl_moto_pwm(
	input				clk,//时钟50M
	input				rst_n,//复位，低电平有效
	input	[7:0]		spd_high_time,//输入高电平持续时间
	input	[7:0]		spd_low_time,//输入低电平持续时间
	output				period_fini,//一个pwm周期结束的标志位
	output	reg			pwm//脉冲信号									
);
				
	//状态机
	parameter	idle		= 8'h0;//空闲状态
	parameter	step_high 	= 8'h1;//脉冲高电平状态，当为该状态时，pwm为高电平
	parameter	step_low  	= 8'h2;//脉冲低电平状态，当为该状态时，pwm为低电平

	reg	[7:0]	curr_st;
	reg	[10:0]	step_high_time;
	reg	[10:0]	step_low_time;
	reg	[10:0]	step_high_cnt;
	reg	[10:0]	step_low_cnt;
	
	//产生一个pwm周期的标志位，当一个pwm产生后，输出高电平，否则输出低电平
	assign period_fini = (step_low_cnt == step_low_time)?1'b1:1'b0;
	
	//将输入值（高、低电平持续时间）存入寄存器中
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)begin
				step_high_time <= 0;
				step_low_time <= 0;
		end
		else begin
				step_high_time <= spd_high_time;
				step_low_time <= spd_low_time;
		end
	end
	
	//状态机主程序
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			curr_st <= idle;
		else case(curr_st)
			idle:curr_st <= step_high;
			step_high:begin
					//当高电平计数时间到达输入值时，进行状态跳转
					if(step_high_cnt == step_high_time)
						curr_st <= step_low;
					else;
			end
			step_low:begin
					//当低电平计数时间到达输入值时，进行状态跳转
					if(step_low_cnt == step_low_time)
						curr_st <= step_high;
					else;
			end
			default:;
		endcase
	end
	
	//高电平持续时间计数器，当持续时间到达输入值时，进行状态跳转
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			step_high_cnt <= 0;
		else if(curr_st == idle)
			step_high_cnt <= 0;
		else if(curr_st == step_high)
			step_high_cnt <= step_high_cnt + 1;
		else
			step_high_cnt <= 0;
	end
	
	//低电平持续时间计数器，当持续时间到达输入值时，进行状态跳转
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			step_low_cnt <= 0;
		else if(curr_st == idle)
			step_low_cnt <= 0;
		else if(curr_st == step_low)
			step_low_cnt <= step_low_cnt + 1;
		else
			step_low_cnt <= 0;
	end
	
	//该always块描述pwm的输出
	always@(posedge clk or negedge rst_n)begin
		if(!rst_n)
			pwm <= 0;
		else if(curr_st == idle)
			pwm <= 0;
		else if(curr_st == step_high)
			pwm <= 1;
		else if(curr_st == step_low)
			pwm <= 0;
		else
			pwm <= 1;
	end

endmodule

pwm产生模块的代码中我每一部分都写了对应的注释，可供大家参考，该模块可以直接在需要用到pwm的地方直接调用。

该模块对应的RTL视图和状态转移：
RTL4
状态转移4
我们编写一个简单的测试激励文件：

ctrl_moto_pwm_tb.v：

`timescale 1ns/1ns
`define clock_period 20

module ctrl_moto_pwm_tb;
	
	reg clk;
	reg rst_n;
	reg [7:0]spd_high_time;
	reg [7:0]spd_low_time;
	
	wire period_fini;
	wire pwm;
	
	ctrl_moto_pwm Uctrl_moto_pwm0(
		.clk(clk),//时钟50M
		.rst_n(rst_n),//复位，低电平有效
		.spd_high_time(spd_high_time),//输入高电平持续时间
		.spd_low_time(spd_low_time),//输入低电平持续时间
		.period_fini(period_fini),//一个pwm周期结束的标志位
		.pwm(pwm)//脉冲信号									
	);

	initial clk = 1;
	always #(`clock_period/2) clk = ~clk;
	
	initial begin
	
		rst_n = 0;
		spd_high_time = 0;
		spd_low_time = 0;
		#(`clock_period*100);
	
		rst_n = 1;
		spd_high_time = 15;
		spd_low_time = 5;
		#(`clock_period*2000);
		
		$stop;
	
	end

endmodule

仿真结果：

仿真4

csdn

🧸结尾

小夏与酒
关注
  • 17
    点赞
  • 踩
  • 8
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 5
    评论
专栏目录
FPGA实验 - 状态机实现流水灯
Cherish1ove的博客
12-18 3363
状态机实现流水灯 实验目的 了解层次化设计概念，熟悉层次化设计流程。 熟悉项目设计步骤及逻辑训练。 概念 层次化设计：对一个很大的项目进行拆分，直到拆分成很容易实现的最小规模为止。 系统顶层模块只负责连线，将各功能模块正确地组合起来。各功能模块由对应的若干子模块组成，同一模块的子模块之间有着相应的级联关系。 流水灯的实现步骤 利用状态机实现流水灯的时序 创建一个时钟分频模块，用慢时钟驱动状态机 系统架构 模块名称 说明 freq_slow 时钟分频，产生慢时钟
数字IC笔面基础，师傅领进门，修行靠个人——人人心中都有一个状态机（状态机简介及Verilog模板）
HFUT90S的博客
11-03 786
（1）状态机（Finite State Machine， FSM），是用来控制在有限状态之间跳变和时序电路，包含组合逻辑和时序逻辑，用来控制数字IC的流程。（2）几乎所有的Verilog语法书中都会介绍状态机，而每本语法书中对状态机的描述都各有千秋，每个人对状态机的理解和代码风格也不同。真的算是师傅领进门，修行靠个人。（3）状态机的基本要素包含状态个数、状态转移条件、输出以及输入。（4）描述状态机有状态转移图（常考）、状态转移列表以及HDL语言描述（会基础的状态机写法）。
FPGA状态机
Royonen的博客
06-29 1081
FPGA、Verilog、状态机
FPGA状态机设计详解
最新发布
weixin_66634995的博客
05-21 1169
• IDLE：初始状态，对输入的码流进行检测，若为1则跳转到状态A，则为0保留在该状态• A: 对输入的码流进行检测，若为0则跳转到状态B（10），则为1保留在该状态• B: 对输入的码流进行检测，若为0则跳转到状态C（100），则为1则跳转到状态A（101）• C: 对输入的码流进行检测，若为1则跳转到状态D（1001），则为0则跳转到状态IDLE（1000）• D: 对输入的码流进行检测，若为0则跳转到状态E（10010），则为1则跳转到状态A（10011）
【FPGA/IC】状态机FSM的各种写法（一段式、二段式、三段式、摩尔型Moore、米勒型Mealy）
热门推荐
孤独的单刀
08-05 5万+
FPGA状态机（一段式、二段式、三段式）、摩尔型（Moore）和米勒型（Mealy）
状态机
weixin_30336061的博客
11-01 244
状态机简写为FSM(Finite State Machine。 状态机就是状态转移图。 举个最简单的例子。人有三个状态健康，感冒，康复中。触发的条件有淋雨（t1），吃药（t2），打针（t3），休息（t4）。所以状态机就是健康-（t4）->健康；健康-（t1）->感冒；感冒-（t3）->健康；感冒-（t2）->康复中；康复中-（t4）->健康，等等。 就是这样状态...
FPGA入门系列实验教程——蜂鸣器发出警车鸣笛声.zip-综合文档
05-19
旨在帮助读者理解并掌握FPGA（Field-Programmable Gate Array）的基础知识，通过一个生动有趣的项目——让蜂鸣器模拟警车鸣笛声，来深入学习FPGA的工作原理和编程技巧。这个实验不仅涵盖了FPGA的基本概念，还涉及到...
FPGA学习需注意的几个重要问题
07-25
在FPGA学习之旅中，奠定坚实的数字电路基础至关重要。数字电路不仅为理解FPGA内部结构提供必要的背景知识，还帮助形成正确的硬件设计思维。无论采用哪版教材，都需要深入学习数字电路的基本原理和技术细节。 在编程...
初学者如何学习FPGA
04-11
FPGA，全称为Field-Programmable Gate Array，中文名为现场可编程门阵列，是电子设计领域中的一个重要组成部分。它允许工程师在硬件级别定制和优化数字电路，广泛应用于通信...希望这些指南能帮助你开启FPGA学习之旅。
fpga学习资料
11-15
《FPGA学习之旅：从入门到精通》 FPGA（Field-Programmable Gate Array），即现场可编程门阵列，是一种高度灵活的集成电路设计平台，允许用户在硬件级别自定义逻辑功能。对于想要深入理解和掌握数字系统设计的...
FPGA学习建议合集
02-14
### FPGA学习建议合集 #### 一、学习FPGA的重要性与步骤 FPGA（Field-Programmable Gate Array）即现场可编程门阵列，是一种半定制电路...希望上述建议能为你的学习之旅提供方向和动力，愿你在FPGA领域取得辉煌成就。
FPGA状态机详解
居安士的博客
02-05 7924
本篇文章介绍了状态机原理，Mealy和Moore状态机分类，一段式状态机与三段式状态机写法，并用流水灯举例分析了一段式状态机和三段式状态机的异同
fpga学习——状态机
qq_44982210的博客
06-03 332
fpga学习——状态机
【FPGA】状态机
weixin_43778388的博客
12-26 2550
【 1、状态机 1.1、理论 FPGA不同于CPU的一点特点就是CPU是顺序执行的，而FPGA是同步执行（并行）的。那么FPGA如何处理明显具有时间上先后顺序的事件呢？这个时候我们就需要使用到状态机了。 状态机简写为 FSM（Finite State Machine），也称为同步有限状态机，我们一般简称为状态机，之所以说“同步”是因为状态机中所有的状态跳转都是在时钟的作用下进行的，而“有限”则是说状态的个数是有限的。状态机的每一个状态代表一个事件，从执行当前事件到执行另一事件我们称之为状态的跳转或状
初学FPGA——状态机
gouyepeng的博客
04-12 894
@[仅记录FPGA学习过程中的点点滴滴，欢迎交流与指正] 基础知识 状态机全称是有限状态机（Finite State Machine,FSM ）,是一种在有限个状态之间按一定规律转换的时序电路，可以认为是组合逻辑和时序逻辑的一种组合。状态机通过控制各个状态的跳转来控制流程，使得整个代码看上去更加清晰易懂，在控制复杂流程的时候，状态机优势明显，因此基本上都会用刀状态机。 状态机功能： 描述系统逻辑功能。 定义系统的不同状态。 描述系统转化的条件及转化过程。 刻画系统状态和输入输出之间的关系。 状态机的.
如何在FPGA中实现状态机
weixin_44441263的博客
08-14 700
状态机 状态机（State Machine） 有限状态机（FSM）：在有限个状态之间按一定规律转换的时序电路。 模型： 梅利型和摩尔型区别：输出是否只与状态有关（是否需要输入信号） 编程方法：四段论 根据前面的模型可以知道，要想完成状态机的编程需要完成以下几步： 状态空间的定义 状态的跳转（判断当前状态是啥，是一个时序结构） 下一个状态（根据当前状态，结合一些其他的判断来判断下一个状态是什么） 状态的动作 ...
FPGA学习-状态机解析
HackEle的博客
02-06 192
点击蓝字关注我们关注、星标公众号，精彩内容每日送达 来源：网络素材一、有限状态机定义有限状态机（Finite-State Machine，FSM），又成为有限状态自动机，简称状态机，是表示有限个状态以及在这些状态之间的转移和动作等行为的数学模型。本文所讲的是基于硬件描述语言Verilog HDL的有限状态机的编写技巧及规范。众所周知FPGA以其并行性和可重构性为世人所知，而在当今的电子世界，基本所...
FPGA——状态机专题
YouthBlood9的博客
05-15 1199
1、根据以下描述功能用verilog编写一段代码，并用状态机来实现该功能。 （1）状态机：实现一个测试过程，该过程包括启动准备状态、启动测试、停止测试、查询测试结果、显示测试结果、测试结束返回初始化6个状态；用时间来控制该过程，90秒内完成该过程； （2）描述状态跳转时间； （3）编码实现。 2. 画出可以检测10010串的状态图, 并用verilog编程实现之。
FPGA学习（五）——状态机
m0_56145255的博客
06-15 1723
有限状态机（Finite State Machine,简称 FSM） 在有限个状态之间按一定规律转换的时序电路。状态机是包含有限个状态的概念化机器，由这3个元素组成的有向图，三者关系如下：所有的状态机体系中，普遍的假设一个状态机在它能进行下一个事件处理完成对每个事件的处理，这个执行模型被称为"运行—到—完成模型"（Run-to-Completion Execution Model，RTC）。 由一组触发器组成，用来记忆状态机当前所处的状态，状态的改变只发生在时钟的跳变沿。状态是否改变，如何改变，取决于组合逻
精通状态机设计：从基础到高级
"如何写好状态机 - 介绍状态机的基本概念，并探讨如何在FPGA设计中构建高效的状态机，以及使用Synplify Pro进行分析。" 在数字系统设计中，状态机是一种至关重要的思想方法，尤其在FPGA设计中扮演着核心角色。状态...
评论 5
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

小夏与酒

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值