前言:本篇博客只是一个简单的实现边缘泛光功能的例子,主要是当做笔记使用。
核心要点:
1.使用法向量和视角向量的点积值来获取明亮度,从模型边缘到模型中心点积值从0~1变化。点积值为负数说明当前顶点在平面背面,摄像机视角看不到,可以不做明亮度处理。点积值为正值时,说明当前顶点在平面正面,可以结合衰减系数调用pow接口来获取衰减后的明亮值。
2.第一个pass主要是沿着法向量方向缩放模型,并从模型中心点往模型边缘处明亮度从1->0的变化,然后和颜色缓冲区中的颜色进行透明度混合处理。效果如图所示:
3.第二个pass主要是在源模型大小进行原色输出,然后用第一个pass中的颜色减去当前pass中的颜色和第一个pass中颜色的透明度值,从而来实现源模型处镂空的效果。效果如图所示:
4.使用第三个pass从模型中心点往模型边缘处明亮度从0->1的变化,然后和上面pass中的颜色进行透明度混合处理。效果图如下所示:
5.由于使用了多个pass,且每个pass都对模型做了处理。为了得到正确的层级效果,需要关闭深度写入。
核心代码:如下所示:
Shader "Custom/Rim" {
Properties {
// 模型主颜色
_MainColor("MainColor", COLOR) = (1, 1, 1, 1)
// 模型明亮度衰减因子
_Scale("Scale", Range(1, 8)) = 2
// 模型外围缩放因子
_Outer("Outer", Range(0, 1)) = 0.2
}
SubShader {
// 开启透明度混合
Tags { "Queue" = "Transparent" "RenderType" = "Transparent" "IgnoreProjector" = "TRUE" }
pass {
// 与颜色缓冲区中的颜色进行混合处理:当前pass中获取的颜色透明度越大,越显示当前颜色多点。
blend SrcAlpha OneMinusSrcAlpha
zwrite off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "unitycg.cginc"
struct v2f {
float4 pos:POSITION0;
float3 normal:POSITION1;
float4 vertex:POSITION2;
};
fixed4 _MainColor;
float _Scale;
float _Outer;
v2f vert(appdata_base v)
{
v2f o;
// 沿着法线方向缩放顶点
v.vertex.xyz += v.normal * _Outer;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.vertex = v.vertex;
o.normal = v.normal;
return o;
}
fixed4 frag(v2f v):COLOR0
{
float3 N = UnityObjectToWorldNormal(v.normal);
float3 V = normalize(WorldSpaceViewDir(v.vertex));
// 通过法向量和视角向量的点积值来获取明亮度:
// 1.模型边缘点积值为0,模型中心点积值为1。从模型中心到边缘,明亮值从1-》0的变换。
// 2.点积负值表示当前视角看的顶点所在平面背面,可以不做处理。
float bright = saturate(dot(N, V));
// 通过衰减系数来获取明亮度:衰减系数越大,越往模型边缘偏移的明亮值会越小。
bright = pow(bright, _Scale);
// 通过明亮值来限定模型颜色的透明度,从而达到外围光晕效果
_MainColor.a *= bright;
return _MainColor;
}
ENDCG
}
pass {
// 使用上一个pass中获取的目标颜色来减去当前pass中获取的源颜色,从而将当前模型镂空
blendop revsub
blend dstalpha one
zwrite off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "unitycg.cginc"
struct v2f {
float4 pos:POSITION0;
};
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
return o;
}
fixed4 frag(v2f v):COLOR0
{
return fixed4(1, 1, 1, 1);
}
ENDCG
}
pass {
// 与上面pass中的颜色进行混合处理:当前pass中获取的颜色透明度越大,越显示当前颜色多点。
blend SrcAlpha OneMinusSrcColor
zwrite off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "unitycg.cginc"
struct v2f {
float4 pos:POSITION0;
float3 normal:POSITION1;
float4 vertex:POSITION2;
};
float _Scale;
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.vertex = v.vertex;
o.normal = v.normal;
return o;
}
fixed4 frag(v2f v):COLOR0
{
float3 N = UnityObjectToWorldNormal(v.normal);
float3 V = normalize(WorldSpaceViewDir(v.vertex));
// 通过法向量和视角向量的点积值来获取明亮度:
// 1.模型边缘点积值为0,模型中心点积值为1。
// 2.使用1.0减去点积结果值就可以表示从模型边缘到模型中心,明亮值从1-》0的变换。
float bright = 1.0 - saturate(dot(N, V));
// 通过衰减系数来获取明亮度:衰减系数越大,越往模型中心偏移的明亮值会越小。
bright = pow(bright, _Scale);
return fixed4(1, 1, 1, 1) * bright;
}
ENDCG
}
}
}
运行效果:如下图所示: