codesys 轴程序

已于 2024-01-18 10:14:11 修改
阅读量606 收藏 8
点赞数 12
分类专栏： codesys 文章标签： codesys
于 2024-01-17 15:33:53 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_58619062/article/details/135651896
版权 
TYPE ENUM_index_axis :
(
	indexAxisStart:=0,

	//伺服索引编号
	indexAxisExample1,
	indexAxisExample2,
	indexAxisExample3,
	
	indexAxisEnd
);
END_TYPE

TYPE ENUM_index_axis_error :
(
	indexAxisErrorStart:=0,
	
	indexAxisErrorInterferenceError,
	indexAxisErrorTorqueLimitError,
	indexAxisErrorPositiveLimitError,
	indexAxisErrorNegativeLimitError,
	indexAxisErrorAxisError,
	indexAxisErrorJogError,
	indexAxisErrorHomeError,
	indexAxisErrorMoveRelativeError,
	indexAxisErrorMoveAbsoluteError,
	indexAxisErrorMoveVelocityError
);
END_TYPE

TYPE ST_axis :
STRUCT
	sComment:WSTRING;

	REF:POINTER TO SM3_Basic.AXIS_REF_SM3;
	
	bControlMode:BOOL;
	
	control:ST_axis_control;
	parameter:ST_axis_parameter;
	other:ST_axis_other;
	signal:ST_axis_signal;
	status:ST_axis_status;
	FB:FB_axis;
END_STRUCT
END_TYPE

TYPE ST_axis_com :
STRUCT
	//关联硬件
	nDigitalInputs AT %I* :UDINT;//0.0负限位，0.1正限位，0.2原点
	nErrorCode AT %I* :UINT;//驱动器报错代码
	nState AT %I* :UINT;//通讯状态
	nPort AT %I* :WORD;//伺服通讯端口号
	nTorque AT %I* :INT;//扭矩

	nControlWord AT %Q* :UINT;//控制字
	nModesOfOperation AT %Q* :SINT;//运行模式

	//关联NC轴
	nCtrl1 AT %I* :USINT;//控制字
	nCtrl2 AT %I* :USINT;//控制字
	nCtrl5 AT %I* :USINT;//运行模式
END_STRUCT
END_TYPE

TYPE ST_axis_control :
STRUCT
	manual:ST_axis_control_manu_auto;
	automatic:ST_axis_control_manu_auto;
END_STRUCT
END_TYPE

TYPE ST_axis_control_manu_auto :
STRUCT
	bPower:BOOL:=TRUE;
	bStop:BOOL;
	bHalt:BOOL;
	bReset:BOOL;

	bHome:BOOL;
	bJogForward:BOOL;
	bJogBackward:BOOL;
	bMoveRelative:BOOL;
	bMoveAbsolute:BOOL;
	bMoveVelocity:BOOL;
END_STRUCT
END_TYPE

TYPE ST_axis_other :
STRUCT
	bTorqueLimit:BOOL;
	nTorqueLimit:LREAL;
	
	bPositionLimit:BOOL;
	nPositiveLimit:LREAL;
	nNegativeLimit:LREAL;

	nPositionCompareMax:LREAL:=0.05;
END_STRUCT
END_TYPE

TYPE ST_axis_parameter :
STRUCT
	manual:ST_axis_parameter_manu_auto;
	automatic:ST_axis_parameter_manu_auto;
END_STRUCT
END_TYPE

TYPE ST_axis_parameter_manu_auto :
STRUCT
	nOverride:LREAL:=100;//速度百分比

	nAccelerationTime:LREAL:=0.2; //加速时间
	nDecelerationTime:LREAL:=0.2; //减速时间

	nVelocity:LREAL:=100;
	nAcceleration:LREAL:=1000;
	nDeceleration:LREAL:=1000;
	nJerk:LREAL:=10000;//加加速度

	nJogVelocity:LREAL:=1;
	nJogAcceleration:LREAL:=1000;
	nJogDeceleration:LREAL:=1000;
	nJogJerk:LREAL:=10000;//加加速度

	nDistance:LREAL;
	nPosition:LREAL;
	nDirection:MC_Direction;
	nHomeMethod:UDINT:=23;
