CMake | 拆分CMakeLists.txt文件

目录

一、add_subdirectory

举个栗子

1.src/CMakeLists.txt

2.子目录下CMakeLists.txt

二、include

1.src/CMakeLists.txt

2.src/evolution/CMakeLists.txt

3.其他子目录下CMakeLists.txt文件

---

一、add_subdirectory

        为了降低代码的复杂性和简化项目的维护，我们可以限制变量的范围和副作用，把一个项目分割成几个范围有限的CMakeLists.txt文件， 这些文件将使用 add_subdirectory 命令进行处理。

add_subdirectory(source_dir [binary_dir] [EXCLUDE_FROM_ALL])

        将子目录添加到生成中。

• source_dir：必选参数。该参数指定一个子目录，子目录下应该包含CMakeLists.txt文件和代码文件。子目录可以是相对路径也可以是绝对路径，如果是相对路径，则是相对当前目录的一个相对路径。
• binary_dir：可选参数。该参数指定一个目录，用于存放输出文件。可以是相对路径也可以是绝对路径，如果是相对路径，则是相对当前输出目录的一个相对路径。如果该参数没有指定，则默认的输出目录使用source_dir。
• EXCLUDE_FROM_ALL：可选参数。当指定了该参数，则子目录下的目标不会被父目录下的目标文件包含进去，父目录的CMakeLists.txt不会构建子目录的目标文件，必须在子目录下显式去构建。例外情况：当父目录的目标依赖于子目录的目标，则子目录的目标仍然会被构建出来以满足依赖关系（例如使用了target_link_libraries）。

        add_subdirectory 方法隔离了作用范围，因为子目录中定义的变量在父范围中不能访问。

        使用 add_subdirectory 调用树构建项目的一个限制是，CMake不允许将 target_link_libraries 与定义在当前目录范围之外的目标一起使用。

举个栗子

1.src/CMakeLists.txt

add_executable(automata main.cpp)

add_subdirectory(evolution)
add_subdirectory(initial)
add_subdirectory(io)
add_subdirectory(parser)

target_link_libraries(automata
  PRIVATE
    evolution
    initial
    io
    parser
  )

2.子目录下CMakeLists.txt

        子目录下CMakeLists.txt文件都是类似的，一共定义了四个库，src/evolution/CMakeLists.txt：

add_library(evolution "")

target_sources(evolution
  PRIVATE
    evolution.cpp
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}/evolution.hpp
  )

target_include_directories(evolution
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}
  )

二、include

        与add_subdirectory不同的是，使用 include 来组装不同的 CMakeLists.txt 文件，它允许我们链接到当前目录之外定义的目标。

1.src/CMakeLists.txt

src项目结构同上，修改src/CMakeLists.txt文件：

add_library(automaton "")
add_library(evolution "")

include(${CMAKE_CURRENT_LIST_DIR}/evolution/CMakeLists.txt)
include(${CMAKE_CURRENT_LIST_DIR}/initial/CMakeLists.txt)
include(${CMAKE_CURRENT_LIST_DIR}/io/CMakeLists.txt)
include(${CMAKE_CURRENT_LIST_DIR}/parser/CMakeLists.txt)

add_executable(automata "")

target_sources(automata
  PRIVATE
    ${CMAKE_CURRENT_LIST_DIR}/main.cpp
  )

target_link_libraries(automata
  PRIVATE
    automaton
    conversion
  )

2.src/evolution/CMakeLists.txt

target_sources(automaton
  PRIVATE
    ${CMAKE_CURRENT_LIST_DIR}/evolution.cpp
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}/evolution.hpp
  )

target_include_directories(automaton
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}
  )

target_sources(evolution
  PRIVATE
    ${CMAKE_CURRENT_LIST_DIR}/evolution.cpp
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}/evolution.hpp
  )

target_include_directories(evolution
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}
  )

3.其他子目录下CMakeLists.txt文件

        其他子目录下CMakeLists.txt文件同样都是类似的，都是automaton库，src/initial/CMakeLists.txt文件：

target_sources(automaton
  PRIVATE
    ${CMAKE_CURRENT_LIST_DIR}/initial.cpp
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}/initial.hpp
  )

target_include_directories(automaton
  PUBLIC
    ${CMAKE_CURRENT_LIST_DIR}
  )