SHADER学习笔记（一）：Surface Shader

最新推荐文章于 2024-08-30 09:47:03 发布
最新推荐文章于 2024-08-30 09:47:03 发布
阅读量1.4k 收藏 5
点赞数 1
分类专栏： Unity3d 文章标签： 学习 unity c# SurfaceShader Shader
原文链接：https://blog.csdn.net/needmorecode/article/details/81952538
版权

Surface Shader是Unity为了方便shader编写提供的特殊功能，它对底层的vertex/fragment shader做了封装，省去了一些重复代码编写的工作量。我的理解是它同时具有vertex/fragment shader的功能，只是写法上更加简洁，更容易上手。

Unity的官方manual上就提供了几个最好的学习例子，我在学习的过程中加上了注释。

简单的漫反射（SIMPLE）

这里写图片描述

 

  Shader "Example/Diffuse Simple" {
    SubShader {
      Tags { "RenderType" = "Opaque" } // 标签，决定什么时候渲染（对不透明物体渲染）
      CGPROGRAM // //CG语言标记开始
      #pragma surface surf Lambert // 编译指令 surface shader 自定义函数 光照模型[1] 
      struct Input {               // 输入的结构体
          float4 color : COLOR;    // 颜色值
      };
      void surf (Input IN, inout SurfaceOutput o) { // surface shader处理函数
          o.Albedo = 1;  // 将基础颜色设为白色[2]
      }
      ENDCG
    }
    Fallback "Diffuse" // 发生异常时回滚成Unity内置的Diffuse shader
  }

带纹理的漫反射（TEXTURE）

这里写图片描述

 

  Shader "Example/Diffuse Texture" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {} // 纹理，若没有赋值则默认为全白
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex; // 纹理uv坐标
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb; // 按uv坐标查找纹理上的像素，并获取rgb值
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

带法向贴图的漫反射（NORMAL MAPPING）

这里写图片描述

 

Shader "Example/Diffuse Bump" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {} // 法向贴图[3]
    }
    SubShader {
      Tags { "RenderType" = "Opaque" } 
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
        o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
        o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap)); // 将从法向贴图中取得的法向量赋给output
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

边缘光（RIM LIGHTING）

这里写图片描述

 

 Shader "Example/Rim" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _RimColor ("Rim Color", Color) = (0.26,0.19,0.16,0.0) // 边缘光的颜色
      _RimPower ("Rim Power", Range(0.5,8.0)) = 3.0 // 边缘光的强度
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 viewDir; // 观察向量
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      float4 _RimColor;
      float _RimPower;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          // 对观察向量和法向量求点积，这个值越小，代表这两个方向夹角越接近90度，即为轮廓边缘
          half rim = 1.0 - saturate(dot (normalize(IN.viewDir), o.Normal)); 
          // 越接近边缘，发出的光越亮
          o.Emission = _RimColor.rgb * pow (rim, _RimPower);
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

细节纹理（DETAIL TEXTURE）这里写图片描述

 

  Shader "Example/Detail" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Detail ("Detail", 2D) = "gray" {} // 细节纹理[4]
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float2 uv_Detail;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          // 将纹理和细节纹理叠加
          o.Albedo *= tex2D (_Detail, IN.uv_Detail).rgb * 2;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

屏幕空间下的细节纹理（DETAIL TEXTURE IN SCREEN SPACE）

这里写图片描述

 

 Shader "Example/ScreenPos" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float4 screenPos; // 屏幕坐标
      };
      sampler2D _MainTex;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          float2 screenUV = IN.screenPos.xy / IN.screenPos.w;
          screenUV *= float2(8,6);
          // 根据屏幕的uv坐标来叠加细节纹理[5]
          o.Albedo *= tex2D (_Detail, screenUV).rgb * 2;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

立方体贴图反射（CUBEMAP REFLECTION）

  Shader "Example/WorldRefl" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Cube ("Cubemap", CUBE) = "" {} // 立方体贴图[6]
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex; 
          float3 worldRefl; // 世界反射向量
      };
      sampler2D _MainTex;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          // 根据世界反射向量和立方体贴图，反射相应的rgb
          o.Emission = texCUBE (_Cube, IN.worldRefl).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

世界坐标下的切片（SLICES VIA WORLD SPACE POSITION）

这里写图片描述

 

  Shader "Example/Slices" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      Cull Off
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldPos;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
      // 自定义的切片函数（将y和z作为参数，意味沿x轴做切片）
          clip (frac((IN.worldPos.y+IN.worldPos.z*0.1) * 5) - 0.5);
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

使用顶点修改器的法线挤压（NORMAL EXTRUSION WITH VERTEX MODIFIER）