END_STRUCT
END_TYPE
(*
nAcceleration:=nVelocity*2/nAccelerationTime;
nDeceleration:=nVelocity*2/nDecelerationTime;
nJerk:=nAcceleration*2/nAccelerationTime;
*)

TYPE ST_axis_signal :
STRUCT
	bPositiveSensor:BOOL;
	bNegativeSensor:BOOL;
	bHomeSensor:BOOL;
	
	bInterference:ARRAY[1..4] OF BOOL;
END_STRUCT
END_TYPE

TYPE ST_axis_status :
STRUCT
	nAxisErrorID:DWORD;
	nActualPosition:LREAL;
	nActualVelocity:LREAL;
	nActualTorque:LREAL;
	
	bInterferenceError:BOOL;
	bTorqueLimitError:BOOL;
	bPositiveLimitError:BOOL;
	bNegativeLimitError:BOOL;

	bPowerState:BOOL;

	bJogDone:BOOL;
	bJogBusy:BOOL;
	bJogError:BOOL;

	bHomeDone:BOOL;
	bHomeBusy:BOOL;
	bHomeError:BOOL;

	bMoveRelativeDone:BOOL;
	bMoveRelativeBusy:BOOL;
	bMoveRelativeError:BOOL;

	bMoveAbsoluteDone:BOOL;
	bMoveAbsoluteBusy:BOOL;
	bMoveAbsoluteError:BOOL;

	bMoveVelocityState:BOOL;
	bMoveVelocityBusy:BOOL;
	bMoveVelocityError:BOOL;

	bPositionCompare:BOOL;
	
	bError:BOOL;
	nErrorCode:INT;
	sErrorComment:WSTRING;

	nControlWord:UINT;//控制字
	nModesOfOperation:SINT;//运行模式
END_STRUCT
END_TYPE
FUNCTION_BLOCK FB_axis
VAR_IN_OUT
	AxisRef:SM3_Basic.AXIS_REF_SM3;
END_VAR
VAR_INPUT
	bSystemStop:BOOL;
	bSystemEmergency:BOOL;
	bSystemReset:BOOL;
	sAxisComment:WSTRING;
	bAxisControlMode:BOOL;
	AxisControl:ST_axis_control;
	AxisParameter:ST_axis_parameter;
	AxisSignal:ST_axis_signal;
	AxisOther:ST_axis_other;
END_VAR
VAR_OUTPUT
	AxisStatus:ST_axis_status;
END_VAR
VAR
	rTrigControlMode:R_TRIG;
	fTrigControlMode:F_TRIG;
	control:ST_axis_control_manu_auto;
	parameter:ST_axis_parameter_manu_auto;

	i:INT;
	bMoveAllow:BOOL;
	bResetAllow:BOOL;
	bPowerAllow:BOOL;
	bHomeAllow:BOOL;
	bJogForwardAllow:BOOL;
	bJogBackwardAllow:BOOL;
	bMoveRelativeAllow:BOOL;
	bMoveAbsoluteAllow:BOOL;
	bMoveVelocityAllow:BOOL;
	sComment:WSTRING:="";

	Power:MC_Power;
	Stop:MC_Stop;
	Halt:MC_Halt;
	Reset:MC_Reset;
	Home:MC_Home;
	Jog:MC_Jog;
	MoveRelative:MC_MoveRelative;
	MoveAbsolute:MC_MoveAbsolute;
	MoveVelocity:MC_MoveVelocity;
	ReadActualPosition:MC_ReadActualPosition;
	ReadActualVelocity:MC_ReadActualVelocity;
	ReadActualTorque:MC_ReadActualTorque;
	ReadAxisError:MC_ReadAxisError;
END_VAR

