UnityShader入门精要第十章代码解析（Cubemap反射）

Shader "Unlit/NewUnlitShader"
{
	Properties
	{
		_Color("Color Tint",Color) = (1,1,1,1)
		_ReflectionColor("Reflection Color",Color) = (1,1,1,1)
		_ReflectionAmount("Reflection Amount",Range(0,1)) = 1
		_CubeMap("CubeMap",Cube) = "_Skybox"{}
		_MainTex("MainTex",2D) = "white"{}
	}

	SubShader
	{
		Tags{"RenderType" = "Opaque" "Queue" = "Geometry"}

		pass
		{	
			Tags{"LightMode" = "ForwardBase"}

			CGPROGRAM

			#pragma multi_compile_fwdbase	
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"

			fixed4 _Color;
			fixed4 _ReflectionColor;
			fixed _ReflectionAmount;
			samplerCUBE _CubeMap;
			sampler2D _MainTex;
			float4 _MainTex_ST;

			struct a2v
			{	
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f
			{	
				float4 pos :SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float3 worldViewDir : TEXCOORD2;
				float3 worldRefl : TEXCOORD3;
				float2 uv : TEXCOORD4;
				SHADOW_COORDS(5)
			};

			v2f vert(a2v v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);

				//reflect（出射方向，法线）计算出入射光线方向
				o.worldRefl = reflect(-o.worldViewDir,o.worldNormal);

				o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

				TRANSFER_SHADOW(o);

				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

				
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,lightDir));

				//texCUBE(cubemap,入射光线方向)
				fixed3 reflection = texCUBE(_CubeMap,i.worldRefl).rgb * _ReflectionColor.rgb;

				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

				//lerp(线性插值)，当_ReflectionAmount取到 0 时diffuse为MainTex颜色，为1时则全反射
				fixed3 color = ambient + lerp(diffuse,reflection,_ReflectionAmount) * atten;

				return fixed4(color,1.0);

			}

			ENDCG

		}

	}
	FallBack "Reflective/VertexLit"
}

                //reflect（出射方向，法线）计算出入射光线方向
                o.worldRefl = reflect(-o.worldViewDir,o.worldNormal);

                //texCUBE(cubemap,入射光线方向)
                fixed3 reflection = texCUBE(_CubeMap,i.worldRefl).rgb * _ReflectionColor.rgb;

                //lerp(线性插值)，当_ReflectionAmount取到 0 时diffuse为MainTex颜色，为1时则全反射
                fixed3 color = ambient + lerp(diffuse,reflection,_ReflectionAmount) * atten;

_ReflectionAmount 为0时

 

_ReflectionAmount 为1时