* ball_seq.hdev: Inspection of Ball Bonding
* 焊点检查
dev_update_off ()
ImageNames := 'die/' + ['die_02','die_03','die_04','die_07']
dev_set_colored (12)
read_image (Bond, ImageNames[0])
get_image_size (Bond, Width, Height)
dev_close_window ()
dev_open_window (0, 0, Width, Height, 'black', WindowHandle)
set_display_font (WindowHandle, 16, 'mono', 'true', 'false')
dev_set_draw ('margin')
dev_set_line_width (3)
NumImages := |ImageNames|
for I := 0 to NumImages - 1 by 1
read_image (Bond, ImageNames[I])
dev_display (Bond)
*用于提取 Regions 所在区域图像的最大与最小灰度值
min_max_gray (Bond, Bond, 0, Min, Max, Range)
*阈值分割
threshold (Bond, Bright, Max - 80, 255)
*形状变换(最小外接矩形)
shape_trans (Bright, Die, 'rectangle2')
dev_display (Die)
*获取新的标记区域,新的区域是由旧的区域与第2个参数相交所得
reduce_domain (Bond, Die, DieGrey)
*用于提取 Regions 所在区域图像的最大与最小灰度值
min_max_gray (Die, Bond, 0, Min, Max, Range)
*阈值分割
threshold (DieGrey, Wires, 0, Min + 30)
*填充输入区域中具有给定形状特征的孔。参数特征决定了要使用的形状特征,
*而Min和Max确定了为了填补这个洞的形状特征的范围
fill_up_shape (Wires, WiresFilled, 'area', 1, 100)
*开运算(先腐蚀后膨胀)
opening_circle (WiresFilled, Balls, 9.5)
*连通区域分割
connection (Balls, SingleBalls)
*函数根据Shape指定的形状特征,从Regions 选择满足特征的区域,保存到SelectedRegions
select_shape_std (SingleBalls, Rect, 'rectangle1', 90)
*检测region形状的差别,计算对象是两个region,不考虑region灰度值是否有差异
difference (SingleBalls, Rect, IntermediateBalls)
*创建一个空白的区域
gen_empty_region (Forbidden)
*依据灰度值或颜色填充两个区域的间隙或分割重叠区域
expand_gray (IntermediateBalls, Bond, Forbidden, RegionExpand, 4, 'image', 6)
*开运算(先腐蚀后膨胀)
opening_circle (RegionExpand, RoundBalls, 15.5)
*对区域进行排序
sort_region (RoundBalls, FinalBalls, 'first_point', 'true', 'column')
*计算一个给定区域的最小外接圆参数
smallest_circle (FinalBalls, Row, Column, Radius)
NumBalls := |Radius|
Diameter := 2 * Radius
meanDiameter := sum(Diameter) / NumBalls
mimDiameter := min(Diameter)
dev_display (RoundBalls)
if (I != NumImages)
disp_continue_message (WindowHandle, 'black', 'true')
endif
stop ()
endfor
Blob分析--焊点检查
最新推荐文章于 2022-11-04 12:00:50 发布