使用Silvaco设计构建NMOS晶体管、PNP、NPN双极型晶体管并提取各项工艺及器件参数：半导体器件和工艺模拟

半导体器件和工艺模拟

使用Silvaco构建NMOS晶体管、PNP、NPN双极型晶体管并提取各项工艺及器件参数

一、必做

1. 使用SILVACO软件设计一个NMOS管，要求沟道长度不小于0.8微米，阈值电压在-0.5v 至 1V之间，要说明在工艺中如何调整阈值电压并在模拟结果中有所体现。
2. 工艺模拟过程要求提取S/D结结深、阈值电压、沟道表面掺杂浓度、S/D区薄层电阻等参数。
3. 进行器件模拟，要求得到NMOS输出特性曲线族以及特定漏极电压下的转移特性曲线，并从中提取MOS管的阈值电压和值。
4. 分析各关键工艺步骤对器件性能的影响。

二、选做

1、使用SILVACO软件设计一个PNP管，进行相应的工艺模拟与器件模拟，要求输出Gummel曲线及IC——VCE特性曲线，并调整相关参数，观察并分析各关键工艺步骤对晶体管性能的影响。

2、参考例程3进行氧化工艺模拟：111面，N型材料，掺杂浓度 1016。淀积氮化硅，刻蚀掉部分氮化硅。进行磷离子注入，剂量为3*1015cm-3，注入能量为30kEV.湿氧条件下氧化，温度1100摄氏度，时间4分钟。抽取不同掺杂浓度区域的氧化层厚度，用Tonyplot绘出结构图。

3、模拟磷离子注入，注入能量80Kev,注入剂量分别为1.e14 cm-3、5.e14 cm-3、1.e15 cm-3以及5.e15 cm-3条件下的杂质分布，抽取各条件下掺杂浓度与深度的关系曲线，进行比较。（参考例程ATHENA_IMPLANT: Implant Process Simulation/aniiex05.in/Dose Dependence of P Implants）

4、使用SILVACO软件设计一个肖特基二极管，进行相应的工艺模拟与器件模拟，要求对其正偏特性进行分析，并调整相关参数，观察并分析各关键工艺步骤对晶体管性能的影响。

5、使用SILVACO软件设计一个NPN管，进行相应的工艺模拟与器件模拟，要求输出Gummel曲线及IC——VCE特性曲线，并调整相关参数，观察并分析各关键工艺步骤对晶体管性能的影响。

第一部分 必做：使用Silvaco构建NMOS晶体管并提取各项工艺及器件参数

一．目的：

1、熟练氧化、离子注入与扩散工艺，使用Silvaco软件进行模拟

2、掌握nmos工艺流程。

3、学会用Silvaco软件提取MOS晶体管的各种参数

4、掌握MOS晶体管器件模拟

二．要求：

1.用Anthena构建一个NMOS管，要求沟道长度不小于0.8微米，阈值电压在-0.5v 至 1V之间，要说明在工艺中如何调整阈值电压并在模拟结果中有所体现。

2.工艺模拟过程要求提取S/D结结深、阈值电压、沟道表面掺杂浓度、S/D区薄层电阻等参数。

3.进行器件模拟，要求得到NMOS输出特性曲线族以及特定漏极电压下的转移特性曲线，并从中提取MOS管的阈值电压和β值。

4.分析各关键工艺步骤对器件性能的影响。

三．步骤：

1、启动silvaco软件。

2、创建一个网格并定义衬底的参数。

3、由于本实验运用了cmos工艺，所以先在衬底上做一个p阱，严格定义p阱的浓度，注入能量，以及阱区的推进。

4、生长栅氧化层，严格控制各参数。

diffus time=10 temp=950 dryo2 press=1.00 hcl.pc=3

5、淀积多晶硅，其厚度为0.2um。

6、刻蚀掉x=0.35左面的多晶硅，然后低剂量注入磷离子，形成轻掺杂层，剂量为3e13，能量为20kev。

7、淀积氧化层，然后再进行刻蚀，以进行下一步的源漏区注入。

8、进行源漏砷离子的注入，剂量为4e15，能量为40kev。

9、淀积铝，形成S/D金属接触。

10、进行向右镜像操作，形成完整的nmos结构并定义电极。

11、抽取源漏结深，阈值电压，n+区薄层电阻，沟道表面掺杂浓度，轻掺杂源漏区的薄层电阻等参数。

