关于特权同学第9课——消抖电路rtl的分析

rtl代码如下：

//说明：当三个独立按键的某一个被按下后，相应的LED被点亮；
//        再次按下后，LED熄灭，按键控制LED亮灭

module sw_debounce(
            clk,rst_n,
            sw1_n,sw2_n,sw3_n,
               led_d1,led_d2,led_d3
            );

input   clk;    //主时钟信号，50MHz
input   rst_n;    //复位信号，低有效
input   sw1_n,sw2_n,sw3_n;     //三个独立按键，低表示按下
output  led_d1,led_d2,led_d3;    //发光二极管，分别由按键控制

//---------------------------------------------------------------------------
reg[2:0] key_rst;  

always @(posedge clk  or negedge rst_n)
    if (!rst_n) key_rst <= 3'b111;
    else key_rst <= {sw3_n,sw2_n,sw1_n};

reg[2:0] key_rst_r;       //每个时钟周期的上升沿将low_sw信号锁存到low_sw_r中

always @ ( posedge clk  or negedge rst_n )
    if (!rst_n) key_rst_r <= 3'b111;
    else key_rst_r <= key_rst;
   
//当寄存器key_rst由1变为0时，led_an的值变为高，维持一个时钟周期
wire[2:0] key_an = key_rst_r & ( ~key_rst);

//---------------------------------------------------------------------------
reg[19:0]  cnt;    //计数寄存器

always @ (posedge clk  or negedge rst_n)
    if (!rst_n) cnt <= 20'd0;    //异步复位
    else if(key_an) cnt <=20'd0;
    else cnt <= cnt + 1'b1;
 
reg[2:0] low_sw;

always @(posedge clk  or negedge rst_n)
    if (!rst_n) low_sw <= 3'b111;
    else if (cnt == 20'hfffff)     //满20ms，将按键值锁存到寄存器low_sw中     cnt == 20'hfffff
      low_sw <= {sw3_n,sw2_n,sw1_n};
      
//---------------------------------------------------------------------------
reg  [2:0] low_sw_r;       //每个时钟周期的上升沿将low_sw信号锁存到low_sw_r中

always @ ( posedge clk  or negedge rst_n )
    if (!rst_n) low_sw_r <= 3'b111;
    else low_sw_r <= low_sw;
   
//当寄存器low_sw由1变为0时，led_ctrl的值变为高，维持一个时钟周期
wire[2:0] led_ctrl = low_sw_r[2:0] & ( ~low_sw[2:0]);

reg d1;
reg d2;
reg d3;
 
always @ (posedge clk or negedge rst_n)
    if (!rst_n) begin
        d1 <= 1'b0;
        d2 <= 1'b0;
        d3 <= 1'b0;
      end
    else begin        //某个按键值变化时，LED将做亮灭翻转
        if ( led_ctrl[0] ) d1 <= ~d1;    
        if ( led_ctrl[1] ) d2 <= ~d2;
        if ( led_ctrl[2] ) d3 <= ~d3;
      end

assign led_d3 = d1 ? 1'b1 : 1'b0;        //LED翻转输出
assign led_d2 = d2 ? 1'b1 : 1'b0;
assign led_d1 = d3 ? 1'b1 : 1'b0;
 
endmodule

代码分析如下：

1. 首先定义三个独立按键，分别为sw1_n, sw2_n, sw3_n，作为三个led控制的按键，并将这三个1bit位宽的input整合到位宽为3的key_rst信号中，用位拼接符表示key_rst = {sw3_n, sw2_n, sw1_n};

2. 将key_rst信号打一拍，产生key_rst_r信号，并和key_rst的非相与，由此产生下降沿脉冲，因为key_rst是3位，故最多能够产生3个下降沿脉冲。下降沿脉冲信号存储在位宽为3的key_an信号之中，换言之，key_an就是检测下降沿的。

3. 在代码运行伊始，由于所有的always块是并行的，所以复位结束后，计数器cnt一直在计数，只不过cnt清零有两个条件：一是在复位信号有效时候清零；二是当key_an信号有效。注意这里的key_an是3bit位宽，判断条件成立的话，并不是需要key_an == 3'b111；而只需要key_an中有一个电平信号为高即可，比如key_an == 3'b001;

4. 以一个按键sw1_n为例,在按下按键的过程中，由于按键抖动，sw1_n一直在高低电平之间跳变，于是每检测到一次下降沿，电路就将计数器cnt清零，直到电路在按键抖动的过程中检测到最后一次下降沿，此时计数器不再清零，一直计数到cnt满足计数条件（cnt == 20'hfffff，即20ms），则将sw1_n, sw2_n, sw3_n的电平信号置于3bit位宽的low_sw中，同时cnt由于溢出而回到20'h0状态。换言之，key_an启动计数器，当按键不再抖动时（cnt记满20ms后），将此时按键的状态置于low_sw中。

5. 将low_sw打一拍，得到low_sw_r；并和low_sw的非相与，得到按键稳定后对LED的控制信号led_ctrl，对应的LED等将亮或灭。

 

总结而言就是：key_rst一直记录三个按键的变化，并检测出每个按键的下降沿（也就是按下这个动作以及之后的一系列抖动），每次抖动的下降沿触发计数器，使计数器清零并重新计数，直到最后一次抖动，计数器能够记满20ms，20ms之后按键稳定，不再抖动，此时将每个按键的状态置于low_sw中，并由此产生控制LED灯亮灭的led_ctrl信号。记录变化的和点亮LED的分工特别明确，这是特权同学非常好的点子。

 

需要注意的是cnt计数满20ms之后，传递给low_sw的值到底是什么？以sw1_n为例分析如下：

1. 假设在最后一个下降沿之后，sw1_n为0，表明对应的按键确实按下去了，则20ms后，low_sw[0] = 0，对应的LED灯亮。

2. 若此时一直按着sw1_n，则20ms后，sw1_n依然为0，LED灯依然亮着，不会引起电路新动作。

3. 假设在最后一个下降沿之后，紧跟这一个上升沿，表明对应的按键没有被按下去，或者说按了一会又松开了，则sw1_n为1，由于之后再没有下降沿，则cnt不再会被清零，则当计数满20ms后，low_sw[0]仍然会被赋值，但是此时赋的值为1，即low_sw[0] = 1，对应的LED灯不会被点亮。

 

补充一点：

为什么只是检测下降沿，为什么不能是上升沿检测？或者说为什么释放时不用上升沿检测？

答：不论按下还是释放按键，其过程必有抖动，对于下降沿检测来说，当按键按下，只要检测到最后一个下降沿，cnt计数就会一直记到20ms才会将此时的按键状态当做稳定状态传递给low_sw中；当按键释放，最后一个下降沿之后cnt会一直记满20ms，之后将稳定值传递给low_sw中。上升沿检测也是同理。它俩都是为了规定一个记录20ms的开始时间，20ms之后将稳定值记录下来，跟用何种方式实现20ms的计数并无关系。所以没有必要在按下时用下降沿检测，释放时用上升沿检测，也就是说，没必要用两套计数方案。

 

PS:这个写法比小梅哥的状态机消抖要好很多，代码简洁，电路逻辑简单。

另外建议看一下这篇文章：https://blog.csdn.net/joygo007/article/details/71075014