ORB-SLAM2:CMakeLists.txt注释

cmake_minimum_required(VERSION 2.8) #设定cmake最小版本号
project(ORB_SLAM2) #指定项目工程名称

IF(NOT CMAKE_BUILD_TYPE)			    
  SET(CMAKE_BUILD_TYPE Release) #指定生成产物/编辑类型为release
ENDIF()

MESSAGE("Build type: " ${CMAKE_BUILD_TYPE})	#打印编辑类型信息

set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS}  -Wall  -O3 -march=native ")	
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall   -O3 -march=native")
#通过cmake_c_flags设置编译选项；-g -wall(不展示警告);-march=native，自动检测的CPU支持的指令集

# Check C++11 or C++0x support；设置C++标准
include(CheckCXXCompilerFlag)
 #这一行告诉CMake包含此函数以使其可用；INCLUDE（<file>/<module>）用来载入文件或预定义的cmake模块，如果是模块，那么可以通过在变量CMAKE_MODULE_PATH中搜索这个模块；CheckCXXCompilerFlag: 检查CXX编译器是否支持给定标志

#判断判断系统编译器是否支持c++11标准
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11) 
#尝试/判断使用标志-std=c++11编译程序，并将结果存储在变量COMPILER_SUPPORTS_CXX11中;CMake支持尝试使用传递给函数CMAKE_CXX_COMPILER_FLAG的任何标志编译程序，然后将结果存储在传入的变量中	
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
   add_definitions(-DCOMPILEDWITHC11)
   message(STATUS "Using flag -std=c++11.")
elseif(COMPILER_SUPPORTS_CXX0X)
   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
   add_definitions(-DCOMPILEDWITHC0X)
   message(STATUS "Using flag -std=c++0x.")
else()
   message(FATAL_ERROR "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

LIST(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake_modules)
#告诉cmake在哪儿去找我们的.cmake文件；CMAKE_MODULE_PATH指定由include() 加载的CMake模块的搜索路径								

find_package(OpenCV 3.0 QUIET)
if(NOT OpenCV_FOUND)
   find_package(OpenCV 2.4.3 QUIET)
   if(NOT OpenCV_FOUND)
      message(FATAL_ERROR "OpenCV > 2.4.3 not found.")
   endif()
endif()

list(APPEND CMAKE_INCLUDE_PATH “/usr/local/include”)
find_package(Eigen3 3.1.0 REQUIRED)			#找到各种库的头文件以及源码
find_package(Pangolin REQUIRED)

include_directories(					
${PROJECT_SOURCE_DIR} #{PROJECT_SOURCE_DIR}为包含PROJECT()的最近一个CMakeLists.txt文件所在的文件夹			
${PROJECT_SOURCE_DIR}/include
${EIGEN3_INCLUDE_DIR}
${Pangolin_INCLUDE_DIRS}
)#提供头文件路径它提供了一个搜索头文件暂时的根目录

set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/lib)	
#设置存放动态库文件的位置

add_library(${PROJECT_NAME} SHARED			#建立共享库
src/System.cc
src/Tracking.cc
src/LocalMapping.cc
src/LoopClosing.cc
src/ORBextractor.cc
src/ORBmatcher.cc
src/FrameDrawer.cc
src/Converter.cc
src/MapPoint.cc
src/KeyFrame.cc
src/Map.cc
src/MapDrawer.cc
src/Optimizer.cc
src/PnPsolver.cc
src/Frame.cc
src/KeyFrameDatabase.cc
src/Sim3Solver.cc
src/Initializer.cc
src/Viewer.cc
)

target_link_libraries(${PROJECT_NAME}		#将目标文件与库文件进行链接
${OpenCV_LIBS}
${EIGEN3_LIBS}
${Pangolin_LIBRARIES}
${PROJECT_SOURCE_DIR}/Thirdparty/DBoW2/lib/libDBoW2.so
${PROJECT_SOURCE_DIR}/Thirdparty/g2o/lib/libg2o.so
)

# Build examples
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/RGB-D)	
#设置可执行文件存放目录

add_executable(rgbd_tum	
Examples/RGB-D/rgbd_tum.cc)#生成名为xx的可执行文件
target_link_libraries(rgbd_tum ${PROJECT_NAME})

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/Stereo)

add_executable(stereo_kitti
Examples/Stereo/stereo_kitti.cc)
target_link_libraries(stereo_kitti ${PROJECT_NAME})

add_executable(stereo_euroc
Examples/Stereo/stereo_euroc.cc)
target_link_libraries(stereo_euroc ${PROJECT_NAME})		

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/Monocular)

add_executable(mono_tum
Examples/Monocular/mono_tum.cc)
target_link_libraries(mono_tum ${PROJECT_NAME})

add_executable(mono_kitti
Examples/Monocular/mono_kitti.cc)
target_link_libraries(mono_kitti ${PROJECT_NAME})

add_executable(mono_euroc
Examples/Monocular/mono_euroc.cc)
target_link_libraries(mono_euroc ${PROJECT_NAME})