12、描述输出特性曲线并绘出。

13、描述转移特性曲线并绘出，同时从中提取MOS管的阈值电压和β值。

四、结果及分析

1、工艺图

由图可见，此NMOS沟道长度不小于0.8微米，符合要求。

2、工艺过程：

（1）定义矩形网格：

#定义X网格

line x loc=0 spac=0.1

line x loc=0.2 spac=0.006

line x loc=0.6 spac=0.006

#定义Y网格

line y loc=0.00 spac=0.002

line y loc=0.2 spac=0.005

line y loc=0.5 spac=0.05

line y loc=0.8 spac=0.15

（2）定义初始硅并氧化：100 晶向，作为P 型衬底，用硼掺杂，掺杂浓度为1e14，之后制作栅氧化层：把硅片放在950摄氏度，干氧，一个大气压下掺氯（氯化氢）氧化10分钟，结果如下：

不同的氧化方式或氧化时间等参数的不同会使其氧化层厚度不同，并且不同的氧化方式（例如湿氧氧化与干氧氧化作对比）、不同的氧化温度和时间等因素对衬底杂质再分布也会有不同程度影响，综合比较后，我选择了干氧氧化栅氧化层。

（3）调整阈值电压，离子注入，注入硼离子，剂量为2e12，能量为10KeV：

此掺杂包括后续的掺杂过程均可以使用扩散或离子注入实现。扩散是利用杂质离子的自由扩散实现，它同时存在纵向和横向的扩散，扩散的时间越长，掺杂的深度和宽度都增加，横向效应明显，但在小尺寸工艺中，要求有必要的参杂深度，同时希望很小的横向间距，这时候扩散就很难做到。所以我在这里选择了离子注入，它的掺杂是精确控制的，注入离子的种类、注入深度都可以精确控制，同时几乎没有横向扩散，但是容易产生缺陷，需要退火。

（4）淀积Poly层后进行栅刻蚀:刻蚀掉x=0.35左面的多晶硅，结果如下：

（5）湿氧氧化后进行轻掺杂，轻掺杂使用离子注入，注入磷离子，剂量为3e13，能量为20KeV，之后沉积氧化层再进行干刻蚀，以进行下一步的源漏区注入 ，其结果如下：

（6）进行源漏砷离子的注入，重掺杂，剂量为4e15，能量为40KeV，掺杂完成后进行快速退火，结果如下：

上述掺杂工艺选择离子注入的原因是为了减小横向效应，防止源漏扩散使沟道长度变短。

（7）下面处理漏源极，先刻蚀掉x=0.1以左的氧化层 ，再刻蚀掉一个矩形,把栅极多晶硅上面的氧化层刻蚀掉，以便于之后与金属接触制作电极。我蚀刻掉了（0.357,-0.15）->(0.6,-0.15)->(0.6,-0.3)->(0.357,-0.3)区域内的氧化层，结果如下：

（8）在表面淀积铝之后，刻蚀掉一个矩形区域的铝，留下金属电极。我蚀刻掉了（0.35,0.1）->(0.1,0.1)->(0.1,-0.4)->(0.35,0.4)区域内的铝，结果如下：

（9）进行镜像和电极定义，镜像对称并保存镜像结构后，完整的NMOS如下：

至此，完整的NMOS设计工艺过程结束。

3、器件仿真结果及参数特性分析：

（1）结深： 

结深测量语句：extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

测量结果：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=0.882642 um from top of first Silicon layer X.val=0.1

（2）测量沟道阈值电压

沟道阈值电压测量语句：

extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

测量结果：

EXTRACT> extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

n1dvt=0.953742 V X.val=0.49

（3）沟道表面掺杂浓度

沟道表面掺杂浓度测量语句：

extract name="chan surf conc" surf.conc impurity="Net Doping" \

material="Silicon" mat.occno=1 x.val=0.45

测量结果：

EXTRACT> extract name="chan surf conc" surf.conc impurity="Net Doping"

chan surf conc=8.22657e+020 atoms/cm3

（4）获取S/D区薄层电阻

获取语句：

extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

获取结果：

EXTRACT> #extract the N++ regions sheet resistance

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=40.5223 ohm/square X.val=0.05

（5）NMOS输出特性曲线

上图为该器件仿真 Id-VDS曲线（输出特性曲线）的结果，由图可知：