//控制模式上升沿、下降沿
rTrigControlMode(CLK:=bAxisControlMode , Q=> );
fTrigControlMode(CLK:=bAxisControlMode , Q=> );

//手模式控制、自动模式控制
IF bAxisControlMode THEN
	control:=AxisControl.automatic;
	parameter:=AxisParameter.automatic;
ELSE
	control:=AxisControl.manual;
	parameter:=AxisParameter.manual;
END_IF

//状态切换
IF rTrigControlMode.Q OR fTrigControlMode.Q THEN
	control.bJogBackward:=FALSE;
	control.bJogForward:=FALSE;
	control.bHome:=FALSE;
	control.bMoveRelative:=FALSE;
	control.bMoveAbsolute:=FALSE;
	control.bMoveVelocity:=FALSE;
	control.bHalt:=TRUE;
END_IF

//干涉
AxisStatus.bInterferenceError:=FALSE;
FOR i:=1 TO 4 BY 1 DO
	IF AxisSignal.bInterference[i] THEN
		AxisStatus.bInterferenceError:=TRUE;
	END_IF
END_FOR

//正负软限位
AxisStatus.bPositiveLimitError:=FALSE;
AxisStatus.bNegativeLimitError:=FALSE;
IF AxisOther.bPositionLimit THEN
	IF (AxisStatus.nActualPosition>=AxisOther.nPositiveLimit AND control.bJogForward)
	OR (parameter.nPosition>=AxisOther.nPositiveLimit AND control.bMoveAbsolute)
	OR ((parameter.nDistance+AxisStatus.nActualPosition)>=AxisOther.nPositiveLimit
	AND (control.bMoveRelative AND NOT AxisStatus.bMoveRelativeBusy)) THEN
		AxisStatus.bPositiveLimitError:=TRUE;
	END_IF

	IF (AxisStatus.nActualPosition<=AxisOther.nNegativeLimit AND control.bJogBackward)
	OR (parameter.nPosition<=AxisOther.nNegativeLimit AND control.bMoveAbsolute)
	OR ((parameter.nDistance+AxisStatus.nActualPosition)<=AxisOther.nNegativeLimit
	AND (control.bMoveRelative AND NOT AxisStatus.bMoveRelativeBusy)) THEN
		AxisStatus.bNegativeLimitError:=TRUE;
	END_IF
END_IF

//扭矩软限位
AxisStatus.bTorqueLimitError:=FALSE;
IF AxisOther.bTorqueLimit THEN
	IF AxisStatus.nActualTorque>=AxisOther.nTorqueLimit THEN
		AxisStatus.bTorqueLimitError:=TRUE;
	END_IF
END_IF

//控制允许
bMoveAllow:=TRUE;
IF AxisStatus.bInterferenceError OR AxisStatus.bTorqueLimitError
OR AxisStatus.bPositiveLimitError OR AxisStatus.bNegativeLimitError
OR AxisStatus.nAxisErrorID>0 OR AxisStatus.bHomeError OR AxisStatus.bJogError
OR AxisStatus.bMoveRelativeError OR AxisStatus.bMoveAbsoluteError OR AxisStatus.bMoveVelocityError
OR control.bHalt OR control.bStop OR bSystemStop OR bSystemEmergency THEN
	bMoveAllow:=FALSE;
END_IF

//复位
bResetAllow:=FALSE;
IF AxisStatus.bInterferenceError OR AxisStatus.bTorqueLimitError
OR AxisStatus.bPositiveLimitError OR AxisStatus.bNegativeLimitError
OR AxisStatus.nAxisErrorID>0 OR AxisStatus.bHomeError OR AxisStatus.bJogError
OR AxisStatus.bMoveRelativeError OR AxisStatus.bMoveAbsoluteError OR AxisStatus.bMoveVelocityError THEN
	IF control.bReset OR bSystemReset THEN
		bResetAllow:=TRUE;
	END_IF
END_IF

//使能
IF AxisStatus.nAxisErrorID>0 OR NOT control.bPower OR bSystemEmergency THEN
	bPowerAllow:=FALSE;
