Halcon 算法与动态阈值

图片路径

链接：https://pan.baidu.com/s/1ebCwmEQ2nRWeE8KWM0ph7Q
提取码：dtuj

*** 1、读取显示图片 **************
dev_update_off ()

* 读取图片
read_image (Image, './embossed_01.png')
get_image_size (Image, Width, Height)
* 获取窗口
dev_get_window (WindowHandle)
if (WindowHandle >= 0)
    dev_resize_window_fit_image (Image, 0, 0, -1, -1)
else
    dev_open_window_fit_image (Image, 0, 0, -1, -1, WindowHandle)
endif
set_display_font (WindowHandle, 16, 'mono', 'true', 'false')
dev_set_line_width (2)

* 显示图片
dev_display (Image)
Message := '原始图片'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandle, 'black', 'true')
stop ()

*** 2、动态阈值 *********************
* 图片均值处理
mean_image (Image, ImageMean, 59, 59)

* 显示均值处理结果
dev_display (ImageMean)
Message := '均值滤波图片'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandle, 'black', 'true')
stop ()

* 动态阈值 （原始图片与均值图片 的差值）15 差值参数，not_equal 黑白
dyn_threshold (Image, ImageMean, RegionDynThresh, 15, 'not_equal')

* 显示动态阈值处理结果
dev_display (Image)
dev_display (RegionDynThresh)
Message := '动态阈值结果'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandle, 'black', 'true')
dump_window_image (ImageDyn, WindowHandle)
write_image (ImageDyn, 'jpg', 0, './imageDyn')
stop ()

*** 3、形态学处理 *************************
* 闭运算 （合并左右）
closing_circle (RegionDynThresh, RegionClosing, 8.5)
* 开运算 （去除杂质与干扰）
opening_circle (RegionClosing, RegionOpening, 6.5)

* 连通域分析
connection (RegionOpening, ConnectedRegions)
* 最小外接圆
smallest_circle (ConnectedRegions, Row, Column, Radius)
* 获取外接圆
gen_circle_contour_xld (ContCircle, Row, Column, Radius, 0, 6.28318, 'positive', 1)
dev_clear_window ()
dev_display (ConnectedRegions)
dump_window_image (ImageConnected, WindowHandle)
write_image (ImageConnected, 'jpg', 0, './imgConnected')
**** 4、显示结果 ***************************
dev_display (Image)
dev_set_color ('green')
dev_display (ContCircle)
Message := '结果图片  绘圆'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')

dump_window_image (ImageResult, WindowHandle)
write_image (ImageResult, 'jpg', 0, './imgResult')
dev_update_on ()