1、由理论知识得，当栅极电压小于NMOS阈值电压时，没有导电沟道形成，无论VDS取值如何，均不会有漏极电流：图中红色输出曲线是栅压为0.5V时（NMOS截止）的输出曲线。

2、当栅极电压大于NMOS阈值电压时，在栅极下方的衬底会出现反型层，从而形成导电沟道，此时在漏源区加上电压VDS，就会产生漏极电流。

3、当VDS较小时，漏极电流随VDS呈线性增长，此时 MOSFET 工作在线性区。

4、继续增大VDS，一定程度后导电沟道会被夹断，此后Id不再随VDS的增大而变化，Id只与栅极电压VGS有关，此时MOSFET 工作在饱和区。（上方除红色曲线外三条输出曲线分别是栅极电压为1.1V、2.2V、3.3V 时的输出特性曲线，说明 NMOS 的输出特性曲线随栅极电压的不同而变化。）

由仿真结果可知，NMOS输出特性与理论分析相符。

（6）NMOS转移特性曲线

上图为漏极电压VDS恒定时的 Id-VGS 曲线（转移特性曲线），由曲线可以看出：

1、当VDS一定时，栅压很小的时候不存在导电沟道，NMOS截止。

2、随着栅极电压VGS的增大，P型衬底将出现反型层，当VGS大于NMOS阈值电压时，导电沟道出现且宽度变宽，载流子浓度随VGS的增大而增加，VDS呈线性增长。

由仿真结果可以看出， NMOS转移特性与理论分析相符。

（7）提取MOS管的阈值电压

EXTRACT>extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),

abs(i."drain"))))- abs(ave(v."drain"))/2.0)

nvt=0.751552

可见此NMOS阈值电压在-0.5v 至 1V之间，符合要求。

（8）提取参数

1、nxj=0.882642 um 2、n1dvt=0.953742 V

3、chan surf conc=8.22657e+020 atoms/cm3 4、n++ sheet rho=40.5223 ohm/square

5、nvt=0.751552 6、nbeta=0.000173251

4、工艺对器件性能及指标的影响分析：

（1）栅氧化层氧化方式对器件性能及指标的影响：参考标准如上述工艺，使用硅100 晶向作为P 型衬底，用硼掺杂（掺杂浓度为1e14）后，之后制作栅氧化层：把硅片放在950摄氏度，干氧，一个大气压下掺氯（3%氯化氢）氧化10分钟，氧化层和衬底掺杂浓度的结果如下：

上述干氧过程对栅氧化层厚度提取结果如下：

EXTRACT> extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

gateox=122.546 angstroms (0.0122546 um) X.val=0.3

在上述干氧过程基础上后续工艺完成后，整个NMOS输出特性结果如下：

接下来建立湿氧氧化对照组：用控制变量法分析干氧氧化与湿氧氧化对栅氧化层指标的影响：把硅片放在950摄氏度，湿氧，一个大气压下掺氯（3%氯化氢）氧化10分钟，氧化层和衬底掺杂浓度的变化结果如下：

上述湿氧过程对栅氧化层厚度提取结果如下：

EXTRACT> extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

gateox=604.751 angstroms (0.0604751 um) X.val=0.3

可见若在其他参数不变的情况下改变氧化方式为湿氧氧化，其氧化层厚度将增加约6倍，并且湿氧氧化对衬底杂质再分布有较大影响。

若在此湿氧氧化工艺的基础上继续进行后续工序，会影响NMOS阈值电压，从而影响其转移特性曲线，其转移特性曲线变化结果如下：

此NMOS阈值电压提取结果如下：

EXTRACT> extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),

abs(i."drain"))))- abs(ave(v."drain"))/2.0)

nvt=-0.0316666

可见其阈值电压为-0.0316666V，由此可见在湿氧氧化基础上进行后续工艺，会使得此NMOS由增强型NMOS管向耗尽型NMOS管变化，改变了其转移特性。

（2）源漏区离子注入掺杂参数对器件性能及指标的影响：参考标准如上述工艺，在进行源漏砷离子的注入时，剂量为4e15，能量为40KeV，其离子注入工艺结束后杂质分布结果如下：

在上述参数离子注入过程基础上，后续工艺完成后整个NMOS对照组结深测量结果如下：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=0.882642 um from top of first Silicon layer X.val=0.1

对照组源漏区薄层电阻获取结果：

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=40.5223 ohm/square X.val=0.05