这里写图片描述

 

  Shader "Example/Normal Extrusion" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Amount ("Extrusion Amount", Range(-1,1)) = 0.5 // 挤压参数
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert // 声明会使用顶点修改器
      struct Input {
          float2 uv_MainTex;
      };
      float _Amount;
      void vert (inout appdata_full v) { // 顶点修改器实现
          v.vertex.xyz += v.normal * _Amount; // 沿法线移动顶点的坐标
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

逐顶点计算自定义数据（CUSTOM DATA COMPUTED PER-VERTEX）

这里写图片描述

 

  Shader "Example/Custom Vertex Data" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
          float3 customColor; // 自定义数据
      };
      void vert (inout appdata_full v, out Input o) {
          UNITY_INITIALIZE_OUTPUT(Input,o);
          // 在顶点修改器中，将法向量的绝对值赋值给参数customColor
          o.customColor = abs(v.normal); 
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          // 使用传递过来的参数，对颜色做叠加
          o.Albedo *= IN.customColor;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

注释：
[1]：Unity中最常用的是两种内置的光照模型：Lambert 和 BlinnPhong。
[2]：Albedo是物体的基础颜色，与之不同的Emission是自发光颜色，详细的input和output变量表参见官网。
[3]：法向贴图是为了实现凹凸不平的效果，可参见文章。
[4]：细节纹理是为了让纹理产生更细腻的感觉，可参见文章。
[5]：注意rgb相乘和相加的应用场合不同，这里给出了解释。
[6]：立方体贴图可用来做环境反射和天空盒，可参见文章。

 

真像大白阿
关注
专栏目录
Surface Shader（可编程渲染管线 表面着色器）
Champion_Lee的专栏
01-28 4239
1、Unity 3d官方文档上对WorldNormalVector的解释 float3 worldNormal； INTERNAL_DATA -will contain world normal vector if surface shader writes to o.Normal. Toget the normal vector based on per-pixel normal map, u
UnityShader学习笔记：Caustic水纹焦散与鱼群制作水族馆
花式大绵羊的博客
08-27 2430
UnityShader学习笔记：Caustic水纹焦散贴图代码部分关于聚散色彩分离的疑惑鱼群动画 本文教程原地址：https://www.alanzucconi.com/2019/09/13/believable-caustics-reflections/ 作者：Alan Zucconi 文章为自己学习记录使用，不含任何商业目的 贴图 开放版权的纹理贴图取自OpenGameArt 代码部分 Shader "Custom/Cautics" { Properties { _Co
Unity SurfaceShader基础知识入门
weixin_42565127的博客
12-30 1265
本文主要讲解了Unity中SurfaceShader的具体写法，以及几个常用的CG函数的用法。 在这里先说明一下，表面着色器将分为两次讲解，本文介绍表面着色器的基本概念和一些写法，用内置的兰伯特光照模式来进行Surface Shader的书写，而下次将介绍Surface Shader+自定义的光照模式的写法。
UnityURP-SurfaceShaderSolution 使用教程
最新发布
gitblog_00173的博客
08-30 328
UnityURP-SurfaceShaderSolution 使用教程 UnityURP-SurfaceShaderSolutiona tiny and flexible surface shader solution for Unity URP项目地址:https://gitcode.com/gh_mirrors/un/UnityURP-SurfaceShaderSolution 1. 项目的...
Shader编程学习笔记（七）—— Surface Shader 1
weixin_30878501的博客
05-23 169
Surface Shader 　　本小结对Unity的Surface Shader做一个大概的了解。主要了解在Surface Shader当中比较重要的几个部分，分别是: SurfaceOutput Input lighing shadow 　　首先查看一下Unity的官方手册中的Writing Surface Shaders，其中描述道：如果要编写一个shader去和光进行交...
Surface Shader
Potter：I am not for learning and learning, but for study and work
03-23 1192
SurfaceOutput: input: lighting:光照 shadow：阴影 属性声明类型对应关系： Simpler2D-2D half-Rang fixed4-4元向量Tags {“RenderType”=”Opaque”} 描述一种渲染类型,Opaque：不透明的物体 LOD 200 ：层级细节CGPROGRAM 开始 ENDCG 结束
SurfaceShader
hqyellows的博客
08-15 250
表面shader：是unity自己封装处理的shader；    unity封装了一些光照模型，可以直接使用； Surface Shader:   1，没有pass通道，系统自动生成；   2，SubShader { Tags { "RenderType"="Opaque" "Queue"="Transparent"} LOD 200  层次细节 CGPROGRAM //
Unity Shader表面着色器Surface Shader介绍
weixin_42565127的博客
08-12 902
表面着色器是一种对艺术家友好的着色器，它不同于传统的顶点着色器和片元着色器等流程，而是添加了一层抽象，整个渲染流程的着色器被分为三个：表面着色器、光照模型和光照着色器。其中，表面着色器定义了模型表面的反射率、法线和高光等，光照模型则选择兰伯特、Phong和Bliin-Phong等模型。光照着色器负责计算光照衰减和阴影等。绝大部分时候只需要关注表面着色器，例如纹理和颜色等，光照模型是提前定义的，光照着色其由系统定义，不会轻易更改。...
Shader基础：5、表面着色器Surface Shader
真像大白阿的博客
05-30 562
表面着色器是通过Unity给我们制定好的一套标准，计算出需要填充输入什么，输出什么等相关信息，并产生真实的顶点(vertex)&像素(pixel)着色器，以及把渲染路径传递到正向或延时渲染路径。 输出结构 struct SurfaceOutput { half3 Albedo; //反射率，也就是纹理颜色值（r,g,b) half3 Normal; //法线，法向量(x, y, z) half3 Em...
UnityShader入门精要学习笔记
01-12
这篇“UnityShader入门精要学习笔记”将带你了解Shader的基本概念和应用。 首先，我们要理解Shader是什么。Shader是一种运行在GPU上的程序，它负责处理图形的像素和顶点数据，从而实现各种复杂的视觉效果。在Unity...
unity shader 笔记学习文档
12-21
本文档是关于 Unity Shader 的学习笔记，涵盖了 Unity Shader 的基本概念、语法、函数和应用场景。 一、UnpackNormal 函数 UnpackNormal 函数是 UnityCG.cginc 库中的一个函数，用于解压缩法线数据。该函数的用法...
shader学习笔记二中shader
12-31
surface shader例子带有详细注释
Shader学习笔记（1）：Shader基础
南投北浪
10-13 292
最近想学Shader,找到一个大佬的博客，该笔记只是自己学习Shader的知识记录，其实跟博客的内容差不多，但是写一遍，自己对shader的基础更加清楚，这将是一个系列笔记，大佬博客的地址: https://blog.csdn.net/lzhq1982/article/category/6960994   1.unity提供的5种Shader模板 （1）Standard Surface S...
【Unity】Surface Shader的Input输入结构
森系少女的游戏梦
10-18 4054
Input中的UV数据在一个贴图变量之前加上uv两个字母，就代表提取它的uv值，例如uv_MainTex 　Input 这个输入结构通常拥有着色器需要的所有UV纹理坐标，纹理坐标必须被命名为“uv”后接纹理名字。(或者uv2开始，使用第二纹理坐标集)。Input中的可选变量　　可以在输入结构中根据自己的需要，可选附加这样的一些候选值： 　　 float3 viewDir - 视图方向 （view
Surface Shader
Young的博客
03-01 744
surface shader是一种对vertex and fragment shader的一种包装，不能加pass通道，加pass会编译报错 #pragma  surface  surf  standard  fullforwardshadows pragma ：表示是一条编译指令 surface ：表示这个Shader是一个表面着色器 surf ：函数名，在之后的代码块中
【Unity3D Shader编程】之六 暗黑城堡篇: 表面着色器(Surface Shader)的写法(一)
热门推荐
【浅墨的游戏编程Blog】毛星云（浅墨）的专栏
12-28 4万+
本文主要讲解了Unity中SurfaceShader的具体写法，以及几个常用的CG函数的用法。 在这里先说明一下，表面着色器将分为两次讲解，本文介绍表面着色器的基本概念和一些写法，用内置的兰伯特光照模式来进行Surface Shader的书写，而下次将介绍Surface Shader+自定义的光照模式的写法。 PS：最近几天，在完美世界、腾讯互娱工作多年的几个朋友们问了浅墨一些表面着色器相关的Shader写法，浅墨当时回答他们的时候自己也是似懂非懂。通过这篇文章的书写，现在算是对这方面知识有了进一步的理
Unity Shader 表面着色器(Surface Shader)
jk823394954的专栏
10-06 9884
Unity Shader分为表面着色器(Surface Shader)，顶点着色器(Vertex Shader),片段着色器(Fragment Shader) 我们先来看个简单的Surface Shader，看看它都能做什么。 首先我们通过"Create->3D Object ->Plane"创建一个面板 然后通过"Create->Shader->Standard Surface S
Shader学习笔记（一）：Surface Shader
长三月的游戏开发
08-22 3618
Surface Shader是Unity为了方便shader编写提供的特殊功能，它对底层的vertex/fragment shader做了封装，省去了一些重复代码编写的工作量。我的理解是它同时具有vertex/fragment shader的功能，只是写法上更加简洁，更容易上手。 Unity的官方manual上就提供了几个最好的学习例子，我在学习的过程中加上了注释。 简单的漫反射（Simp...
Unity Shader学习笔记：UnpackNormal函数和属性命名规范
Unity Shader 是一种用于在Unity引擎中创建和编辑材质的编程语言。它允许开发人员对游戏中的图形效果进行精细控制，包括光照、阴影、材质贴图等方面。在学习Unity Shader时，有一些重要的注意事项和方法需要特别关注...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值