Unity Shader：光照模型，纹理，详细注释

已于 2022-05-27 20:27:04 修改
阅读量609 收藏
点赞数
分类专栏： 图形 游戏 文章标签： unity 图形渲染 ShaderLab 着色器
于 2022-05-21 20:42:08 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_42885747/article/details/124902963
版权

Phong光照模型

进入摄像机的光线分为四个部分:

环境光（ambient）

其他所有间接光照

自发光（emissive）

给定一个方向，模型表面本身向该方向发射多少辐射量

漫反射（diffuse）

当光线从光源照射到模型表面时，会向所有方向散射多少辐射量

高光反射（specular）

当光线从光源照射到模型表面时，会向镜面反射方向散射多少辐射量

Blinn-Phong模型：引入半程向量来计算高光反射，能得到更好的结果

Blinn-Phong模型是各向同性（isotropic）的，固定视角和光源方向旋转表面时，反射不会发生变化。

逐像素光照：Phong着色（Phong shading）

使用每个像素的法线（对顶点法线插值得到 或法线纹理中采样得到）进行光照模型的计算

逐顶点光照：高洛德着色（Gouraud shading）

只在顶点上计算光照，将结果进行线性插值得到像素颜色，无法计算高光反射

且会导致图元内部的颜色暗于顶点处的最高颜色值，可能会产生棱角现象

但是计算量很小。

逐顶点光照 （Gouraud shading）
Shader "Custom/DiffuseVertex"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        
    }
    SubShader
    {
        Pass{
            Tags { "RenderType"="ForwardBase" }
            CGPROGRAM
            //指定顶点着色器的函数
            #pragma vertex vert  
            //指定片元着色器的函数
            #pragma fragment frag
            #include "Lighting.cginc"
            struct a2v{  //顶点着色器的输入
                float4 vertex: POSITION;  //顶点坐标
                float3 normal:NORMAL;    //顶点法线
            };
            struct v2f{ //顶点着色器的输出，片元着色器的输入
                float4 pos:SV_POSITION;
                float3 color:COLOR;
            };

            fixed4 _Diffuse;

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);   //使用内建函数实现MVP变换
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;  //使用内置宏获取环境光照
                fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject)); //法线 的世界坐标
                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);  //光方向矢量 的世界坐标
                //saturate函数可以对矢量的每一个分量截取在[0,1]范围内
                fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));
                o.color=ambient+diffuse;  //加上环境光照
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {
                return fixed4(i.color,1.0); 
            }
            
            ENDCG
        }
    }
    FallBack "Diffuse"
}
逐像素光照 （Phong shading）

Shader "Custom/DiffusePixel"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Pass{
            Tags { "RenderType"="ForwardBase" }
            CGPROGRAM
    
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            struct a2v{
                float4 vertex: POSITION;
                float3 normal:NORMAL;
            };
            struct v2f{
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;  //顶点变换到世界空间，并截取3x3矩阵
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {
                fixed3 worldNormal=normalize(i.worldNormal);  //法线向量归一化
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;  //环境光照
                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);  //指向光源的方向向量世界坐标
                //saturate函数可以对矢量的每一个分量截取在[0,1]范围内
                fixed lambert=saturate(dot(worldNormal,worldLight));  //兰伯特光照模型
                float halfLambert=dot(worldNormal,worldLight)*0.5+0.5; //半兰伯特光照模型
                fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * halfLambert;  //计算漫反射(使用半兰伯特模型)
                return fixed4(ambient+diffuse,1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Diffuse"
}

镜面反射（高光反射）

在上述基础上增加了specular分量的计算，使用半程向量，可以不用计算反射光线。同时也给出了计算反射光线的方法。

逐像素光照

Shader "Custom/DiffusePixel"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Pass{
            Tags { "RenderType"="ForwardBase" }
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            struct a2v{
                float4 vertex: POSITION;
                float3 normal:NORMAL;
            };
            struct v2f{
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;  //顶点变换到世界空间，并截取3x3矩阵
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {
                fixed3 worldNormal=normalize(i.worldNormal);  //法线向量归一化
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;  //环境光照
                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);  //指向光源的方向向量世界坐标
                //saturate函数可以对矢量的每一个分量截取在[0,1]范围内
                fixed lambert=saturate(dot(worldNormal,worldLight));  //兰伯特光照模型
                float halfLambert=dot(worldNormal,worldLight)*0.5+0.5; //半兰伯特光照模型
                fixed3 diffuse=_LightColor0.rgb * _Diffuse.rgb * halfLambert;  //计算漫反射(使用半兰伯特模型)
                fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz); //视线，从像素到摄像机
                fixed3 reflectDir=normalize(reflect(-worldLight,worldNormal)); //计算反射光线方向
                fixed3 halfDir=normalize(worldLight+viewDir);  //半程向量
                fixed3 specular_phong = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss); //使用Phong模型计算的高光
                fixed3 specular_blinn = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(halfDir,worldNormal)),_Gloss); //使用Blinn-Phong模型计算的高光
                return fixed4(ambient+diffuse+specular_blinn,1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Diffuse"
}

