理论推导
在6.2.4节中,我们给出了基本光照模型中高光反射部分的计算公式
高光反射求的夹角是模型反射光线与视线的夹角,因为视线光线距离反射光线越近,光照强度越高,与漫反射不同,漫反射是求法线与光源方向的夹角,与视野方向无关,所以即使移动镜头摄像机也不会影响表面光照,而高光反射则与视野方向紧密相关,高光反射时摄像机并不能完全收反射光,只能看到部分光照反射,数值与材质光泽度有关
v表示视线方向,r表示反射光线,系数:c分别是是颜色和强度,m材质的高光反射系数,指数mglass指材质光泽度,表示高光反射后所能映入眼睛的视野范围
r向量推导(纯手写)
代码实践
Phone光照模型
逐顶点
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 6/Specular Vertex-Level" {
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)//控制RGBA颜色
_Specular ("Specular", Color) = (1, 1, 1, 1)//控制公式中的高光反射系数(乐乐老师说这是高光反射颜色,希望有懂的解释一下)
_Gloss ("Gloss", Range(8.0, 256)) = 20//控制指数m glass
}
SubShader {
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
/*对应Properties语义段*/
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;//glass的范围比较大,取float
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
fixed3 color : COLOR;
};
v2f vert(a2v v) {
v2f o;
//转移顶点到裁剪空间
o.pos = UnityObjectToClipPos(v.vertex);
// 得到环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// 转移法线到世界坐标系
fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
// 得到世界空间的光线方向
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
// 计算漫反射项(这里如果不加漫反射项,没有受到高光反射的区域会显示成黑色,不被渲染)
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
// 得到世界空间中的反射光线(r向量)
fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
// 在世界空间转到裁剪空间
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
// 计算高光反射
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
//三项相加(环境光+漫反射+高光反射)
o.color = ambient + diffuse + specular;
return o;
}
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
逐像素
我们已经得到了高光反射的效果,但是使用逐顶点高光反射得到的高光效果有比较大的问题,我们可以在图6.10中看出高光部分明显不平滑,因为片元着色器COLOR语义是返回顶点坐标,经过顶点计算的颜色是线性的,而高光反射计算是非线性的,破坏了高光反射本身的非线性关系,所以改用TEXCOORD0语义即从获得纹理颜色的方式改为输出纹理坐标的方式,坐标即像素,故称为逐像素光照
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level" {
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader {
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;//定义一组坐标
float3 worldPos : TEXCOORD1;//定义两组坐标
};
v2f vert(a2v v) {
v2f o;
// 将模型从模型空间转换到裁剪空间
o.pos = UnityObjectToClipPos(v.vertex);
// 计算法线
o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
// 计算顶点坐标
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
fixed4 frag(v2f i) : SV_Target {
// 环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
// 漫反射
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
// 世界空间的光源方向
fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
// 世界空间的视野方向
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
// 计算高光
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
可以看出,细节上更加细腻
Blinn-Phong光照模型
既然高光反射是通过反射光线与视角来判断光照强度,那么我们是否可以通过一种折中的方法,求视角与反射光线的向量和进行计算?实际上Blinn模型就是使用的该方法,它是通过视角v与光线方向l之和归一化得到的,程序中实际上没有归一化,因此得到的光线更亮。
修改逐像素光照的frag部分的计算公式即可
fixed4 frag(v2f i) : SV_Target {
// Get ambient term
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
// Compute diffuse term
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
// Get the view direction in world space
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
// 得到世界坐标与视野方向的向量和halfDir
fixed3 halfDir = normalize(worldLightDir + viewDir);
// 计算高光反射,其中第三参数为halfDir
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
可以看出实际上Blinn模型更亮,实际中一般我们会使用此模型,效果比较好。
内置函数
在unity中有许多内置函数,分别可以用于求反射光,求观察方向,用于前向渲染,法线方向转换等,大大的简化了代码的编写,但是理解原理依然十分重要。以下是书中使用内置函数的Blinn模型代码
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 6/Blinn-Phong Use Built-in Functions" {
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(1.0, 500)) = 20
}
SubShader {
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float4 worldPos : TEXCOORD1;
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
// 使用内置函数求世界法线,使用该函数这样我们就不用使用mul数学函数求向量与转换矩阵之积了
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(i.worldNormal);
// 使用内置函数求世界空间的光源方向
// 我们需要一个变量来存储normlize()的结果
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
// 使用函数计算世界空间中的视野方向
// 我们需要一个变量来存储normlize()的结果
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 halfDir = normalize(worldLightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
虽然使用函数简化了所需的计算过程,但是当需要处理更复杂的光照时,如点光源与聚光灯,该计算光源方向的方法的方法就是错误的,这需要先进行判断光源类型,再计算它的光源信息。