Unity Shader : 实现Phong和Blinn-Phong光照模型

Phong光照模型包括几个部分：环境光、漫反射、高光反射（镜面反射）。

在unity进行shader编写时，环境光可以由内置变量直接获取。

漫反射部分定义如下：（来自冯乐乐的书）

其中出现的一些向量如图所示：

l是光源方向，r是光的反射方向，n是物体表面法线方向，v是视角方向，也就是相机的方向。

在漫反射计算公式中，clight是光源颜色，mdiffuse是材质的漫反射颜色，核心部分是一个点乘，n dot l，需要注意的是，在使用这些向量之前，需要对它们进行归一化，因为我们需要的只是它的方向，大小并不关心。两个归一化后的向量点乘，是有可能出现负值的，取值范围在（-1，1），我们知道，0表示黑色，1表示白色，其他的颜色则在0到1之间，小于0的颜色值也是黑色，因此做一个max运算，把小于0的部分都变成0。

高光反射部分的计算则如下图所示：

其中，clight是光源颜色，mspecular是高光反射颜色，后面又是一个向量点乘，v dot r，以及做一个max运算，右上角mgloss表示光泽度，是一个次方运算，因为计算出的颜色值是0到1之间，因此进行次方运算时，这个值越大，除了纯白色以外的颜色值都会变小一点，也就显得更黑，相当于是控制高光范围的一个参数。

知道了计算原理后，就可以写出phong模型的shader了：

Shader "Shader/Phong" {
    Properties {
        _MainCol ("漫反射颜色", color) = (1.0, 1.0, 1.0, 1.0)
        _SpecularCol("高光颜色", color) = (1.0, 1.0, 1.0, 1.0)
        _SpecularPow ("高光次幂",range(1, 90)) = 30
    }
    SubShader {
        Tags {
            "RenderType"="Opaque"
        }
        Pass {
            Name "FORWARD"
            Tags {
                "LightMode"="ForwardBase"
            }
            
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            

            //输入参数，注意与开头声明的对应
            uniform float3 _MainCol;
            uniform float3 _SpecularCol;
            uniform float _SpecularPow;
            
            //输入结构
            struct VertexInput {
                float4 vertex : POSITION; //顶点
                float3 normal : NORMAL; //法线
            };

            //输出结构
            struct VertexOutput {
                float4 posCS : SV_POSITION; //裁剪空间下的坐标
                float4 posWS : TEXCOORD0; //世界空间下的坐标
                float3 nDirWS : TEXCOORD1; //法线向量
            };

            //顶点shader
            VertexOutput vert (VertexInput v) {
                VertexOutput o = (VertexOutput)0;
                o.posCS = UnityObjectToClipPos(v.vertex); //顶点转换到裁剪空间
                o.posWS = mul(unity_ObjectToWorld, v.vertex); //顶点位置位置转化到世界空间
                o.nDirWS = UnityObjectToWorldNormal(v.normal); //法线转换到世界空间

                return o;
            }

            //像素shader
            float4 frag(VertexOutput i) : COLOR {
                //准备向量
                float3 nDir = i.nDirWS; //法线向量
                float3 lDir = _WorldSpaceLightPos0.xyz; //光照方向
                float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.posWS); //视角方向，用相机位置-顶点位置就是视角方向
                float3 rDir = normalize(reflect(-lDir, nDir)); //反射方向，使用reflect函数实现，注意由于该函数要求光入射方向要指向交点处，因此对lDir先取反
                //准备点积结果
                float ndotl = dot(nDir, lDir);
                float rdotv = dot(rDir, vDir);
                //光照模型计算
                float3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb; //环境光
                float3 diffuse = _LightColor0.rgb * _MainCol * max(0, ndotl); //漫反射
                float3 specular = _LightColor0.rgb * _SpecularCol * pow(max(0, rdotv), _SpecularPow); //高光
                float3 phong =  ambient + diffuse + specular; //最终颜色

                return float4(phong, 1.0);
            }
            ENDCG

        }
    }
    FallBack "Diffuse"  
}

Blinn-Phong模型相比于Phong模型，不同之处就在于高光计算中使用的是n dot h，其中n是法线方向，h是视角和光照的中间方向。

Blinn-Phong的shader代码如下：

Shader "Shader/Blinn-Phong" {
    Properties {
        _MainCol ("漫反射颜色", color) = (1.0, 1.0, 1.0, 1.0)
        _SpecularCol("高光颜色", color) = (1.0, 1.0, 1.0, 1.0)
        _SpecularPow ("高光次幂",range(1, 90)) = 30
    }
    SubShader {
        Tags {
            "RenderType"="Opaque"
        }
        Pass {
            Name "FORWARD"
            Tags {
                "LightMode"="ForwardBase"
            }
            
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            

            //输入参数，注意与开头声明的对应
            uniform float3 _MainCol;
            uniform float3 _SpecularCol;
            uniform float _SpecularPow;
            
            //输入结构
            struct VertexInput {
                float4 vertex : POSITION; //顶点
                float3 normal : NORMAL; //法线
            };

            //输出结构
            struct VertexOutput {
                float4 posCS : SV_POSITION; //裁剪空间下的坐标
                float4 posWS : TEXCOORD0; //世界空间下的坐标
                float3 nDirWS : TEXCOORD1; //法线向量
            };

            //顶点shader
            VertexOutput vert (VertexInput v) {
                VertexOutput o = (VertexOutput)0;
                o.posCS = UnityObjectToClipPos(v.vertex); //顶点转换到裁剪空间
                o.posWS = mul(unity_ObjectToWorld, v.vertex); //顶点位置位置转化到世界空间
                o.nDirWS = UnityObjectToWorldNormal(v.normal); //法线转换到世界空间

                return o;
            }

            //像素shader
            float4 frag(VertexOutput i) : COLOR {
                //准备向量
                float3 nDir = i.nDirWS; //法线向量
                float3 lDir = _WorldSpaceLightPos0.xyz; //光照方向
                float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.posWS); //视角方向，用相机位置-顶点位置就是视角方向
                float3 hDir = normalize(vDir + lDir); //视角方向和光照方向的中间方向
                //准备点积结果
                float ndotl = dot(nDir, lDir);
                float ndoth = dot(nDir, hDir);
                //光照模型计算
                float3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb; //环境光
                float3 diffuse = _LightColor0.rgb * _MainCol * max(0, ndotl); //漫反射
                float3 specular = _LightColor0.rgb * _SpecularCol * pow(max(0, ndoth), _SpecularPow); //高光
                float3 blinnPhong =  ambient + diffuse + specular; //最终颜色

                return float4(blinnPhong, 1.0);
            }
            ENDCG

        }
    }
    FallBack "Diffuse"  
}

Blinn-Phong模型是为了减小Phong模型的开销而出现的，效果近似于Phong模型，但是在现在硬件的条件下，两者的计算差距已经可以忽略不计了。

这是效果图，下面两组模型中左边的是Phong，右边的是Blinn-Phong。