最近在学习ORB-SLAM,发现基本找不到CMakeLists的代码注释,就决定自己注释一份.
如果发现有问题的地方,欢迎和我交流.
cmake_minimum_required(VERSION 2.8) #设定cmake最小版本号
project(ORB_SLAM2) #指定项目工程
IF(NOT CMAKE_BUILD_TYPE) #编译的类型(debug;release)
SET(CMAKE_BUILD_TYPE Release) #IF 和 ENDIF构成一个if语句
ENDIF()
MESSAGE("Build type: " ${CMAKE_BUILD_TYPE}) #输出消息:"Build type: Release"(打印调试信息)
#cmake_c_flags用来设置编译选项 如 -g -wall(不展示警告);-march=native,GCC会自动检测你的CPU支持的指令集
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -O3 -march=native ")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -O3 -march=native")
# Check C++11 or C++0x support
include(CheckCXXCompilerFlag) #include:从文件或模块加载并运行CMake代码 ;CheckCXXCompilerFlag: 检查CXX编译器是否支持给定标志
#以下代码都用于自动判断系统编译器是否支持c++11标准;
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
add_definitions(-DCOMPILEDWITHC11)
message(STATUS "Using flag -std=c++11.")
elseif(COMPILER_SUPPORTS_CXX0X)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
add_definitions(-DCOMPILEDWITHC0X)
message(STATUS "Using flag -std=c++0x.")
else()
message(FATAL_ERROR "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()
LIST(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake_modules)
#list(APPEND <list><element> [<element> ...]) 添加新element到list中
#CMAKE_MODULE_PATH: 指定要由CMake模块加载的CMake模块的搜索路径include() 要么 find_package()命令,然后检查CMake随附的默认模块。
#{PROJECT_SOURCE_DIR}为包含PROJECT()的最近一个CMakeLists.txt文件所在的文件夹
#cmake_modules:用于找寻不知名库时,事先在CMakeLists.txt相同位置建立一个叫cmake_modules的文件夹,在里面创建寻找库并命名的指令
set(OpenCV_DIR /home/z/cmake-3.4.9/build) #设置OpenCV的目录
find_package(OpenCV 3.4.9 QUIET)
if(NOT OpenCV_FOUND)
message(FATAL_ERROR "OpenCV > 2.4.3 not found.")
endif()
find_package(Eigen3 3.1.0 REQUIRED) #找到各种头文件以及源码
find_package(Pangolin REQUIRED)
include_directories(
#提供头文件路径它提供了一个搜索头文件暂时的根目录,即你可以在cmakelists中写上
#include_directories(/usr/local/include)来让库文件搜索以/usr/local/include为基础,即在main函数前写上#include “opencv/cv.h"即可
${PROJECT_SOURCE_DIR}
#{PROJECT_SOURCE_DIR}为包含PROJECT()的最近一个CMakeLists.txt文件所在的文件夹
${PROJECT_SOURCE_DIR}/include
${EIGEN3_INCLUDE_DIR}
${Pangolin_INCLUDE_DIRS}
)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/lib)
#设置变量到工程lib下 构建时将所有LIBRARY目标放置的位置
add_library(${PROJECT_NAME} SHARED #建立共享库
src/System.cc
src/Tracking.cc
src/LocalMapping.cc
src/LoopClosing.cc
src/ORBextractor.cc
src/ORBmatcher.cc
src/FrameDrawer.cc
src/Converter.cc
src/MapPoint.cc
src/KeyFrame.cc
src/Map.cc
src/MapDrawer.cc
src/Optimizer.cc
src/PnPsolver.cc
src/Frame.cc
src/KeyFrameDatabase.cc
src/Sim3Solver.cc
src/Initializer.cc
src/Viewer.cc
)
target_link_libraries(${PROJECT_NAME} #该指令的作用为将目标文件与库文件进行链接
${OpenCV_LIBS}
${EIGEN3_LIBS}
${Pangolin_LIBRARIES}
${PROJECT_SOURCE_DIR}/Thirdparty/DBoW2/lib/libDBoW2.so
${PROJECT_SOURCE_DIR}/Thirdparty/g2o/lib/libg2o.so
)
# Build examples
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/RGB-D)
#指定可执行文件的输出位置 CMAKE_RUNTIME_OUTPUT_DIRECTORY: 构建RUNTIME目标文件的输出目录
add_executable(rgbd_tum #使用指定的源文件将可执行文件添加到项目中。
Examples/RGB-D/rgbd_tum.cc)
target_link_libraries(rgbd_tum ${PROJECT_NAME})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/Stereo)
add_executable(stereo_kitti
Examples/Stereo/stereo_kitti.cc)
target_link_libraries(stereo_kitti ${PROJECT_NAME})
add_executable(stereo_euroc
Examples/Stereo/stereo_euroc.cc)
target_link_libraries(stereo_euroc ${PROJECT_NAME})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/Examples/Monocular)
add_executable(mono_tum
Examples/Monocular/mono_tum.cc)
target_link_libraries(mono_tum ${PROJECT_NAME})
add_executable(mono_kitti
Examples/Monocular/mono_kitti.cc)
target_link_libraries(mono_kitti ${PROJECT_NAME})
add_executable(mono_euroc
Examples/Monocular/mono_euroc.cc)
target_link_libraries(mono_euroc ${PROJECT_NAME})