接下来建立高能量掺杂的对照组，用控制变量法分析高能量离子注入对NMOS性能指标的影响：在进行源漏砷离子的注入时，剂量为4e15，能量为80KeV（为标准对照组的两倍），其离子注入工艺结束后杂质分布结果如下：

可见源（漏）重掺杂区域相较于对照组深度明显加深，其源漏结深测量结果：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=1.69514 um from top of first Silicon layer X.val=0.1

其源漏区薄层电阻获取结果：

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=26.0693 ohm/square X.val=0.05

可见若在其他参数不变的情况下，进行源漏砷离子的注入时，剂量为4e15，能量为80KeV（为标准对照组的两倍），则NMOS管源漏结深将增大约2倍，并且其源漏区薄层电阻将减小为原来的约1/2。

附录

实验程序

go athena

#定义X网格

line x loc=0 spac=0.1

line x loc=0.2 spac=0.006

line x loc=0.65 spac=0.006

#定义Y网格

line y loc=0.00 spac=0.002

line y loc=0.2 spac=0.005

line y loc=0.5 spac=0.05

line y loc=1.0 spac=0.15

#定义初始硅：100 晶向，作为P 型衬底，用硼掺杂，掺杂浓度为1e14

init silicon c.boron=1e14 orientation=100 space.mul=2 two.d

#制作栅氧化层：把硅片放在950摄氏度，干氧，一个大气压下掺氯（氯化氢）氧化10分钟

diffus time=10 temp=950 dryo2 press=1.00 hcl.pc=3

#抽取栅氧化层厚度

extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

#调整阈值电压，离子注入，注入硼离子

implant boron dose=2e12 energy=10 pearson

#淀积Poly层

depo poly thick=0.25 divi=10

#栅刻蚀:刻蚀掉x=0.35左面的多晶硅

etch poly left p1.x=0.35

#湿氧氧化为轻掺杂做准备

diffuse time=3 temp=900 weto2

#轻掺杂离子注入，注入磷离子，形成轻掺杂层，剂量为3e13，能量为20kev

implant phosphor dose=3e13 energy=20 tilt=0 rotation=0

#沉积氧化层再进行干刻蚀，以进行下一步的源漏区注入

depo oxide thick=0.120 divisions=8

etch oxide dry thick=0.120

#进行源漏砷离子的注入，剂量为4e15，能量为40kev

implant arsenic dose=4.0e15 energy=40 tilt=0 rotation=0

#快速退火

method fermi

diffus time=1 temp=900 nitro press=1.00

#下面处理漏源极

#刻蚀掉x=0.1以左的氧化层

etch oxide left p1.x=0.1

#刻蚀掉一个矩形,把栅极多晶硅上面的氧化层刻蚀掉，我写的下面四句蚀刻掉了（0.357,-0.15）->(0.6,-0.15)->(0.6,-0.3)->(0.357,-0.3)区域内的氧化层

etch oxide start x=0.357 y=-0.15

etch cont x=0.65 y=-0.15

etch cont x=0.65 y=-0.3

etch done x=0.357 y=-0.3

#沉积铝

deposit alumin thick=0.1 div=20

#刻蚀掉一个矩形区域的铝，我写的下面四句蚀刻掉了（0.35,0.1）->(0.1,0.1)->(0.1,-0.4)->(0.35,0.4)区域内的铝

etch alumin start x=0.35 y=0.1

etch cont x=0.1 y=0.1

etch cont x=0.1 y=-0.4

etch done x=0.35 y=-0.4

#接下来进行结果分析的提取，查看器件特性

#Extract design parameters

#extract final S/D Xj

extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

#extract the N++ regions sheet resistance

extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

#extract the sheet rho under the spacer,of the LDD region

extract name="ldd sheet rho" sheet.res material="Silicon"

mat.occno=1 x.val=0.3 region.occno=1

#extract the surface conc under the channel.

extract name="chan surf conc" surf.conc impurity="Net Doping"

material="Silicon" mat.occno=1 x.val=0.45

#extract a curve of conductance versus bias.

extract start material="Polysilicon" mat.occno=1

bias=0.0 bias.step=0.2 bias.stop=2 x.val=0.45

extract done name="sheet cond v bias"

curve(bias,1dn.conduct material="Silicon" mat.occno=1 region.occno=1)

outfile="extract.dat"

#extract the long chan Vt

extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

#接下来进行镜像和电极定义

#镜像对称

structure mirror right

#保存镜像结构，完整的nMOS

