Unity Shader学习记录(9) —— 渐变纹理的实现

1 渐变纹理介绍

尽管在一开始，我们在渲染中使用纹理是为了定义一个物体的颜色，但后来人们发现，纹理其实可以用于存储任何表面属性。一种常见的用法就是使用渐变纹理来控制漫反射光照的结果。在之前计算漫反射光照时，我们都是使用表面法线和光照方向的点积结果与材质的反射率相乘来得到表面的漫反射光照。但有时，我们需要更加灵活地控制光照结果。

使用这种方式，可以保证物体的轮廓线相比于之前使用的传统漫反射光照更加明显，而且能够提供多种色调变化。
（现在很多卡通风格都使用了渐变纹理）

实现代码

Shader "MyShader/7-RampTexture"
{
     Properties
    {   
         _Color ("Color Tint", Color) = (1,1,1,1)
        _RampTex ("Ramp Tex", 2D) = "white" {}
        _Specular("Specular", Color) = (1,1,1,1)
        _Gloss("Gloss", Range(8.0,256)) = 20
      
    }

     SubShader{
        pass{
            //pass的光照模式
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM
                #pragma vertex vert
			    #pragma fragment frag
                #include "Lighting.cginc"

                fixed4 _Color;
			    sampler2D _RampTex;
			    float4 _RampTex_ST;
			    fixed4 _Specular;
			    float _Gloss;

                struct a2v{
                    fixed4 vertex : POSITION;
                    //NORMAL语义告诉unity法线存到normal
                    float3 normal : NORMAL;
                    float4 texcoord : TEXCOORD0;
                };

                struct v2f{
                    float4 pos : SV_POSITION;
                    //TEXCOORD0纹理坐标组
                    float3 worldNormal : TEXCOORD0;
                    float3 worldPos : TEXCOORD1;
                    float2 uv : TEXCOORD2;

                };

                //定义顶点着色器
                v2f vert(a2v v){
                   v2f o;
				    o.pos = UnityObjectToClipPos(v.vertex);
				
				    o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				    o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				    o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);
				
				    return o;
                }
				//定义片元着色器
                fixed4 frag(v2f i) : SV_Target {
                    fixed3 worldNormal = normalize(i.worldNormal);
                    fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                    //半兰伯特模型
                    fixed halfLambert  = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
                    //纹理采样。由于 RampTex实际就是一个一维纹理(它在纵轴方向上颜色不).因此纹理坐标的u和v方向我们都使用了 halfLambert
                    //漫反射采样于贴图
                    fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;

                    fixed3 diffuse = _LightColor0.rgb * diffuseColor;
                    fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				    fixed3 halfDir = normalize(worldLightDir + viewDir);
				    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
                    return fixed4(ambient + diffuse + specular, 1.0);
                }


            ENDCG
        }
     }

     FallBack "Specular"
}

这种方式与单色漫反射shader基本一致，只是采样方式从原来的一种颜色变为了梯度渐变色，能实现清晰的多个色彩层次的漫反射效果。