在UnityShader中实现漫反射光照模型

关于模型空间，世界空间等的区别可见：

(23条消息) D3D11世界空间，观察空间和模型空间（静态摄像头）_x-2010的笔记-CSDN博客_观察空间

         逐顶点的漫反射光照实现：

Shader "Custom/DiffuseVertexLevel"
{
    Properties
    {
        _DiffuseColor("color", Color) = (1.0, 1.0, 1.0, 1.0)
    }
    SubShader
    {
        Pass
        {
            Tags{
                "LightMode" = "ForwardBase"
            }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            half4 _DiffuseColor;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 color : COLOR;
            };

            v2f vert (appdata v)
            {
                v2f o;
                UNITY_INITIALIZE_OUTPUT(v2f, o);
                o.vertex = UnityObjectToClipPos(v.vertex);

                half3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                half3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                half3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                half3 mdiffuse = _LightColor0.rgb * _DiffuseColor * saturate(dot(worldNormal, worldLight));

                o.color = mdiffuse + ambient;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return fixed4(i.color, 1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

 saturate函数：把参数截取到[0, 1]范围内，saturate(x)的作用是如果x取值小于0，则返回值为0。如果x取值大于1，则返回值为1。若x在0到1之间，则直接返回x的值。

        结果可以看出来，在向光面和背光面交界处有明显锯齿存在，这是由于使用顶点计算光照的原因，对于细分程度较低的模型会存在一些视觉问题，但对于细分程度高的模型则不会出现这种情况。

        对于代码中涉及的法线变化，mul(v.normal, (float3x3)unity_WorldToObject)。假设使用3×3的变换矩阵M来变换顶点，则对于法线的变换矩阵为M的逆转置矩阵（具体推导见《UnityShader入门精要》章节4.7）。如果同样使用矩阵M对法线进行变换，可能会出现如下图的问题。

        逐像素漫反射光照实现： 

Shader "Custom/DiffusePixelLevel"
{
    Properties
    {
        _DiffuseColor("color", Color) = (1.0, 1.0, 1.0, 1.0)
    }
    SubShader
    {
        Pass
        {
            Tags{
                "LightMode" = "ForwardBase"
            }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            half4 _DiffuseColor;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
            };

            v2f vert (appdata v)
            {
                v2f o;
                UNITY_INITIALIZE_OUTPUT(v2f, o);
                o.vertex = UnityObjectToClipPos(v.vertex);
                
                o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                half3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                half3 mdiffuse = _LightColor0.rgb * _DiffuseColor * saturate(dot(normalize(i.worldNormal), worldLight));

                half3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                half3 color = mdiffuse + ambient;

                return fixed4(color, 1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

         显然，逐像素的漫反射不会有锯齿出现。

原因：对于逐顶点的漫反射光照，在顶点着色器中计算光照，在片元着色器中通过对顶点着色器的光照进行插值得到像素颜色。在逐像素的漫反射光照中，计算光照在片元着色器中，通过对法线进行插值得到像素的法线，然后计算光照。

         分析：直接使用顶点颜色对像素颜色插值是线性插值，但显然由光照的计算公式知光照与法线和光照方向的叉积有关，即与cos(法线，光照方向)有关，对于像素来说，像素的法线是线性变化的，可以直接插值处理的。但光照并不是线性变化的，而是以余弦函数变化。所以在细分程度较低的模型中，直接对法线插值才能得到比对光照插值更符合现实的光照。

        实现HalfLambert模型

Shader "Custom/HalfLambert"
{
    Properties
    {
        _DiffuseColor("color", Color) = (1.0, 1.0, 1.0, 1.0)
    }
    SubShader
    {
        Pass
        {
            Tags{
                "LightMode" = "ForwardBase"
            }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            half4 _DiffuseColor;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
            };

            v2f vert (appdata v)
            {
                v2f o;
                UNITY_INITIALIZE_OUTPUT(v2f, o);
                o.vertex = UnityObjectToClipPos(v.vertex);
                
                o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                half3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                half3 mdiffuse = _LightColor0.rgb * _DiffuseColor * 0.5 * dot(normalize(i.worldNormal), worldLight) + 0.5;

                half3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                half3 color = mdiffuse + ambient;

                return fixed4(color, 1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

HalfLambert模型在原基础上进一步添加了环境光(ambient)，使得暗面也同样有光照。

         高光反射光照模型实现（基于顶点着色器）：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Custom/SpecularVertexLevel"
{
    Properties
    {
        _DiffuseColor("Color", Color) = (1.0, 1.0, 1.0, 1.0)
        _GlossColor("GlossColor", Color) = (1.0, 1.0, 1.0, 1.0)
        _Gloss("Gloss", float) = 1
    }
    SubShader
    {
        Pass
        {
            Tags{
                "LightMode" = "ForwardBase"
            }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            half4 _DiffuseColor;

            half4 _GlossColor;

            float _Gloss;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 color : COLOR;
            };

            v2f vert (appdata v)
            {
                v2f o;
                UNITY_INITIALIZE_OUTPUT(v2f, o);
                o.vertex = UnityObjectToClipPos(v.vertex);

                half3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                half3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                half3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                half3 mdiffuse = _LightColor0.rgb * _DiffuseColor.rgb * saturate(dot(worldNormal, worldLight));

                half3 worldCamera = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);

                half3 specular = _LightColor0.rgb * _GlossColor.rgb * pow(saturate(dot(worldCamera, normalize(reflect(-worldLight, worldNormal)))), _Gloss);

                o.color = mdiffuse + ambient + specular;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return fixed4(i.color, 1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

 _WorldSpaceLightPos0：返回的是顶点到光源的单位向量。所以在计算反射方向时用负值计算。