structure outfile=mirror.str

electrode name=gate x=0.5 y=-0.2

electrode name=source x=0.05 y=0

electrode name=drain x=1.30 y=0

electrode name=substrate backside

#工艺仿真器件制作完成，保存到我的LiTianhao-NMOS1_athena.str文件中

structure outfile=LiTianhao-NMOS1_athena.str

tonyplot LiTianhao-NMOS1_athena.str

#接下来进行器件物理特性分析，先求栅压为1.1V,2.2V,3.3V时，漏电流与漏电压的关系，即进行CVT分析

go atlas

# 定义栅极功能，N型接触

contact name=gate n.poly

# 定义栅氧化层正电荷为3e10

interface qf=3e10

# 使用CVT模型分析 MOS

models cvt srh print numcarr=2

# 设置栅极偏置，同时设置Vds=0V

solve init

solve vgate=0.5 outf=solve_tmp0_LiTianhao

solve vgate=1.1 outf=solve_tmp1_LiTianhao

solve vgate=2.2 outf=solve_tmp2_LiTianhao

solve vgate=3.3 outf=solve_tmp3_LiTianhao

#加载文件和步进Vd

load infile=solve_tmp0_LiTianhao

log outf=LiTianhao_MOSLEX_0.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

load infile=solve_tmp1_LiTianhao

log outf=LiTianhao_MOSLEX_1.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3



load infile=solve_tmp2_LiTianhao

log outf=LiTianhao_MOSLEX_2.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3



load infile=solve_tmp3_LiTianhao

log outf=LiTianhao_MOSLEX_3.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

# 提取最大漏极电流和β值（斜率）

extract name="nidsmax" max(i."drain")

extract name="sat_slope" slope(minslope(curve(v."drain",i."drain")))

tonyplot -overlay -st LiTianhao_MOSLEX_0.log LiTianhao_MOSLEX_1.log LiTianhao_MOSLEX_2.log LiTianhao_MOSLEX_3.log

#接下来进行Vt 测试：返回 Vt、Beta 和 θ

go atlas

#建立材料模型

models cvt srh print

contact name=gate n.poly

interface qf=3e10

method gummel newton

solve init

# 漏极给偏置电压

solve vdrain=0.1

# 栅压步进

log outf=LiTianhao-Vt.log master

solve vgate=0 vstep=0.25 vfinal=3.0 name=gate

save outf=LiTianhao-Vt.str

tonyplot LiTianhao-Vt.log

#提取器件参数

extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),abs(i."drain"))))- abs(ave(v."drain"))/2.0)

extract name="nbeta" slope(maxslope(curve(abs(v."gate"),abs(i."drain"))))* (1.0/abs(ave(v."drain")))

extract name="nsubvt" 1.0/slope(maxslope(curve(abs(v."gate"),log10(abs(i."drain")))))

quit

第二部分 选做：使用Silvaco构建PNP、NPN双极型晶体管并提取各项工艺及器件参数

选做一：使用SILVACO软件设计一个PNP管，进行相应的工艺模拟与器件模拟，要求输出Gummel曲线及IC——VCE特性曲线，并调整相关参数，观察并分析各关键工艺步骤对晶体管性能的影响。

一、用工艺软件ATHENA制作的PNP基本结构：

二、PNP型三极管Gummel曲线：

三、PNP型三极管共射极输出特性曲线：

四、特性分析：

由图可知，PNP型三极管基极导通电压Vbe约为-0.1V。三极管工作在放大状态时Vbe约为-0.1V到-0.5V之间。同时从输出特性曲线可知，当管子饱和时，饱和管压降较小,Vces 约为-0.6V。它与NPN 型硅三极管相比,不仅电压、电流方向不同，而且导通电压数值较小。利用这些特点，可以很容易地在电路中区分出PNP型三极管。

五、工艺对器件性能及指标的影响分析：

（1）是否进行退火对器件性能及指标的影响：参考标准：在工艺过程中进行基区退火，发射区退火，接触区退火，在退火的基础上完成后续工艺后，整个PNP双极型晶体管的杂质浓度分布情况如下：

参照组Gummel曲线结果如下：

参照组共射极输出特性结果如下：

接下来建立全程不进行退火处理的对照组：用控制变量法分析全程不做任何退火处理的PNP双极型晶体管特性，其杂质浓度分布情况的变化结果如下：

上述对照组全程不做任何退火处理的PNP双极型晶体管Gummel曲线结果如下：