纹理

单一纹理贴图
Shader "Custom/SingleTexture"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)  //控制物体整体色调
        _Specular ("Specular",Color) = (1,1,1,1)  
        _Gloss ("Gloss",Range(8.0,256)) = 20  
        _MainTex ("Main Tex",2D)="white" {}  //使用的纹理贴图
    }
    SubShader
    {
        Pass{
            Tags { "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            struct a2v{
                float4 vertex: POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };
            struct v2f{
                float4 pos:SV_POSITION;       //裁剪空间坐标
                float3 worldNormal:TEXCOORD0; //世界空间坐标
                float3 worldPos:TEXCOORD1;
                float2 uv:TEXCOORD2;
            };

            fixed4 _Color;
            fixed4 _Specular;
            float _Gloss;
            sampler2D _MainTex;
            float4 _MainTex_ST;  //纹理的缩放和平移值
            v2f vert(a2v v)
            {
                v2f o;  //顶点着色器输出
                o.pos=UnityObjectToClipPos(v.vertex);  
                o.worldNormal=UnityObjectToWorldNormal(v.normal);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;  
                o.uv=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //乘以缩放矩阵，再加上平移量
                //或者可以使用内置宏:
                //o.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {
                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));  //使用内置函数得到光线矢量
                fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb;  //从纹理中获得计算漫反射使用的颜色
                fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(worldNormal,worldLightDir)); //计算漫反射颜色
                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir=normalize(worldLightDir+viewDir);  //计算半程向量
                fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;  //计算环境光照
                
                return fixed4(ambient+diffuse+specular,1.0);


            }
            
            ENDCG
        }
    }
    FallBack "Specular"
}
法线贴图
在顶点的切线空间中计算
Shader "Custom/NormalMap_TangentSpace"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)  //控制整体色调
        _MainTex ("Main Tex", 2D) = "white" {}   //光照贴图
        _BumpMap ("Normal Map",2D)="bump" {}     //法线纹理
        _BumpScale ("Bump Scale",Float)=1.0
        _Specular ("Specular", Color)=(1,1,1,1)
        _Gloss ("Gloss", Range(0,255)) = 10
        
    }
    SubShader
    {
        Pass{
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM
            // Physically based Standard lighting model, and enable shadows on all light types
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            fixed4 _Color;
            fixed4 _Specular;
            float _Gloss;
            sampler2D _MainTex;
            float4 _MainTex_ST;  //纹理的缩放和平移值
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            float _BumpScale;  //控制凹凸程度

            struct a2v{
                float4 vertex: POSITION;
                float3 normal:NORMAL;    
                float4 tangent:TANGENT;  //切线方向
                float4 texcoord:TEXCOORD0;   //_MainTex和_BumpMap 通常使用同一组纹理坐标
            };
            struct v2f{
                float4 pos:SV_POSITION;       //裁剪空间坐标
                float4 uv:TEXCOORD0;        //xy存储光照贴图的纹理坐标，zw存储法线贴图的纹理坐标
                float3 lightDir:TEXCOORD1;  //光照方向
                float3 viewDir:TEXCOORD2;   //视角方向k
            };


            v2f vert(a2v v)
            {
                v2f o;  //顶点着色器输出
                o.pos=UnityObjectToClipPos(v.vertex);
                o.uv.xy=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;  //纹理坐标乘以纹理的缩放加上平移
                o.uv.zw=v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;  //法线贴图坐标乘以缩放加上平移
                //用z轴（法线）叉乘x轴（切线）来计算y轴（副切线）的方向
                float3 binormal=cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
                //构造切线空间到模型空间的变换矩阵
                float3x3 rotation=float3x3(v.tangent.xyz,binormal,v.normal);
                //把光照方向和视角方向变换到切线空间
                o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex));
                o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex));
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {

                fixed3 tangentLightDir=normalize(i.lightDir);  //切线空间下的光照方向
                fixed3 tangentViewDir=normalize(i.viewDir);   //切线空间下的观察方向
                fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw);  //从法线贴图中采样得到切线空间下的法线
                
                fixed3 tangentNormal;
                tangentNormal.xy=(packedNormal.xy*2-1)*_BumpScale;
                tangentNormal.z=sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy))); //z^2=1-(x^2+y^2)
                
                //如果在Unity中把法线纹理的类型设置成Normal_Map，可以使用内置宏:
                //tangentNormal=UnpackNormal(packedNormal);
                //tangentNormal.xy*=_BumpScale
                //tangentNormal.z=sqrt(1.0-saturate(dot((tangentNormal.xy,tangentNormal.xy)))); //z^2=1-(x^2+y^2)

                fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb;  //从纹理中获得计算漫反射使用的颜色
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;  //计算环境光照
                fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(tangentNormal,tangentLightDir)); //在切线空间中计算漫反射颜色
                fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);  //半程向量
                //在切线空间中计算高光
                fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
                
                return fixed4(ambient+diffuse+specular,1.0);


            }
            
            ENDCG
        }
    }
    FallBack "Specular"
}
在世界空间中计算(推荐)
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Custom/NormalMap_WorldSpace"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)  //控制整体色调
        _MainTex ("Main Tex", 2D) = "white" {}   //基本纹理贴图
        _BumpMap ("Normal Map",2D)="bump" {}     //法线纹理
        _BumpScale ("Bump Scale",Float)=1.0    //凹凸程度
        _Specular ("Specular", Color)=(1,1,1,1)
        _Gloss ("Gloss", Range(0,255)) = 10
        
    }
    SubShader
    {
        Pass{
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM
            // Physically based Standard lighting model, and enable shadows on all light types
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            fixed4 _Color;
            fixed4 _Specular;
            float _Gloss;
            sampler2D _MainTex;
            float4 _MainTex_ST;  //纹理贴图的缩放和平移值
            sampler2D _BumpMap;
            float4 _BumpMap_ST;  //法线贴图的缩放和平移值
            float _BumpScale;  

            struct a2v{
                float4 vertex: POSITION;
                float3 normal:NORMAL;    
                float4 tangent:TANGENT;  //切线方向,w分量存储旋向性，用于确定副切线的方向性
                float4 texcoord:TEXCOORD0;   //_MainTex和_BumpMap 通常使用同一组纹理坐标
            };
            struct v2f{
                float4 pos:SV_POSITION;       //裁剪空间坐标
                float4 uv:TEXCOORD0;        //xy存储光照贴图的纹理坐标，zw存储法线贴图的纹理坐标
                float4 TtoW0: TEXCOORD1;    //分开存储切线空间到世界空间的变换矩阵
                float4 TtoW1: TEXCOORD2;
                float4 TtoW2: TEXCOORD3;
                
            };


            v2f vert(a2v v)
            {
                v2f o;  //顶点着色器输出
                o.pos=UnityObjectToClipPos(v.vertex);
                o.uv.xy=v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;  //纹理坐标乘以纹理的缩放加上平移
                o.uv.zw=v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;  //法线贴图坐标乘以缩放加上平移

                float3 worldPos=mul(unity_ObjectToWorld,v.vertex);
                fixed3 worldNormal=UnityObjectToWorldNormal(v.normal);
                fixed3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
                //用z轴（法线）叉乘x轴（切线）来计算y轴（副切线）的方向
                fixed3 worldBinormal=cross(worldNormal,worldTangent) * v.tangent.w;
                //切线空间变换到世界空间的变换矩阵，前三列是切线空间的坐标轴在世界空间下的表达
                //因为只需要变换向量（法线），不需要计算平移，只需要3x3的矩阵, w分量可以用于存储worldPos
                o.TtoW0=float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
                o.TtoW1=float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
                o.TtoW2=float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
                return o;
            }
            fixed4 frag(v2f i):SV_TARGET
            {

                float3 worldPos=float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
                fixed3 lightDir=normalize(UnityWorldSpaceLightDir(worldPos));
                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(worldPos));
                fixed3 bump=UnpackNormal(tex2D(_BumpMap,i.uv.zw));
                bump.xy*=_BumpScale;
                bump.z=sqrt(1.0-saturate(dot(bump.xy,bump.xy)));
                //左乘变换矩阵，等于和每一行的行向量进行点乘,得到世界空间中的法线
                bump=normalize(half3(dot(i.TtoW0.xyz,bump),dot(i.TtoW1.xyz,bump),dot(i.TtoW2.xyz,bump)));
                
                fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb;  //从纹理中获得计算漫反射使用的颜色
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;  //计算环境光照
                fixed3 diffuse=albedo*_LightColor0.rgb*max(0,dot(bump,lightDir)); //计算漫反射颜色
                fixed3 halfDir=normalize(lightDir+viewDir);  //半程向量
                //计算高光
                fixed3 specular=_LightColor0.rgb * _Specular.rgb *pow(max(0,dot(bump,halfDir)),_Gloss);
                return fixed4(ambient+diffuse+specular,1.0);

            }
            ENDCG
        }
    }
    FallBack "Specular"
}

