HDLbits答案更新系列13（3.2.5 Finite State Machines 3.2.5.10 Lemmings 1等）

最新推荐文章于 2022-04-09 22:38:57 发布
最新推荐文章于 2022-04-09 22:38:57 发布
阅读量5.4k 收藏 6
点赞数 12
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/wangkai_2019/article/details/106385817
版权

目录

前言

3.2.5 Finite State Machines

3.2.5.10 Lemmings 1（Lemmings1）

3.2.5.11 Lemmings 2（Lemmings2）

3.2.5.12 Lemmings 3（Lemmings3）

3.2.5.13 Lemmings 4（Lemmings4）

结语

HDLbits网站链接

前言

今天更新几道题目，这几道题目是旅鼠游戏，这个游戏层层递进，状态机的思想体现地淋漓尽致，希望大家可以做一做，很有趣。

3.2.5 Finite State Machines

3.2.5.10 Lemmings 1（Lemmings1）

Lemmings.gif

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    output walk_left,
    output walk_right); //  

    parameter LEFT=1'b0, RIGHT=1'b1;
    reg state, next_state;
    
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            state <= LEFT;
        end
        else begin
            state <= next_state;
        end
    end

    always @(*) begin
        case(state)
            LEFT:begin
                if(bump_left)begin
                    next_state = RIGHT;
                end
                else begin
                    next_state = LEFT;
                end
            end
            RIGHT:begin
                if(bump_right)begin
                    next_state = LEFT;
                end
                else begin
                    next_state = RIGHT;
                end
            end
        endcase
    end

    // Output logic
    assign walk_left = (state == LEFT);
    assign walk_right = (state == RIGHT);

endmodule

这道题目比较容易，旅鼠只有两种状态，向左走或者向右走，如果碰到障碍物，它将切换方向，也就是如果在左侧撞到，它将会朝右走，如果在右侧撞到，将会向左走。题目要求moore型状态机实现，应该没什么难度。

3.2.5.11 Lemmings 2（Lemmings2）

Lemmings2.gif

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    output walk_left,
    output walk_right,
    output aaah ); 
    
    parameter LEFT = 2'd0, RIGHT = 2'd1, GROUND_LEFT = 2'd2, GROUND_RIGHT = 2'd3;
    reg	[1:0]	current_state;
    reg [1:0]	next_state;
    
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            current_state <= LEFT;
        end
        else begin
            current_state <= next_state;
        end
    end
    
    always@(*)begin
        case(current_state)
            LEFT:begin
                next_state = ground ? (bump_left ? RIGHT : LEFT) : GROUND_LEFT;
            end
            RIGHT:begin
                next_state = ground ? (bump_right ? LEFT : RIGHT) : GROUND_RIGHT;
            end
            GROUND_LEFT:begin
                next_state = ground ? LEFT : GROUND_LEFT;
            end
            GROUND_RIGHT:begin
                next_state = ground ? RIGHT : GROUND_RIGHT;
            end
            default:begin
                next_state = LEFT;
            end
        endcase
    end    
    
    assign walk_left = (current_state == LEFT);
    assign walk_right = (current_state == RIGHT);
    assign aaah = (current_state == GROUND_LEFT || current_state == GROUND_RIGHT);
    
    /*
    //second way
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            aaah <= 1'b0;
        end
        else begin
            aaah <= ~ground;
        end
    end
    */

endmodule

这道题目相比第一道题，多加了一个掉落状态，如果ground为1，旅鼠将会发出大叫并且跌落。这里的旅鼠大叫信号（aaah）有两种实现方式，一种就是用状态机输出，另一种是直接将ground取反，但是不建议第二种方式，从作者的题意来看，要根据状态决定输出。

3.2.5.12 Lemmings 3（Lemmings3）