PNP共射极输出特性结果如下：

由结果可见，由于往半导体中注入杂质离子时，高能量的入射离子会与半导体晶格上的原子碰撞，使一些晶格原子发生位移，结果造成大量的空位，会使得注入区中的原子排列混乱或者变成为非晶区。而在其他参数不变的情况下，若不选择退火处理，将会使PNP双极型晶体管各结处半导体无法恢复晶体结构，也无法消除缺陷，会使得其放大区变窄，放大区输出特性变差，管子很容易进入饱和区。

六、附录：实验程序与详细注释：

go athena

#定义网格

line x loc=0.0 spacing=0.03

line x loc=0.2 spacing=0.02

line x loc=0.24 spacing=0.01

line x loc=0.3 spacing=0.015

line x loc=0.8 spacing=0.15



line y loc=0.0 spacing=0.01

line y loc=0.1 spacing=0.01

line y loc=0.4 spacing=0.02

line y loc=0.5 spacing=0.06

line y loc=1.0 spacing=0.15



#衬底掺杂硼，浓度为2e16

init c.boron=2e16



# 基区注入磷离子

implant phos energy=100 dose=8e13



# 基区退火

diffuse time=5 temp=900



# 淀积多晶硅栅厚度为0.3，设置10个网格

deposit poly thick=0.3 divisions=6 min.space=0.05

# 多晶掺杂 杂质为bf2 使用剂量为3e15 能量35kev

implant bf2 dose=3e15 energy=35

# 从x=0.2um到右边的多晶硅被刻蚀

etch poly right p1.x=0.2

# 放宽网格

relax y.min=.5

relax x.min=0.4



# 发射区退火

method compress fermi

diffuse time=45 temp=900 nitrogen



# 发射区离子注入

implant phos dose=2e14 energy=70



# 沉积氧化层

deposit oxide thick=0.3 divisions=10 min.space=0.1



# 刻蚀氧化层

etch oxide dry thick=0.3



# N型离子重掺杂后进行接触区退火

implant arsenic dose=1e15 energy=50

diffuse time=30 temp=900 nitrogen



# 在接触区淀积铝之后反刻铝

deposit alum thick=0.05 div=2

etch alum start x=0.16 y=-4

etch continue x=0.16 y=0.2

etch continue x=0.6 y=0.2

etch done x=0.6 y=-4

# 命名电极

electrode x=0.0 name=emitter

electrode x=0.7 name=base

electrode backside name=collector

# 提取结深

extract name="EB_xj" xj material="Silicon" mat.occno=1 x.val=0.1 junc.occno=1

extract name="BC_xj" xj material="Silicon" mat.occno=1 x.val=0.1 junc.occno=2

extract name="base_width" $BC_xj - $EB_xj

#提取一维电气参数

extract name="base_rho" n.sheet.res material="Silicon" mat.occno=1 x.val=0.1 region.occno=2 extract name="poly_emitter_rho" p.sheet.res material="Polysilicon" mat.occno=1 x.val=0.1 region.occno=1 semi.poly

#保存最终结构在LiTianhao-PNPBJT.str中

structure outfile=LiTianhao-PNPBJT.str

tonyplot LiTianhao-PNPBJT.str

#接下来进行器件特性模拟

#Gummel Plot 测试

go atlas

# 设置材料和模型参数

material material=Polysilicon taun0=1e-9 taup0=1e-9 mun=40 mup=2

material material=Silicon taun0=5e-6 taup0=5e-6

models

models material=Silicon bipolar print

models material=Polysilicon srh



#提供零偏压下势能和载流子浓度初始值

solve init

method newton autonr trap

solve prev

#设置集电极电压，基极电压从-0.1到-0.4变化，-0.1步进

solve vcollector=-2

solve vbase=-0.1 vstep=-0.1 vfinal=-0.4 name=base

log outf=LiTianhao-PNPBJT_0.log

solve vbase=-0.4 vstep=-0.05 vfinal=-1.0 name=base ac freq=1e6 aname=base

# 提取各种参数

extract name="peak collector current" max(abs(i."collector"))

extract name="peak gain" max(i."collector"/ i."base")

extract name="max fT" max(g."collector""base"/(2*3.1415*c."base""base"))

tonyplot LiTianhao-PNPBJT_0.log

# IC/VCE （输出特性曲线）测试

go atlas

material material=Polysilicon taun0=1e-9 taup0=1e-9 mun=40 mup=2