参考

  1. 冯乐乐 《Unity Shader 入门精要》
夜若渊
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
unityshader：水流动效果shader
03-29
u3d场景中用于实现水流动的效果的shader
unity shader实现较完整光照效果
08-25
今天，我们将详细介绍如何使用 Unity Shader 实现较完整的光照效果。 首先，让我们来了解什么是光照。光照是指物体在接受光照时的反射和散射现象。它是计算机图形学中一个重要的概念，能够极大地影响游戏或动画中的...
Unity Shader入门精要 第六章——Unity中的基础光照
buzhengli的博客
07-21 1846
逐像素光照，以每个像素为基础，得到它的法线（可以是对顶点法线插值得到的，也可以是从法线纹理中采样得到的），然后进行光照模型计算，这种在面片之间对顶点法线进行插值的技术称为Phong着色，也被称为Phong插值或法线插值技术，这不同于Phong光照模型。上面两个模型(也叫兰伯特光照模型)有个问题就是，光照没有照射到的地方是全黑的，没有明暗变化，导致背面就像是有个平面一样。与原来的兰伯特光照模型相比，半兰伯特光照模型没有使用max操作来防止n*I的点积为负值，而是进行了一个α倍的缩放和β大小的偏移。
第二十二章 Unity 光照贴图
konkon2012的博客
05-02 3308
unity烘焙 Lightmap 光照贴图，使用 light probe光照探针
【Unity Shader学习】接收并显示光照贴图
凡心所向，素履以往
04-03 1073
Shader "Sbin/Textures/Texture03" { Properties { _MainTex("MainTex",2D) = ""{} } SubShader { Tags { "RenderType"="Opaque" } LOD 200 pass { CGPROGRAM #pragma vertex vert #pragma fragmen...
unityShader采样光照贴图
weixin_36961960的博客
04-30 839
unityShader采样光照贴图 sampler2D _MainTex; float4 _MainTex_ST; sampler2D unity_Lightmap; //光照贴图 float4 unity_LightmapST; //光照贴图的缩放和偏移 v2f vert(appdata_full v){ v2f o; o.vertex = UnityObjectToClipPos(v.vertex); o.uv = TRANSFORM_TEX(v.uv, _MainTe
Shader注释
qq_42126516的博客
09-17 627
表面着色器Surface Shader 光照多了用它 顶点/片元着色器 Vertex/Fragment Shader 固定函数着色器 Fixed Function Shader(弃用 老设备可以用) Shader “jm” {//不用跟文件名保持一致 Properties{ //属性 //属性名 面板名 类型 默认值RGBA _Color(“Color”, Color) = (1,1,1,1) //向量 _Vector(“Vector”,Vector) = (1,2,3,4) //整数 _Int(“
UnityShader 实现3D模型颜色渐变效果
05-11
使用Unity Shader使模型的颜色产生简单的两种颜色过渡的渐变效果。
Unity Shader实现纹理遮罩效果
08-19
在本文中，我们将详细介绍如何使用 Unity Shader 实现纹理遮罩效果。 纹理遮罩是一种常用的图形技术，它可以保护模型中的某些区域不受某些因素的影响。例如，我们可以使用纹理遮罩来控制模型表面的反光强度、颜色、...
Unity 光照与纹理初始项目
最新发布
01-24
Unity 光照与纹理初始项目
Unity Shader : 实现Phong和Blinn-Phong光照模型
weixin_47260762的博客
01-09 2724
Phong光照模型包括几个部分：环境光、漫反射、高光反射（镜面反射）。 在unity进行shader编写时，环境光可以由内置函数直接获取。 漫反射部分定义如下：（来自冯乐乐的书） 其中出现的一些向量如图所示： l是光源方向，r是光的反射方向，n是物体表面法线方向，v是视角方向，也就是相机的方向。 在漫反射计算公式中，clight是光源颜色，mdiffuse是材质的漫反射颜色，核心部分是一个点乘，n dot l，需要注意的是，在使用这些向量之前，需要对它们进行归一化，因为我们需要的只是它的方向，大小并不关
Unity Shader阶段总结——光照、纹理、阴影
memory_MM_forever的博客
06-27 272
Shader "Unity Shaders Book/Common/Bumped Specular" { Properties { _Color ("Color Tint", Color) = (1, 1, 1, 1) _MainTex ("Main Tex", 2D) = "white" {} _BumpMap ("Normal Map", 2D) = "bump" {} _Specular ("Specular Color", Color) = (1, 1, 1, 1) _Glos
unityshader入门精要第五章代码注释
weixin_63637185的博客
03-20 155
如以下代码所示，这章主要知识点是熟悉shaderlab的格式。
【Unity Shader】1.Unity的基本Shader框架学习(颜色，光照，材质)
用01改变世界
07-24 2751
首先说明，博主是一位Shader的初学者，在大学里也是菜鸟一枚，只是对游戏有着热情才开始学习Shader，若有写的不好地方，望各位见谅。。。哈哈哈，废话不多说，开始正题。O(∩_∩)O 效果展示一、基本概念了解 1.学过计算机图形学的同学都知道，计算机图形学中的渲染管线一共有两种：1)固定功能渲染管线 2)可编程渲染管线ps：渲染管线就是计算机绘制图形的过程： 局部坐标系->世界坐标系
《Unity开发实战》——3.4节创建高光纹理贴图
weixin_33896726的博客
07-03 185
本节书摘来自华章社区《Unity开发实战》一书中的第3章，第3.4节创建高光纹理贴图，作者 （爱尔兰）Matt Smith　（巴西）Chico Queiroz，更多章节内容可以访问云栖社区“华章社区”公众号查看 3.4　创建高光纹理贴图有些表面可能既有光滑的区域，又有粗糙的区域，为了达到这个效果，可以使用高光贴图（specular maps）。 3.4....
Unity3D - 发光材质（Emissive Materials）
热门推荐
biezhihua的专栏
08-11 1万+
Emissive Materials
Unity Shader 纹理贴图
ww386362087的博客
07-23 1523
标准光照模型 自发光emissive 环境光ambient 高光反射 specular 漫反射 diffuse 环境光Cambient = Gambient 自发光 标准光照模型使用材质的自发光颜色  全局光照自发光会影响周围物体 漫反射 再漫反射中视角是不重要的，反射是随机的，但是跟入射光线的角度很重要 Cdiffuse = Clight*Mdiffuse MAX (0,n.l) sat...
Unity实现2D动态光照
蛰伏--当你不够强大时，就不要放弃努力
07-18 3152
关于Deferred light / Forward light 了解3d游戏中光照的人，应该很熟悉deferred和forward这两种不同的实现方式。 简而言之，deferred light是以这种方式绘制的： 对每一个场景中的Mesh 将其法线绘制到法线贴图上 将其颜色绘制到颜色贴图上 将其深度绘制到深度贴图上 对每一个灯光，对三张贴图进行采样，绘制到屏幕上。 而fo...
Unity Shader：Projective Texture Mapping
06-02
Projective Texture Mapping 是一种常用的 Shader 技术，可以用来在 Unity 中实现纹理投影效果。它的原理是通过将投影纹理映射到场景物体上，并基于物体的表面法线和光照方向来计算出光照效果，从而实现物体表面的投影纹理效果。 以下是一个简单的 Projective Texture Mapping 的 Shader 示例： ```shader Shader "Custom/ProjectiveTextureMapping" { Properties { _MainTex ("Texture", 2D) = "white" {} _ProjTex ("Projection Texture", 2D) = "white" {} _Intensity ("Intensity", Range(0,1)) = 1 } SubShader { Pass { CGPROGRAM #pragma vertex vert #pragma fragment frag #include "UnityCG.cginc" struct appdata { float4 vertex : POSITION; float3 normal : NORMAL; }; struct v2f { float4 projPos : TEXCOORD0; float3 worldNormal : TEXCOORD1; float4 vertex : SV_POSITION; }; sampler2D _MainTex; sampler2D _ProjTex; float _Intensity; v2f vert (appdata v) { v2f o; o.vertex = UnityObjectToClipPos(v.vertex); o.worldNormal = UnityObjectToWorldNormal(v.normal); o.projPos = ComputeGrabScreenPos(o.vertex); return o; } fixed4 frag (v2f i) : SV_Target { // 计算纹理坐标 float2 projCoord = i.projPos.xy / i.projPos.w; projCoord = 0.5 * (projCoord + 1.0); // 计算投影纹理颜色 fixed4 projColor = tex2D(_ProjTex, projCoord); // 计算漫反射光照 float3 worldNormal = normalize(i.worldNormal); float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz); float intensity = _Intensity * max(0, dot(worldNormal, worldLightDir)); // 计算最终颜色并返回 fixed4 texColor = tex2D(_MainTex, i.uv); fixed4 finalColor = lerp(texColor, projColor, intensity); return finalColor; } ENDCG } } } ``` 这个 Shader 的主要实现思路是，将投影纹理的颜色和物体表面原有的颜色进行插值计算，插值的比例根据光照方向和表面法线来计算。其中，ComputeGrabScreenPos() 函数用于将物体的顶点坐标转换为屏幕坐标，从而计算出纹理坐标。在 Pass 中的 vert 函数中，通过 UnityObjectToWorldNormal() 函数将物体的法线转换为世界坐标系下的法线，从而能够正确计算出光照效果。 使用这个 Shader，将它添加到一个材质中，并将这个材质应用到需要投影纹理的物体上，就可以实现 Projective Texture Mapping 技术了。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值