c++读出像素矩阵_Unity Shader 点阵像素剔除半透（Stipple Transparency ）

最近一段时间一直不停的刷只狼（打铁真好玩.......），无意中发现主角被场景物体遮挡的时候，半透效果比较有意思，是像马赛克一样被剔除掉了。

上图是我在游戏里截的，在上传以后被压缩了 所以有点糊，但应该还是能辨别出来，摄像机前面是有一棵树的，在遮挡住主角后变成半透了，并且透明的方式并不是传统的半透，而是像扣掉了像素一样的马赛克形状。

之前一个朋友问过我这个效果，我从网上搜了下，发现还是有很多资料的，具体来自于这

Unity Stipple Transparency Shader - Alex Ocias Blog​ocias.com

文章里写的还是很详细的，这个技术其实非常古老了，在过去硬件性能很差的时候，很多半透效果无法实现，毕竟这种混合算法要把前后层都渲一遍然后做算法融合，并且还有万恶的排序问题。所以很快就有人想出了这种利用像素剔除的方式来模拟半透效果，性能开销要好很多，并且因为不需要融合，所以不会出现排序问题。

下面是重点代码，其实很简单，就是先设定了一个4*4的矩阵来作为阈值，利用x轴采样这个阈值，小于这个阈值的像素将被剔除掉，_RowAccess 是一个单位矩阵，用来定义Y轴的采样，_Transparency 这个属性就是用来控制透明度的级别，根据这个透明度去采样阈值。

    // Screen-door transparency: Discard pixel if below threshold.
    float4x4 thresholdMatrix =
    {  1.0 / 17.0,  9.0 / 17.0,  3.0 / 17.0, 11.0 / 17.0,
      13.0 / 17.0,  5.0 / 17.0, 15.0 / 17.0,  7.0 / 17.0,
       4.0 / 17.0, 12.0 / 17.0,  2.0 / 17.0, 10.0 / 17.0,
      16.0 / 17.0,  8.0 / 17.0, 14.0 / 17.0,  6.0 / 17.0
    };
    float4x4 _RowAccess = { 1,0,0,0, 0,1,0,0, 0,0,1,0, 0,0,0,1 };
    float2 pos = IN.screenPos.xy / IN.screenPos.w;
    pos *= _ScreenParams.xy; // pixel position
    clip(_Transparency - thresholdMatrix[fmod(pos.x, 4)] * _RowAccess[fmod(pos.y, 4)]);

说到性能这方面，这个做法在手机上的表现可能并不突出，因为手机上alphatest的开销是要高于alphablend的，所以如果手机想用这种效果，还是根据对这种像素风格的需求来定吧。

这里只有一个shader，就不做工程文件了，如果上面的网站进不去，就直接用下面的完整代码。

Shader "Ocias/Diffuse (Stipple Transparency)" {
Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
    _Transparency ("Transparency", Range(0,1)) = 1.0
}
SubShader {
    Tags { "RenderType"="Opaque" }
    LOD 150
CGPROGRAM
#pragma surface surf Lambert noforwardadd
sampler2D _MainTex;
struct Input {
    float2 uv_MainTex;
    float4 screenPos;
};
half _Transparency;
void surf (Input IN, inout SurfaceOutput o) {
    fixed4 c = tex2D(_MainTex, IN.uv_MainTex);
    o.Albedo = c.rgb;
    o.Alpha = c.a;
    // Screen-door transparency: Discard pixel if below threshold.
    float4x4 thresholdMatrix =
    {  1.0 / 17.0,  9.0 / 17.0,  3.0 / 17.0, 11.0 / 17.0,
      13.0 / 17.0,  5.0 / 17.0, 15.0 / 17.0,  7.0 / 17.0,
       4.0 / 17.0, 12.0 / 17.0,  2.0 / 17.0, 10.0 / 17.0,
      16.0 / 17.0,  8.0 / 17.0, 14.0 / 17.0,  6.0 / 17.0
    };
    float4x4 _RowAccess = { 1,0,0,0, 0,1,0,0, 0,0,1,0, 0,0,0,1 };
    float2 pos = IN.screenPos.xy / IN.screenPos.w;
    pos *= _ScreenParams.xy; // pixel position
    clip(_Transparency - thresholdMatrix[fmod(pos.x, 4)] * _RowAccess[fmod(pos.y, 4)]);
}
ENDCG
}
Fallback "Mobile/VertexLit"
}