material material=Silicon taun0=5e-6 taup0=5e-6

models

models material=Silicon bipolar print

models material=Polysilicon srh



solve init

solve vbase=-0.025

solve vbase=-0.05

solve vbase=-0.1 vstep=-0.1 vfinal=-0.7 name=base

# 设置边界条件

contact name=base current

# 保存基极偏置电流的恒定初始值

solve ibase=-1.e-6 outf=LiTianhao-PNPBJT_1.str master

solve ibase=-2.e-6 outf=LiTianhao-PNPBJT_2.str master

solve ibase=-3.e-6 outf=LiTianhao-PNPBJT_3.str master

solve ibase=-4.e-6 outf=LiTianhao-PNPBJT_4.str master

solve ibase=-5.e-6 outf=LiTianhao-PNPBJT_5.str master

# 加载到每个初始基极电流文件和步进 VCE

load inf=LiTianhao-PNPBJT_1.str master

log outf=LiTianhao-PNPBJT_1.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

load inf=LiTianhao-PNPBJT_2.str master

log outf=LiTianhao-PNPBJT_2.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector



load inf=LiTianhao-PNPBJT_3.str master

log outf=LiTianhao-PNPBJT_3.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector



load inf=LiTianhao-PNPBJT_4.str master

log outf=LiTianhao-PNPBJT_4.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector



load inf=LiTianhao-PNPBJT_5.str master

log outf=LiTianhao-PNPBJT_5.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector



# 提取峰值电流和β值

extract name="pnp_max_ic_mA" max(abs(i."collector"))*1.0e+3

extract name="pnp_lin_slope" slope(maxslope(curve(v."collector",i."collector")))

extract name="pnp_sat_slope" slope(minslope(curve(v."collector",i."collector")))

tonyplot -overlay LiTianhao-PNPBJT_5.log LiTianhao-PNPBJT_4.log LiTianhao-PNPBJT_3.log LiTianhao-PNPBJT_2.log LiTianhao-PNPBJT_1.log

quit

选做二：使用SILVACO软件设计一个NPN管，进行相应的工艺模拟与器件模拟，要求输出Gummel曲线及IC——VCE特性曲线，并调整相关参数，观察并分析各关键工艺步骤对晶体管性能的影响。

一、用工艺软件ATHENA制作的NPN基本结构：

二、NPN型三极管Gummel曲线：

三、NPN型三极管共射极输出特性曲线：

四、特性分析：

由图可知，当Ib改变时，Ic和Vce的关系是一组平行的曲线族，并有截止、放大、饱和三个工作区。

1、截止区：此时晶体管的集电结处于反偏，发射结电压Vbe＜0处于反偏，由于Ib＝0，在反向饱和电流可忽略的前提下，Ic=βIb也等于0，晶体管无电流的放大作用。

2、放大区：工作在放大区的三极管有电流的放大作用，此时三极管的发射结正偏，集电结反偏，由输出特性曲线可见，当Ib等量变化时，Ic几乎也按一定比例等距离平行变化，此时三极管可近似看做一个输出电流Ic受Ib控制的受控电流源。

3、饱和区：当集电极电流Ic增大时，Vce=Vcc-Rc将下降，对于硅管，当Vce 降低到小于0.7V时，集电结进入正向偏置的状态，集电极吸引电子的能力将下降，此时即使Ib再增大，Ic也几乎不再增大了，三极管失去了电流放大作用。这种状态下，三极管为饱和状态。

通过上述两个选做题的实践与分析可看出，NPN型三极管的输出特性曲线和PNP型三极管的输出特性曲线是一组关于原点对称的图象。它们电压、电流方向不同，而且PNP三极管导通电压数值较小，利用这些特点可以实现特殊要求的电路。

五、工艺对器件性能及指标的影响分析：

（1）改变掺杂类型对NPN双极型晶体管特性的影响：参考标准：NPN双极型晶体管使用欧姆区掺杂，掺杂时使用高斯分布，在此基础上完成后续工艺后，整个NPN双极型晶体管的杂质浓度分布情况如下：

参照组Gummel曲线结果如下：

参照组共射极输出特性结果如下：

接下来建立将发射区（N型）高斯掺杂的结深扩大十倍的对照组：用控制变量法分析将发射区（N型）高斯掺杂的结深扩大十倍，即：doping reg=1 gauss n.type conc=5e19 peak=0.0 junct=0.5（参照组为0.05） x.right=0.8，其杂质浓度分布情况的变化结果如下：