Lemmings3.gif

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 
    
    parameter LEFT = 4'd0, RIGHT = 4'd1, GROUND_LEFT = 4'd2, GROUND_RIGHT = 4'd3;
    parameter DIGGING_LEFT = 4'd4, DIGGING_RIGHT = 4'd5;
    reg	[3:0]	current_state;
    reg [3:0]	next_state;
    
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            current_state <= LEFT;
        end
        else begin
            current_state <= next_state;
        end
    end
    
    always@(*)begin
        case(current_state)
            LEFT:begin
                next_state = ground ? (dig ? DIGGING_LEFT : (bump_left ? RIGHT : LEFT)) : GROUND_LEFT;
            end
            RIGHT:begin
                next_state = ground ? (dig ? DIGGING_RIGHT : (bump_right ? LEFT : RIGHT)) : GROUND_RIGHT;
            end
            GROUND_LEFT:begin
                next_state = ground ? LEFT : GROUND_LEFT;
            end
            GROUND_RIGHT:begin
                next_state = ground ? RIGHT : GROUND_RIGHT;
            end
            DIGGING_LEFT:begin
                next_state = ground ? DIGGING_LEFT : GROUND_LEFT;
            end
            DIGGING_RIGHT:begin
                next_state = ground ? DIGGING_RIGHT : GROUND_RIGHT;
            end
            default:begin
                next_state = LEFT;
            end
        endcase
    end    
    
    assign walk_left = (current_state == LEFT);
    assign walk_right = (current_state == RIGHT);
    assign digging = (current_state == DIGGING_LEFT || current_state == DIGGING_RIGHT);
    assign aaah = (current_state == GROUND_LEFT || current_state == GROUND_RIGHT);
    
    /*
    //second way
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            aaah <= 1'b0;
        end
        else begin
            aaah <= ~ground;
        end
    end
    */

endmodule

这道题目花了我不少时间，主要在于状态的增加我没有理清楚。题目中作者说如果旅鼠在地面上（ground = 1）并且挖掘信号为1，则它可以开始挖洞，一直挖，直到把地都挖穿了（ground = 0），此时，旅鼠就掉下去了，并且发出大叫。对于大叫信号，和上一道题一样，有两种写法，建议用第一种。大家好好体会一下这道题目。

3.2.5.13 Lemmings 4（Lemmings4）

