Silvaco TCAD提取二维矩形区域中的器件信息

提示：文章写完后，目录可以自动生成，如何生成可参考右边的帮助文档

---

前言

Silvaco TCAD中extract语句的用法十分灵活，能够通过改变各种参数来实现对器件信息的提取。对于我们最常生成的二维器件结构而言，提取一维方向的信息可以直接使用tools中的cutline工具进行切线操作，此处不再赘述。本文重点提供一种提取器件二维矩形区域内信息的方法，对于计算如耗尽区内平均雪崩概率等内容可能会有帮助。

---

一、提取二维矩形区域的信息

这里以Silvaco TCAD的示例程序库中diodeex01为例，并将完整程序附在下面，以确保读者能够运行（为了突出重点，已根据个人习惯对程序进行了一些删改）。

go atlas

mesh space.mult=1.0
# 
x.mesh loc=0.00 spac=0.5
x.mesh loc=3.00 spac=0.2
x.mesh loc=5.00 spac=0.25
x.mesh loc=7.00 spac=0.25
x.mesh loc=9.00 spac=0.2
x.mesh loc=12.00 spac=0.5
#
y.mesh loc=0.00 spac=0.1
y.mesh loc=1.00 spac=0.1
y.mesh loc=2.00 spac=0.2
y.mesh loc=5.00 spac=0.4


region num=1 silicon

electr name=anode x.min=5 length=2

electr name=cathode bot

#....   N-epi doping 
doping n.type conc=5.e16 uniform

#....   Guardring doping 
doping p.type conc=1e19 x.min=0  x.max=3  junc=1 rat=0.6 gauss
doping p.type conc=1e19 x.min=9 x.max=12 junc=1 rat=0.6 gauss

#....   N+ doping 
doping n.type conc=1e20 x.min=0 x.max=12 y.top=2 y.bottom=5 uniform

model conmob fldmob srh auger bgn 

method newton
#contact name=anode workf=4.97

solve init

save outf=diodeex01_0.str

extract init infile="diodeex01_0.str"

extract 2d.conc.file impurity="electron conc" material="Silicon" x.min=0.0 x.max=10.0 y.min=0 y.max=5 outf="test_2d.dat"

quit

代码运行结束后，名为“test_2d.dat”的文件会被保存在当前路径下，在Deckbuild的Outputs界面可以看到（将Filter更改为*.dat）。

该文件中存储了所有网格格点的横、纵坐标及提取出的电子浓度值（electron conc），由于数据为n×3的矩阵形式，不能像输出.log的文件那样在TCAD中用使用TonyPlot直接输出，可以使用Excel或Origin等数据处理软件打开，处理我们所得到的数据。

二、文中extract用法的简单介绍

1.导入提取来源文件

在提取器件信息前，需要将包含被提取信息的文件导入：

extract init infile="diodeex01_0.str"

此即导入了"diodeex01_0.str"文件，以便后续对其进行提取操作。

2.导出二维区域感兴趣的信息

将这句command分为五行逐一解读

extract 2d.conc.file \
impurity="electron conc" \
material="Silicon" \
x.min=0.0 x.max=10.0 y.min=0 y.max=5 \
outf="test_2d.dat"

第一行表明我们现在要提取出的信息为二位区域的浓度文件，而这个浓度是什么呢？
第二行里impurity定义的便是这个浓度，比如此处我们想要提取的是电子浓度，便将"electron conc"赋值给impurity，如果我们想要提取电场强度的值，便可以写

impurity="Electric Field" \

总之，如下图中，在Tonyplot能够display的contours均可作为impurity的值来提取。

第三行定义被提取的材料信息，此处材料为Silicon。
第四行便是划定我们要提取的二维区域，通过定义X和Y方向的最大值与最小值，便可以确定出来这一矩形区域了，大致画出我们此处作为示例划定的区域：

第五行，就是给输出的文件进行命名，至此，提取结束，可以通过excel打开路径下的test_2d.dat文件。

三、Excel处理导出的结果

打开Excel软件，并点击打开，如图

点击浏览，找到程序所在的路径，将过滤器改为全部文件，点开test_2d.dat

在文件导入向导中先点击下一步，在【第二步】中将分隔符号选为【空格】，点击完成即可。

导入之后如图，第一列为横坐标，第二列为纵坐标，第三列为impurity所指定的信息。

impurity的默认单位可以参考数据手册，如图：

---

以上内容均为原创，转载请注明出处