ELSE
	bPowerAllow:=TRUE;
END_IF

//回原点
IF bMoveAllow AND NOT AxisStatus.bJogBusy 
AND NOT AxisStatus.bMoveRelativeBusy AND NOT AxisStatus.bMoveAbsoluteBusy AND NOT AxisStatus.bMoveVelocityBusy
AND control.bHome THEN
	bHomeAllow:=TRUE;
ELSE
	bHomeAllow:=FALSE;
END_IF

//正向点动
IF bMoveAllow AND NOT AxisStatus.bHomeBusy  
AND NOT AxisStatus.bMoveRelativeBusy AND NOT AxisStatus.bMoveAbsoluteBusy AND NOT AxisStatus.bMoveVelocityBusy
AND NOT AxisSignal.bPositiveSensor AND control.bJogForward THEN
	bJogForwardAllow:=TRUE;
ELSE
	bJogForwardAllow:=FALSE;
END_IF

//负向点动
IF bMoveAllow AND NOT AxisStatus.bHomeBusy  
AND NOT AxisStatus.bMoveRelativeBusy AND NOT AxisStatus.bMoveAbsoluteBusy AND NOT AxisStatus.bMoveVelocityBusy
AND NOT AxisSignal.bNegativeSensor AND control.bJogBackward THEN
	bJogBackwardAllow:=TRUE;
ELSE
	bJogBackwardAllow:=FALSE;	
END_IF

//相对运动
IF bMoveAllow AND NOT AxisStatus.bHomeBusy AND NOT AxisStatus.bJogBusy
AND NOT AxisStatus.bMoveAbsoluteBusy AND NOT AxisStatus.bMoveVelocityBusy
AND NOT AxisSignal.bPositiveSensor AND NOT AxisSignal.bNegativeSensor 
AND control.bMoveRelative THEN
	bMoveRelativeAllow:=TRUE;	
ELSE
	bMoveRelativeAllow:=FALSE;
END_IF

//绝对运动
IF bMoveAllow AND NOT AxisStatus.bHomeBusy AND NOT AxisStatus.bJogBusy
AND NOT AxisStatus.bMoveRelativeBusy AND NOT AxisStatus.bMoveVelocityBusy
AND NOT AxisSignal.bPositiveSensor AND NOT AxisSignal.bNegativeSensor
AND control.bMoveAbsolute THEN
	bMoveAbsoluteAllow:=TRUE;
ELSE
	bMoveAbsoluteAllow:=FALSE;
END_IF

//速度运动
IF bMoveAllow AND NOT AxisStatus.bHomeBusy AND NOT AxisStatus.bJogBusy
AND NOT AxisStatus.bMoveRelativeBusy AND NOT AxisStatus.bMoveAbsoluteBusy 
AND NOT AxisSignal.bPositiveSensor AND NOT AxisSignal.bNegativeSensor
AND control.bMoveVelocity THEN
	bMoveVelocityAllow:=TRUE;
END_IF
IF NOT bMoveAllow THEN
	bMoveVelocityAllow:=FALSE;
END_IF

//加速度//加加速度
IF parameter.nAccelerationTime<>0 THEN
	IF parameter.nVelocity<>0 THEN 
		parameter.nAcceleration:=parameter.nVelocity*2/parameter.nAccelerationTime;
		parameter.nJerk:=parameter.nAcceleration*2/parameter.nAccelerationTime;
	END_IF
	
	IF parameter.nJogVelocity<>0 THEN
		parameter.nJogAcceleration:=parameter.nJogVelocity*2/parameter.nAccelerationTime;
		parameter.nJogJerk:=parameter.nJogAcceleration*2/parameter.nAccelerationTime;
	END_IF
END_IF

//减速度
IF parameter.nDecelerationTime<>0 THEN
	IF parameter.nVelocity<>0 THEN 
		parameter.nDeceleration:=parameter.nVelocity*2/parameter.nDecelerationTime;
	END_IF
	
	IF parameter.nJogVelocity<>0 THEN
		parameter.nJogDeceleration:=parameter.nJogVelocity*2/parameter.nDecelerationTime;
	END_IF