Lemmings4.gif

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 
    
    parameter LEFT = 4'd0, RIGHT = 4'd1, GROUND_LEFT = 4'd2, GROUND_RIGHT = 4'd3;
    parameter DIGGING_LEFT = 4'd4, DIGGING_RIGHT = 4'd5, SPLATTER = 4'd6, AAAH_END = 4'd7;
    reg	[3:0]	current_state;
    reg [3:0]	next_state;
    
    
    reg [4:0]	counter;
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            counter <= 5'd0;
        end
        else if(next_state == GROUND_LEFT || next_state == GROUND_RIGHT)begin
            counter <= counter + 1'b1;
        end
        else begin
            counter <= 5'd0;
        end
    end
    
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            current_state <= LEFT;
        end
        else begin
            current_state <= next_state;
        end
    end
    
    always@(*)begin
        case(current_state)
            LEFT:begin
                next_state = ground ? (dig ? DIGGING_LEFT : (bump_left ? RIGHT : LEFT)) : GROUND_LEFT;
            end
            RIGHT:begin
                next_state = ground ? (dig ? DIGGING_RIGHT : (bump_right ? LEFT : RIGHT)) : GROUND_RIGHT;
            end
            GROUND_LEFT:begin
                next_state = ground ? LEFT : (counter == 5'd20 ? SPLATTER : GROUND_LEFT);
            end
            GROUND_RIGHT:begin
                next_state = ground ? RIGHT : (counter == 5'd20 ? SPLATTER : GROUND_RIGHT);
            end
            DIGGING_LEFT:begin
                next_state = ground ? DIGGING_LEFT : GROUND_LEFT;
            end
            DIGGING_RIGHT:begin
                next_state = ground ? DIGGING_RIGHT : GROUND_RIGHT;
            end
            SPLATTER:begin
                next_state = ground ? AAAH_END : SPLATTER;
            end
            AAAH_END:begin
                next_state = AAAH_END;
            end
            default:begin
                next_state = LEFT;
            end
        endcase
    end    
    
    assign walk_left = (current_state == LEFT);
    assign walk_right = (current_state == RIGHT);
    assign digging = (current_state == DIGGING_LEFT || current_state == DIGGING_RIGHT);
    assign aaah = (current_state == GROUND_LEFT || current_state == GROUND_RIGHT || current_state == SPLATTER);   

endmodule

这道题目真是作者又加了一个输出，如果旅鼠跌落的时间太久（大于20个周期），旅鼠就挂了，所以这里需要一个计数器，来计算旅鼠跌落的时间，大家注意，这里的计数器和平常的计数器不太一样，这里计数器的加1条件是当旅鼠开始跌落起计时，如果计数到20个周期，旅鼠就完蛋了...这里的大叫信号只能采用博主答案中的这种方式，没有第二种方式了。建议大家先不要看答案，先自己做一做，这几道题目真是非常有意思。

结语

今天更新这几道旅鼠的题目吧，不知道为啥，每次都把旅鼠打成竹鼠......我也很无奈.....好啦，还是那句老话，如果代码有错误的地方，欢迎大家指出来，我一定尽快改正。

HDLbits网站链接

https://hdlbits.01xz.net/wiki/Main_Page

 

wangkai_2019
关注
  • 12
    点赞
  • 踩
  • 6
    收藏
    觉得还不错? 一键收藏
  • 15
    评论
HDLbits答案更新系列10（3.2 Sequential Logic 3.2.4 More Circuits）
小k的博客
05-23 5353
今天更新一个小节内容，第三部分中Sequential Logic中的More Circuits，其中有一道题目是康威生命游戏，这道题目还是有一定难度的，大家可以去尝试做一下。希望能和大家一起学习，共同进步。
HDLbits答案更新系列9（3.2 Sequential Logic 3.2.3 Shift Registers）
小k的博客
05-22 9085
今天更新一个小节内容，第三部分中Sequential Logic中的Shift Registers，里面涉及到线性反馈移位寄存器和查找表等， 希望大家可以掌握。我也希望能和大家一起学习，共同进步~
Lemmings_HDLbits(旅鼠游戏——基于Verilog描述的有限状态机简单小游戏)
NJUzzf98的博客
04-09 4015
旅鼠游戏中的动物行为很简单 ，我们将使用有限状态机FSM对其进行建模。
HDLBits刷题合集—17 Finite State Machines-3
GitHDL的博客
07-26 1012
HDLBits刷题合集—17 Finite State Machines-3 HDLBits-133 Fsm onehot Problem Statement 给定以下具有1个输入和2个输出的状态机： 假设此状态机使用独热编码，其中state[0]至state[9]分别对应于状态S0至S9。 除非另有说明，否则输出为零。 实现状态机的状态转换逻辑和输出逻辑部分（但不实现状态触发器）。 你将给定state[9：0]中的当前状态，并且必须产生next_state [9：0]和两个输出。通过假设独热编码，通过检验
HDLbits答案更新系列11（3.2 Sequential Logic 3.2.5 Finite State Machines 3.2.5.1 Simple FSM 1等）
小k的博客
05-25 7526
今天终于来到了状态机部分的内容，对于这部分内容博主并不是每道题目都那么顺利就解决了，有些题目博主尝试了很多次，希望大家也可以去尝试一下，同时也希望能和大家一起学习，共同进步~
HDLBits刷题之：Lemmings1-3
qq_43156536的博客
01-17 688
Lemmings1： The game Lemmings involves critters with fairly simple brains. So simple that we are going to model it using a finite state machine. In the Lemmings’ 2D world, Lemmings can be in one of two states: walking left or walking right. It will switch d
SpringBoot3.2.x微服务架构及单架构版本框架源码
最新发布
04-06
SpringBoot 3.2.x 是一个流行的Java框架，用于快速开发高效、生产就绪的应用程序。这个框架基于Spring Framework，简化了Spring应用的初始搭建以及开发过程，通过内嵌的Tomcat服务器，使得应用程序无需额外配置即可...
安华金和应用系统安全审计系统 AAS V3.2.2.5-1 用户手册
08-29
安华金和应用系统安全审计系统 AAS V3.2.5-1 用户手册 安华金和应用系统安全审计系统 AAS V3.2.2.5-1 用户手册是北京安华金和科技有限公司开发的应用系统安全审计系统的用户手册。该手册详细介绍了 AAS V3.2.2.5-1 ...
子项目3.2工资等级制度 子任务3.2.5岗位职能工资制 .pdf
03-02
子项目3.2工资等级制度 子任务3.2.5岗位职能工资制 .pdf
ceph-ansible-3.2.5-1.el7.noarch.rpm
12-09
官方离线安装包，亲测可用
openstack-java-client-3.2.5-1.el7.noarch.rpm
01-16
官方离线安装包，测试可用。请使用rpm -ivh [rpm完整包名] 进行安装
HDLbits答案1
weixin_41543509的博客
03-16 456
目录 1. 入门 1.1 入门 1.2 输出零 2. 基本语言 2.1 简易电路 2.2 四线 2.3 逆变器 2.4 与门 2.5 或非门 2.6 XNOR门 2.7 宣告电线 2.8 7458芯片 1.入门 1.1 入门 module top_module (one); output one; assign one=1’b1; endmodule 1.2 输出零 module top_module(zero); output zero; assign zero=1’b0; endmodule `` 2.
HDLbits答案更新系列12（3.2.5 Finite State Machines 3.2.2.5 Simple state transitions 3等 ）
小k的博客
05-26 7196
今天更新状态机部分的5道题目，其中的重点是对one-hot编码的理解。希望能和大家一起学习，共同进步~
HDLbits答案更新系列18（3.2.5 Finite State Machines 3.2.5.27 Q6b: FSM next-state logic等）
小k的博客
06-02 4266
今天更新状态机小节的最后几道题目，其中最后一道题需要重点去理解，这个小节的内容终于完结啦~~~状态机小节是整个网站习题的重头戏，基本上难题都在这里，大家可以试着多用几种方法去完成。希望能和大家一起努力，共同进步~
verilog练习：hdlbits网站上的做题笔记（6）
杰之行的博客
02-13 3483
前言 之前的文章《如何学习verilog，如何快速入门？》中提到了verilog学习，推荐了一个可以练习的网站：hdlbits网站，那自己也玩玩这个网站。 这篇文章，是接着《verilog练习：hdlbits网站上的做题笔记（5）》写的！ 3.2.5 Finite State Machines 3.2.5.1 Simple FSM 1 (asynchronous reset) This is a Moore state machine with two states, one input,
HDLbits系列解题分析
weixin_41102001的博客
08-03 1644
HDLbits sequential circuits1 Counters1.1 Four-bit binary counter1.1.1 解决思路1.1.2 代码实现 1 Counters 1.1 Four-bit binary counter 构建一个4位二进制计数器，其计数范围为0到15（含15），周期为16。重置输入是同步的，应将计数器重置为0。 1.1.1 解决思路 该题可以从同步时序逻辑电路的设计方法入手，由于没有入参，因此只能构建Moore型FSM。 #mermaid-svg-QG81s0rg
HDLBits 答案汇总（持续更新）
nomorepolishing的博客
12-22 6642
HDLBits solutions
HDLbits答案更新系列17（3.2.5 Finite State Machines 3.2.5.24 Q3a: FSM等）
小k的博客
06-01 4500
今天更新三道题目，其中第一道题目大家要重点去理解，我的方法是使用状态机和计数器的组合，当然也可以增加状态数目，将每种情况都列出来，大家可以多尝试自己的方法，重点在掌握解题思路。希望能和大家一起努力，共同进步~
HDLbits答案更新系列7（3.2 Sequential Logic 3.2.1 Latches and Flip-Flops）
热门推荐
小k的博客
05-20 1万+
今天更新一个小节内容，第三部分Circuit中Sequential Logic里面的Latchs and Flip-Flops，这部分内容是时序电路设计的基础，里面的一些题目也很有技巧性，希望能和大家一起学习，共同进步~
No such file or directory: 'E:\\桌面\\识别与定位技术课程配套程序\\3.2\\3.2.5\\未命名1.py'
09-19
No such file or directory: 'E:\\桌面\\识别与定位技术课程配套程序\\3.2\\3.2.5\\未命名1.py' 错误提示意味着在指定路径下找不到名为“未命名1.py”的文件或目录。请确保路径和文件名正确，并且文件存在于该路径下。另外，也请检查文件名是否包含特殊字符或有拼写错误。如果确认路径和文件名正确无误，但仍然无法找到文件，请检查文件是否被移动或删除了。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 15
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值