【U3D/Shader】3.剖析并模块化最简单的shader

自我介绍

广东双非一本的大三小白，计科专业，想在制作毕设前夯实基础，毕设做出一款属于自己的游戏！

最简单的shader

简单来说，有输入也要有输出，输入和输出的类型相当于语义

002.shader

Shader "Unlit/002"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			//POSITION SV_POSITION  语义
			//POSITION：告诉unity把模型的顶点坐标填充到输入参数v中
			//SV_POSITION：告诉unity输出的是裁剪空间中的顶点坐标
			float4 vert(float4 v:POSITION):SV_POSITION
			{
				//UnityObjectToClipPos将坐标点从模型空间转换到裁剪空间
				//内部实现：return mul(UNITY_MATRIX_VP, mul(unity_ObjectToWorld, float4(pos, 1.0)));
				return UnityObjectToClipPos(v);
			}

			//SV_TARGET：将用户的输出颜色存储到一个渲染目标，这里将输出到默认的帧缓存中
			fixed4 frag():SV_TARGET
			{
				return fixed4(1,1,1,1);
			}
			ENDCG
		}
	}
}

出来的效果是纯白的一个模型，因为偏远着色器输出的颜色是 (1, 1, 1, 1)

顶点着色器中的模型数据哪里来呐？

• 由该材质的 mesh renderer 组件提供，里面包括的数据有 顶点位置，法线，切线，纹理坐标，顶点颜色等

模块化后的shader

003.shader

Shader "Unlit/003"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_Color("Color" , Color) = (1,1,1,1)
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			//#include "UnityCG.cginc"

			//只有在CGPROGRAM内再次定义一个与属性块内名字与类型相同的变量，属性块对应的变量才能起作用
			fixed4 _Color;

			struct a2v	//application to vert
			{
				float4 vertex:POSITION;		//用模型顶点填充v变量
				float3 normal:NORMAL;		//用模型的法线填充n变量
				float4 texcoord: TEXCOORD0;	//用模型的第一套uv填充texcoord
			};

			struct v2f	// vert 2 frag
			{
				float4 pos:SV_POSITION;	//SV_POSITION语义告诉unity : pos为裁剪空间中的位置信息  
				fixed3 color:COLOR0;	//COLOR0 语义可以储存颜色信息
			};
	
			v2f vert(a2v v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				//v.normal包含了顶点的法线方向，范围[-1, 1]
				//将[-1, 1]转变为【0，1】  x/2 + 0.5;
				o.color = v.normal * 0.5 + fixed3(0.5,0.5,0.5);
				return o;
			}

			fixed4 frag(v2f i):SV_TARGET
			{
				fixed3 c = i.color;
				c *= _Color.rgb;
				return fixed4(c, 1);
			}

			ENDCG
		}
	}
}