END_IF

//位置比较
IF ABS(AxisStatus.nActualPosition-parameter.nPosition)<AxisOther.nPositionCompareMax THEN 
	AxisStatus.bPositionCompare:=TRUE;
ELSE
   	AxisStatus.bPositionCompare:=FALSE;
END_IF

//轴功能块
ReadAxisError(
	Axis:=AxisRef , 
	Enable:=TRUE , 
	Valid=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> , 
	AxisError=> , 
	AxisErrorID=>AxisStatus.nAxisErrorID , 
	SWEndSwitchActive=> );

ReadActualPosition(
	Axis:=AxisRef , 
	Enable:=TRUE , 
	Valid=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> , 
	Position=>AxisStatus.nActualPosition );

ReadActualVelocity(
	Axis:=AxisRef , 
	Enable:=TRUE , 
	Valid=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> , 
	Velocity=>AxisStatus.nActualVelocity );
	
ReadActualTorque(
	Axis:=AxisRef , 
	Enable:=TRUE , 
	Valid=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> , 
	Torque=>AxisStatus.nActualTorque );

Power(
	Axis:=AxisRef , 
	Enable:=bPowerAllow , 
	bRegulatorOn:=TRUE , 
	bDriveStart:=TRUE , 
	Status=>AxisStatus.bPowerState , 
	bRegulatorRealState=> , 
	bDriveStartRealState=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> );

Halt(
	Axis:=AxisRef , 
	Execute:=control.bHalt , 
	Deceleration:= , 
	Jerk:= , 
	Done=> , 
	Busy=> , 
	CommandAborted=> , 
	Error=> , 
	ErrorID=> );
	
Stop(
	Axis:=AxisRef , 
	Execute:=NOT bMoveAllow AND NOT control.bHalt , 
	Deceleration:= , 
	Jerk:= , 
	Done=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> );	
	
Reset(
	Axis:=AxisRef , 
	Execute:=bResetAllow , 
	Done=> , 
	Busy=> , 
	Error=> , 
	ErrorID=> );
	
Jog(
	Axis:=AxisRef , 
	JogForward:=bJogForwardAllow , 
	JogBackward:=bJogBackwardAllow , 
	Velocity:=parameter.nJogVelocity , 
	Acceleration:=parameter.nJogAcceleration , 
	Deceleration:=parameter.nJogDeceleration , 
	Jerk:=parameter.nJogJerk , 
	Busy=>AxisStatus.bJogBusy , 
	CommandAborted=> , 
	Error=> , 
	ErrorId=> );

Home(
	Axis:=AxisRef , 
	Execute:=bHomeAllow , 
	Position:=0 , 
	Done=>AxisStatus.bHomeDone , 
	Busy=>AxisStatus.bHomeBusy , 
	CommandAborted=> , 
	Error=>AxisStatus.bHomeError , 
	ErrorID=> );	
	
MoveRelative(
	Axis:=AxisRef , 
	Execute:=bMoveRelativeAllow , 
	Distance:=parameter.nDistance , 
	Velocity:=parameter.nVelocity , 
	Acceleration:=parameter.nAcceleration , 
	Deceleration:=parameter.nDeceleration , 
	Jerk:=parameter.nJerk , 
	BufferMode:= , 
	Done=>AxisStatus.bMoveRelativeDone , 
	Busy=>AxisStatus.bMoveRelativeBusy , 
	Active=> , 
	CommandAborted=> , 
	Error=>AxisStatus.bMoveRelativeError , 
	ErrorID=> );
	