上述将发射区掺杂结深扩大十倍的NPN双极型晶体管Gummel曲线结果如下：

共射极输出特性结果如下：

由结果可见，对于NPN型双极型晶体管，为了获得尽可能大的放大倍数，发射区浓度需要很大，以便可以发射足够多的载流子。而通过上述对照组可知，将发射区高斯掺杂的结深扩大，会使其发射区掺杂浓度变大，进而使得放大区输出特性曲线斜率变大，意味着NPN管的放大倍数变大。因此，需要提高NPN晶体管的放大倍数时，可以通过增大其发射区结深与掺杂浓度实现。

六、附录：实验程序与详细注释：

go atlas

# 建立网格

mesh

x.m l=0 spacing=0.15

x.m l=0.8 spacing=0.15

x.m l=1.0 spacing=0.03

x.m l=1.5 spacing=0.12

x.m l=2.0 spacing=0.15

y.m l=0.0 spacing=0.006

y.m l=0.04 spacing=0.006

y.m l=0.06 spacing=0.005

y.m l=0.15 spacing=0.02

y.m l=0.30 spacing=0.02

y.m l=1.0 spacing=0.12

#定义发射区，集电区，基区三个区域，同时分析代码：欧姆区掺杂（因为电极还要做重掺杂才可以做成欧姆接触，所以做欧姆接触需要掺杂）

region num=1 silicon

electrode num=1 name=emitter left length=0.8

electrode num=2 name=base right length=0.5 y.max=0

electrode num=3 name=collector bottom

#掺杂：高斯分布（离子注入时均匀掺杂突变结，实际情况是缓变结。）

doping reg=1 uniform n.type conc=5e15

doping reg=1 gauss n.type conc=1e18 peak=1.0 char=0.2

doping reg=1 gauss p.type conc=1e18 peak=0.05 junct=0.15

doping reg=1 gauss n.type conc=5e19 peak=0.0 junct=0.05 x.right=0.8

doping reg=1 gauss p.type conc=5e19 peak=0.0 char=0.08 x.left=1.5

#工艺仿真器件制作完成，保存到我的LiTianhao-BJT_athena.str文件中

save outf=LiTianhao-BJT_athena.str

tonyplot LiTianhao-BJT_athena.str

#接下来进行器件特性仿真：

models conmob fldmob consrh auger print

contact name=emitter n.poly surf.rec

# Gummel plot仿真

solve init

method newton autonr trap

solve vcollector=0.025

solve vcollector=0.1

solve vcollector=0.25 vstep=0.25 vfinal=2 name=collector

solve vbase=0.025

solve vbase=0.1

solve vbase=0.2

log outf= LiTianhao-BJT_0.log

solve vbase=0.3 vstep=0.05 vfinal=1 name=base

tonyplot LiTianhao-BJT_0.log

#IC/VCE仿真，此时基极电流恒定

#偏置基极

log off

solve init

solve vbase=0.025

solve vbase=0.05



solve vbase=0.1 vstep=0.1 vfinal=0.7 name=base



#定义基极为电流边界

contact name=base current



#将基极偏置到不同的电流值

solve ibase=1.e-6

save outf=LiTianhao-BJT_1.str master

solve ibase=2.e-6

save outf=LiTianhao-BJT_2.str master

solve ibase=3.e-6

save outf=LiTianhao-BJT_3.str master

solve ibase=4.e-6

save outf=LiTianhao-BJT_4.str master

solve ibase=5.e-6

save outf=LiTianhao-BJT_5.str master

#载入不同基极电流,偏置集电极

load inf=LiTianhao-BJT_1.str master

log outf=LiTianhao-BJT_1.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector



load inf=LiTianhao-BJT_2.str master

log outf=LiTianhao-BJT_2.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector



load inf=LiTianhao-BJT_3.str master

log outf=LiTianhao-BJT_3.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector



load inf=LiTianhao-BJT_4.str master

log outf=LiTianhao-BJT_4.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector



load inf=LiTianhao-BJT_5.str master

log outf=LiTianhao-BJT_5.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector



#输出曲线族

tonyplot -overlay LiTianhao-BJT_1.log LiTianhao-BJT_2.log LiTianhao-BJT_3.log LiTianhao-BJT_4.log LiTianhao-BJT_5.log



quit