动画效果往都是把时间添加到一些变量中计算做出来的效果。
纹理动画
这个在移动平台用的比较多,因为可以用来代替复杂的粒子效果。
下面图片纹理动画的序列帧截图:
图片的wrap mode类型需要选择Repeat。
下面是代码,解释都加在注释里了:
动画往往是透明的,让你以Queue和RenderType要设置成Transparent并把IgnoreProjector设置为True。
思路如下:
通过时间的改变修改图片中的UV,使其每个时间只显示对应的图像。
Shader "Unity Shaders Book/Chapter 11/Image Sequence Animation" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Image Sequence", 2D) = "white" {}
//水平动画数
_HorizontalAmount ("Horizontal Amount", Float) = 4
//垂直动画数
_VerticalAmount ("Vertical Amount", Float) = 4
//动画速度
_Speed ("Speed", Range(1, 100)) = 30
}
SubShader {
//透明混合、关闭投影、转置
Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
Pass {
Tags { "LightMode"="ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
float _HorizontalAmount;
float _VerticalAmount;
float _Speed;
struct a2v {
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
};
v2f vert (a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag (v2f i) : SV_Target {
//时间乘以速度
float time = floor(_Time.y * _Speed);
//时间除以列数以得到行数 数值超级最大值会折算的
float row = floor(time / _HorizontalAmount);
//时间减去高数乘以水平个数得到列数
float column = time - row * _HorizontalAmount;
// half2 uv = float2(i.uv.x /_HorizontalAmount, i.uv.y / _VerticalAmount);
// uv.x += column / _HorizontalAmount;
// uv.y -= row / _VerticalAmount;
//算出当前UI应在的位置
half2 uv = i.uv + half2(column, -row);
uv.x /= _HorizontalAmount;
uv.y /= _VerticalAmount;
//根据UI来取图片进行显示
fixed4 c = tex2D(_MainTex, uv);
c.rgb *= _Color;
return c;
}
ENDCG
}
}
FallBack "Transparent/VertexLit"
}