MoveAbsolute(
	Axis:=AxisRef , 
	Execute:=bMoveAbsoluteAllow , 
	Position:=parameter.nPosition , 
	Velocity:=parameter.nVelocity , 
	Acceleration:=parameter.nAcceleration , 
	Deceleration:=parameter.nDeceleration , 
	Jerk:=parameter.nJerk , 
	Direction:= , 
	BufferMode:= , 
	Done=>AxisStatus.bMoveAbsoluteDone , 
	Busy=>AxisStatus.bMoveAbsoluteBusy , 
	Active=> , 
	CommandAborted=> , 
	Error=>AxisStatus.bMoveAbsoluteError , 
	ErrorID=> );
	
MoveVelocity(
	Axis:=AxisRef , 
	Execute:=bMoveVelocityAllow , 
	Velocity:=parameter.nVelocity , 
	Acceleration:=parameter.nAcceleration , 
	Deceleration:=parameter.nDeceleration , 
	Jerk:=parameter.nJerk , 
	Direction:=parameter.nDirection , 
	BufferMode:= , 
	InVelocity=>AxisStatus.bMoveVelocityState , 
	Busy=>AxisStatus.bMoveVelocityBusy , 
	Active=> , 
	CommandAborted=> , 
	Error=>AxisStatus.bMoveVelocityError , 
	ErrorID=> );
	
//错误码
IF sComment="" THEN
	sComment:=WCONCAT("轴:",sAxisComment);
END_IF

IF AxisStatus.bInterferenceError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorInterferenceError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--干涉报警");
ELSIF AxisStatus.bPositiveLimitError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorPositiveLimitError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--正极限值报警");
ELSIF AxisStatus.bNegativeLimitError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorNegativeLimitError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--负极限值报警");
ELSIF AxisStatus.bTorqueLimitError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorTorqueLimitError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--扭矩限值报警");
ELSIF AxisStatus.nAxisErrorID>0 THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorAxisError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--NC轴报警");
ELSIF AxisStatus.bHomeError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorHomeError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--回原点报警");
ELSIF AxisStatus.bJogError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorJogError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--点动报警");
ELSIF AxisStatus.bMoveRelativeError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorMoveRelativeError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--相对运动报警");
ELSIF AxisStatus.bMoveAbsoluteError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorMoveAbsoluteError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--绝对运动报警");
ELSIF AxisStatus.bMoveVelocityError THEN
	AxisStatus.bError:=TRUE;
	AxisStatus.nErrorCode:=indexAxisErrorMoveVelocityError;
	AxisStatus.sErrorComment:=WCONCAT(sComment,"--速度运动报警");
ELSE
	AxisStatus.bError:=FALSE;
END_IF
VAR_GLOBAL
	axis:ARRAY[0..indexAxisEnd-1] OF ST_axis;
	
	axisManualId:INT;
END_VAR

PROGRAM P_axis
VAR
	i:INT;
END_VAR

//轴映射
axis[1].REF:=ADR(SM_axis1);
axis[2].REF:=ADR(SM_axis2);
axis[3].REF:=ADR(SM_axis3);

//描述信息
axis[0].sComment:="0：未选中轴";

axis[indexAxisExample1].sComment:=WCONCAT(INT_TO_WSTRING(indexAxisExample1),"：示例轴");
axis[indexAxisExample2].sComment:=WCONCAT(INT_TO_WSTRING(indexAxisExample2),"：示例2轴");
axis[indexAxisExample3].sComment:=WCONCAT(INT_TO_WSTRING(indexAxisExample3),"：示例3轴");

//干涉（若有则添加）

//轴功能块控制
FOR i:=1 TO indexAxisEnd-1 BY 1 DO
	axis[i].FB(
		AxisRef:=axis[i].REF^ , 
		bSystemStop:=system.control.bStop , 
		bSystemEmergency:=system.control.bEmergency , 
		bSystemReset:=system.control.bReset , 
		sAxisComment:=axis[i].sComment , 
		bAxisControlMode:=axis[i].bControlMode ,
		AxisControl:=axis[i].control , 
		AxisParameter:=axis[i].parameter , 
		AxisSignal:=axis[i].signal , 
		AxisOther:=axis[i].other , 
		AxisStatus=>axis[i].status );
END_FOR

