【Unity】ShaderLab-3_1-基础纹理

/**********
*
* 作者   :   Quaye
* 时间   :   2018.05.31
*
* 描述   :    基本纹理，对于单张纹理的渲染，我们通常使用一张纹理来代替漫反射的颜色。
**/
Shader "Quaye/_SingleTesture"
{
    Properties
    {
        _Color("Color",Color)=(1,1,1,1)
        _Main2D("_Main2D",2D) = "white"{}
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8,256)) = 20
    }

    SubShader
    {
        Tags {"LightMode"= "ForwardBase"}
        Pass
        {
            CGPROGRAM
            #pragma vertex vert 
            #pragma fragment frag 
            #include "Lighting.cginc"

            struct a2v 
            {
                float4 vertex   : POSITION;
                float3 normal   : NORMAL;
                fixed4 textcoord: TEXCOORD0;
            };
            struct v2f
            {
                float4 pos  : SV_POSITION;
                float3 wNo  : TEXCOORD0;
                float4 wPo  : TEXCOORD1;
                float2 uv   : TEXCOORD2;
            };
            fixed4 _Color;
            sampler2D _Main2D;
            fixed4 _Main2D_ST;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos( v.vertex);
                o.wNo = UnityObjectToWorldNormal(v.normal);
                o.wPo = mul(unity_ObjectToWorld,v.vertex);
                o.uv  = TRANSFORM_TEX(v.textcoord,_Main2D); 
                return o;
            }

            fixed4 frag (v2f o) : SV_TARGET
            {
                fixed3 wN   = normalize(o.wNo); 
                fixed3 wL   = normalize(UnityWorldSpaceLightDir(o.wPo)).xyz;
                // 纹理取样
                fixed3 albedo = tex2D(_Main2D,o.uv).rgb * _Color.rgb;
                // 环境光 = 环境光 * 纹理取样
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb * albedo;
                // 漫反射 = 平行光 * 纹理取样
                fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(wN,wL));

                fixed3 v = normalize(UnityWorldSpaceViewDir(o.wPo));
                fixed3 h = normalize( wL + v );
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(wN,h)),_Gloss);

                return fixed4(ambient + diffuse +specular,1);
            }
            ENDCG
        }
    }
}