[ Unity特效 ] 来一发信号干扰效果

昨天在B站发现了重装战姬的印象曲。
突然想实现一下这种干扰的效果。

从画面上看，应该只是将图片的UV分段然后偏移。
这种效果一般UI上面会用的比较多，所以做成UI效果应该会比较好。

第一步

首先先从Unity官网下载当前Unity版本的builtin_shaders;
https://unity3d.com/get-unity/download/archive
Downloads -> Bulit in shaders
这一步是为了拿到Unity默认的UI/Default的shader源码，然后在它的基础上改。
在不改变该shader的基础上可以添加代码，可以应用很多Unity自带的UI效果，比如Mask。

Unity默认的UI Default里的参数大都是组件调用的，比如Mask组件会改写Stencil相关的属性来达到遮罩的效果，详细请搜模板测试。
Image组件的Color改变的也不是材质的Tint Color，从而在不更换材质的情况下减少了DC。
在UI/Default的shader基础上进行修改，可以“继承”UI的很多功能。

第二步

Shader "UI/ChannelNoise"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)

        _StencilComp ("Stencil Comparison", Float) = 8
        _Stencil ("Stencil ID", Float) = 0
        _StencilOp ("Stencil Operation", Float) = 0
        _StencilWriteMask ("Stencil Write Mask", Float) = 255
        _StencilReadMask ("Stencil Read Mask", Float) = 255

        _ColorMask ("Color Mask", Float) = 15

        [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0

        _NoiseStrength("NoiseStrength", Range(0, 1)) = 0
        _NoiseSeed("NoiseSeed", Range(0, 1)) = 0
        _Segment("Segment", int) = 50
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Stencil
        {
            Ref [_Stencil]
            Comp [_StencilComp]
            Pass [_StencilOp]
            ReadMask [_StencilReadMask]
            WriteMask [_StencilWriteMask]
        }

        Cull Off
        Lighting Off
        ZWrite Off
        ZTest [unity_GUIZTestMode]
        Blend SrcAlpha OneMinusSrcAlpha
        ColorMask [_ColorMask]

        Pass
        {
            Name "Default"
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0

            #include "UnityCG.cginc"
            #include "UnityUI.cginc"

            #pragma multi_compile_local _ UNITY_UI_CLIP_RECT
            #pragma multi_compile_local _ UNITY_UI_ALPHACLIP

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
                float4 worldPosition : TEXCOORD1;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            sampler2D _MainTex;
            fixed4 _Color;
            fixed4 _TextureSampleAdd;
            float4 _ClipRect;
            float4 _MainTex_ST;

            float _NoiseStrength;
            float _NoiseSeed;
            int _Segment;

            float rand(float2 p)
            {
                return frac(sin(dot(p ,float2(12.9898,_NoiseSeed))) * 43758.5453);
            }

            float noise(float2 x)
            {
                float2 i = floor(x);
                float2 f = frac(x);

                float a = rand(i);
                float b = rand(i + float2(1.0, 0.0));
                float c = rand(i + float2(0.0, 1.0));
                float d = rand(i + float2(1.0, 1.0));
                float2 u = f * f * f * (f * (f * 6 - 15) + 10);

                float x1 = lerp(a,b,u.x);
                float x2 = lerp(c,d,u.x);
                return lerp(x1,x2,u.y);
            }

            float2 getUV(int segment, float2 texcoord)
            {
                float2 uv = texcoord;
                uv.x = texcoord.x + (noise(floor(uv.y * segment)) - 0.5) * _NoiseStrength;
                return uv;
            }

            v2f vert(appdata_t v)
            {
                v2f OUT;
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
                OUT.worldPosition = v.vertex;
                OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);

                OUT.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);

                OUT.color = v.color * _Color;
                return OUT;
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                float2 uv = getUV(_Segment, IN.texcoord);
                float4 tempColor = tex2D(_MainTex, uv);
                half4 color = (tempColor + _TextureSampleAdd) * IN.color;

                #ifdef UNITY_UI_CLIP_RECT
                color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
                #endif

                #ifdef UNITY_UI_ALPHACLIP
                clip (color.a - 0.001);
                #endif

                return color;
            }
        ENDCG
        }
    }
}

这是通过UI/Default修改的完整代码。
通过UV的y方向*切割的片数，可以将UV0到1的区间转换为0到片数，然后通过floor取整来将UV的y方向分成片数个片段。
Noise主要解决随机偏移问题，相同的数值通过noise会得到相同的结果，并且它有随机的特点且不会超出0到1的范围。

最终效果

图片稍微给了一点蓝色，这样会有全息的感觉。

而且支持遮罩哦，这就是为什么在UI/Default的基础上修改的原因，这样外面框起来就是一个对话框了。

Shader的属性。
后三个是新添加的。
NoiseStrength是偏移强度，越大偏移效果分开的越强。
NoiseSeed是种子，种子不同偏移的方向也不相同，可以通过脚本修改来达到动态絮乱的感觉。
Segment是片数，表示将一张图分成多少段。

所以做完了。

配合脚本控制效果。