WX_LW
关注
  • 12
    点赞
  • 踩
  • 8
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
codesys ethcat通讯中轴报错记录
MENGJIAN891021的博客
04-20 2613
首次在CSDN上发表文章，尝试记录调试编程过程中遇到的各种问题。 1、reset块 在异常停止时，容易导致轴的状态从sdandstill（3）切换到应急停止的状态（1），而伺服驱动器上却可能不报任何错误。此时需要使用此块。 2、reinit块 在PLC/PAC/运动控制器由stop_run后，轴通讯状态会变为1100。这里100为正常，小于100时，通讯有异常，大于100时，可以正常通讯，但轴不在运行状态。在变为1100时，需要初始化轴才能正常通讯。 3、...
CODESYS控制轴程序ST以及通讯
04-22
CODESYS控制轴程序ST以及通讯
基于CodeSys的伺服电机控制教程。
03-07
1、CodeSys电机运行代码 2、实现了电机的JOG运行、绝对位移、抓点 3、实现了实时显示电机的位置
基于CODESYS的多轴运动控制程序框架：逻辑与运动控制分离，快速开发灵活操作
nhYSYETnU的博客
04-07 462
而基于CODESYS开发的多轴运动控制程序框架，通过抽象和封装的方式，将功能模块化，使开发者能够更加高效地进行多轴运动控制程序的开发。基于codesys开发的多轴运动控制程序框架，将逻辑与运动控制分离，将单轴控制封装成功能块，对该功能块的操作包含了所有的单轴控制（归零、点动、相对定位、绝对定位、设置当前位置、伺服模式切换等等）。程序框架由主程序按照状态调用分归零模式、手动模式、自动模式、故障模式，程序状态的跳转都已完成，只需要根据不同的工艺要求完成所需的动作即可。
codesys 控制轴组程序
weixin_58619062的博客
10-08 1124
/关节绝对运动允许。//直线绝对运动允许。//圆弧绝对运动允许。
codesys 6轴机器人正解程序
weixin_58619062的博客
10-13 895
机器人轴组程序查看之前的文章。
codesys【程序】
cfqq1989的博客
01-16 1185
FB。
CODESYS 单轴控制实验
qq_42983533的博客
07-06 1578
CODESYS 单轴控制实验
codesys CNC控制程序
weixin_58619062的博客
10-11 480
CNC G代码变量x:INT;y:INT;程序//使能XMC_PowerX(Status=> ,Busy=> ,Error=> ,//使能YMC_PowerY(Status=> ,Busy=> ,Error=> ,//插补器bAbort:= ,bAcknM:= ,bDone=> ,bBusy=> ,bError=> ,
codesys【轴组】SM3_Robotics
cfqq1989的博客
06-12 3363
附加轴： 获取附加轴坐标： SMC_POSINFO (STRUCT)enable不必再调用Power，但可以利用单一轴上电去激活轴组使能。暂停： MC_GroupInterrupt。a:轴坐标，c:笛卡尔坐标，v:坐标数组。点动： SMC_GroupJog2。移动，回零，错停，待命，停止，关闭。（轴上电）是批量调用。
Codesys实现对轴的绝对定位和相对定位控制的可视化仿真程序及教程
05-18
1、Codesys运动控制库softmotion； 2、梯形图与ST混搭配合，通过全局变量连接； 3、轴定位控制，绝对...程序使用软件版本Codesys3.5.14.10 仿真运行结果视频查看地址：https://www.bilibili.com/video/BV1Sa411J7pF/
CoDeSys 机械手项目源码代码
11-20
CoDeSys 机械手项目源码代码 本程序为实际给传过去的工程，已设置为只读，并备份。
CODESYS运动控制之功能块的使用.docx
06-06
在《CODESYS运动控制之编写凸轮控制程序》中，我们用梯形图程序实现了两个轴的控制，但是在实际的运动控制中可能会与到较多轴数的控制，如果也用同样的方式对轴进行声明，那么操作起来就很繁琐。那么如何才能简化...
Codesys跟随指令实现非线性函数（正弦、椭圆）的轴联动功能源程序
01-18
Codesys使用跟随指令followposition，实现两轴之间非线性函数关系的联动功能，正弦函数，椭圆函数等都可以用此指令，可通过可视化仿真模拟验证，codesys版本为V3.5.14.10参考博客地址:...
CODESYS SoftMotion（二）单轴运动实例
Fishfishfishfishcat
03-20 6674
一、CODESYS SoftMotion编程实例 所有关于SoftMotion都会放在特定位置，可以参考学习，我自己的路径是：D:\CODESYS16\CODESYS\Projects\SoftMotion\4.6.3.0\Examples\Tutorial 3.1 单轴运动 功能块需要：使能功能块MC_Power、绝对运动功能块MC_MoveAbsolute。下面是编程步骤（极其繁琐） Ctrl+N 新建一个工程： 因为我的设备是树莓派单核，所以选择CODESYS Control for Raspber
618商品网页制作编程示例开发案列优质学习资料资源工具与案列应用场景开发文档教程资料.txt
最新发布
06-02
618商品网页制作编程示例开发案列优质学习资料资源工具与案列应用场景开发文档教程资料
329_沁心茶叶商城小程序的设计与实现-源码.zip
06-02
提供的源码资源涵盖了安卓应用、小程序、Python应用和Java应用等多个领域，每个领域都包含了丰富的实例和项目。这些源码都是基于各自平台的最新技术和标准编写，确保了在对应环境下能够无缝运行。同时，源码中配备了详细的注释和文档，帮助用户快速理解代码结构和实现逻辑。 适用人群： 这些源码资源特别适合大学生群体。无论你是计算机相关专业的学生，还是对其他领域编程感兴趣的学生，这些资源都能为你提供宝贵的学习和实践机会。通过学习和运行这些源码，你可以掌握各平台开发的基础知识，提升编程能力和项目实战经验。 使用场景及目标： 在学习阶段，你可以利用这些源码资源进行课程实践、课外项目或毕业设计。通过分析和运行源码，你将深入了解各平台开发的技术细节和最佳实践，逐步培养起自己的项目开发和问题解决能力。此外，在求职或创业过程中，具备跨平台开发能力的大学生将更具竞争力。 其他说明： 为了确保源码资源的可运行性和易用性，特别注意了以下几点：首先，每份源码都提供了详细的运行环境和依赖说明，确保用户能够轻松搭建起开发环境；其次，源码中的注释和文档都非常完善，方便用户快速上手和理解代码；最后，我会定期更新这些源码资源，以适应各平台技术的最新发展和市场需求。
codesys轴指令手册
10-24
CODESYS轴指令手册是一本用于学习和参考CODESYS软件中轴控制指令的手册。CODESYS是一种广泛应用于工业自动化领域的集成开发环境，可以用于编程、调试和控制工业机械设备。轴指令手册则是针对CODESYS中用于控制轴运动的特定指令进行了详细说明和解释。 在手册中，可以学习到如何使用CODESYS软件中的轴指令来实现各种轴控制功能，例如定位控制、速度控制、加速度控制等。手册会详细介绍每个指令的语法、参数和使用方法，以及每个指令所能实现的功能和效果。 通过学习轴指令手册，用户可以了解如何编写轴控制程序、如何配置轴参数、如何调试轴运动等。手册还提供了一些实例代码和示意图，使用户能够更好地理解指令的用法和实际应用场景。 对于工程师和技术人员来说，轴指令手册是非常重要和有用的工具。它可以帮助他们更高效地使用CODESYS软件，并能够更准确地实现轴控制功能。通过手册的学习和参考，用户可以快速掌握CODESYS轴控制的编程技巧和最佳实践，提高工作效率和产品质量。 总之，CODESYS轴指令手册对于想要学习和掌握CODESYS轴控制编程的人来说是一个重要的参考工具，它提供了详细、全面的指令说明和实例，帮助用户更好地理解和应用轴控制指令。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值