7.纹理

最新推荐文章于 2022-09-02 18:59:43 发布

ght_1995

最新推荐文章于 2022-09-02 18:59:43 发布

阅读量257

点赞数

本文链接：https://blog.csdn.net/ght_1995/article/details/88807437

版权

7.基础纹理
纹理，就是一张图片来控制模型的外观。
纹理坐标定义了该顶点在纹理中对应的2D坐标。
纹理坐标，是针对一张纹理图片而言，他是将一张图片作为一个坐标系，横轴u，纵轴v，将图片放在（0,0）到（1,1）的空间之中。

纹理实际上是一个二维数组，它的元素是一些颜色值。单个的颜色值被称为纹理元素（texture elements）或纹理像素（texel）。每一个纹理像素在纹理中都有一个唯一的地址。这个地址可以被认为是一个列（column）和行（row）的值，它们分别由U和V来表示。

对于屏幕空间中的每一个像素，我们来计算相应的纹理空间中的纹理像素位置。对那一点上的或那一点周围的纹理颜色进行采样（sample）。采样过程被称为纹理过滤（texture filtering）。

屏幕空间的像素->计算对应的纹理空间的纹理像素位置->采样获得颜色值->颜色值赋给屏幕空间的像素

（u，v）来确定坐标
1.tex2D（_MainTex,float2(x,y)）,对当前纹理进行采样，得到的是一般是fixed3的颜色信息
Float2（x,y）是当前纹理的uv坐标。（u和v都是在（0,1）之间的）
一．单张纹理
1.纹理属性

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
/*
单张纹理
*/
Shader "Custom/test7.1" {
Properties{
_Color("COLOR Tint",Color)=(1.0,1.0,1.0,1.0)
_MainTex("Main Tex",2D)="white" {}//2D是纹理属性的声明方式
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256))=20
}
SubShader {
        
pass{
Tags{"LightMode"="ForwardBase"}//确定该Pass在光照流水线的角色
    CGPROGRAM
    #pragma vertex vert
    #pragma fragment frag
#include"Lighting.cginc" 
    fixed4 _Color;
    sampler2D _MainTex;
    //纹理名_ST来声明某个纹理的属性，ST是缩放scale和平移tranlation的缩写 
    //_MainTex_ST.xy存储的是缩放值，_MainText_ST.zw存储的是偏移值
    //sampler2D是声明纹理的格式
    float4 _MainTex_ST;
    fixed4 _Specular;
    float _Gloss; 
     struct a2v{
float4 vertex: POSITION;
     float3 normal: NORMAL;
     float4 texcoord : TEXCOORD0;//纹理坐标，float4类型
    };
    struct v2f{
        float4 pos:SV_POSITION; //pos变成SV_POSITION
        float3 worldNormal : TEXCOORD0;
        float3 worldPos :TEXCOORD1;
        float2 uv:TEXCOORD2;
    
    };
    v2f vert (a2v v )
    {
        v2f o;
 //将v.vertex从模型空间转到裁剪空间
o.pos=UnityObjectToClipPos(v.vertex);
//把法线从模型空间转换到世界空间中
        o.worldNormal=UnityObjectToWorldNormal(v.normal);
//把顶点坐标由模型空间转到世界空间中
        o.worldPos= mul(unity_ObjectToWorld, v.vertex).xyz;
o.uv= v.texcoord.xy *_MainTex_ST.xy + _MainTex_ST.zw;
//uv就是坐标（x，y）
        
        return o;
    }
//#define TRANSFORM_TEX(tex,name) (tex.xy * name ## _ST.xy +name##_ST.zw)
    fixed4 frag(v2f i):SV_Target
    {
    
        float3 worldNormal = normalize(i.worldNormal);
//在顶点坐标由物体坐标转到世界坐标之后，获取世界坐标系中光的方向        
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
//tex2D对纹理进行采样        
fixed3 albedo=tex2D(_MainTex,i.uv).rgb * _Color.rgb;
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
//max（a，b）即取得a与b之间的最大值
        fixed3 diffuse =_LightColor0.rgb *albedo*max(0,dot(worldNormal,worldLightDir));
        //fixed3 reflectDir = normalize(_WorldSpaceCameraPos.xyz -i.worldPos.xyz );
fixed3 viewDir=normalize(normalize(UnityWorldSpaceViewDir(i.worldPos)));
        
        fixed3 halfDir= normalize(worldLightDir + viewDir); 
fixed3 specular=_LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);       
        return fixed4(ambient + diffuse + specular,1.0);
    }
        ENDCG
    }
    }
}

Warp Mode：
（1）repeat 当选取这种模式时，若纹理坐标超过1 ，它的整数部分会被舍弃，直接用小数部分进行采样，结果是，纹理不断重复
（2）clamp 当选取这种模式时，若纹理坐标超过1，那么将截取到1。如果小于0，那么截取到0

FilterMode:
选择滤波模式。
二．凹凸映射
在表面纹理细节比较丰富时，模型会给GPU渲染带来大量工作，所以使用一张纹理，来表现效果。法向量与光向量点积可以决定一个点亮还是暗，因此可以控制法向量，即一张存储法线信息的纹理图片。
1.在切线空间下计算：
原理：即改变光照计算下的法线信息，在片元着色内通过一张法线纹理进行采样，得到切线空间下某点的法线值，然后再与切线空间下的视角方向，光照方向等进行计算，得到光照

Shader "Unity Shaders Book/Chapter 7/Normal Map Tangent Space" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1) 
_MainTex("Main Tex", 2D ) = "white" {}
// 法线纹理
// bump是Unity内置的法线纹理
_BumpMap("Normap Map", 2D) = "bump" {}
// 用于控制凹凸程度，当它为0时，意味着该法线纹理不会对光照产生任何影响
_BumpScale("Bump Scale", Float) = 1.0
_Specular("Specular", Color) = (1, 1, 1, 1)
_Gloss("Gloss", Range(8.0, 256)) = 20
}
SubShader {
Pass {
Tags {"LightMode"="ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
// 与Properties语义块中的属性建立联系
fixed4 _Color;
sampler2D _MainTex;
// 得到MainTex纹理属性的平铺和偏移系数
float4 _MainTex_ST;
sampler2D _BumpMap;
// 得到法线纹理的平铺和偏移系数
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
// 顶点的切线方向
// 需要使用tangent.w分量来决定切线空间中的第三个坐标轴-副切线的方向性
//副切线，在切线空间中，由切线以及法线叉乘得到，并且与切线和法线一起组成了切线空间
float4 tangent : TANGENT;//切线
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
//texcoord 纹理坐标
float4 uv : TEXCOORD0;
// 光照方向
float3 lightDir : TEXCOORD1;
// 视角方向
float3 viewDir : TEXCOORD2;
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);//转入裁剪空间
//出于减少插值寄存器的使用数目的目的，我们往往只计算和存储一个纹理坐标即可
// uv的xy分量存储了_MainTex的纹理坐标（包括缩放和平移）
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
// uv的zw分量存储了_BumpMap的纹理坐标（包括缩放和平移）
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
// 将模型空间下的切线方向、副切线方向和法线方向按行排列得到从模型空间到切线空间的变换矩阵rotation。
// 之所以和w分量相乘，是为了决定使用哪一个方向
// float3 binormal = cross( normalize(v.normal), normalize(v.tangent.xyz) ) * v.tangent.w; 
// float3x3 rotation = float3x3( v.tangent.xyz, binormal, v.normal )
TANGENT_SPACE_ROTATION;
//TANGENT_SPACE_ROTATION;是Unity提供的一个宏，它定义了一个rotation矩阵用于从Object Space变换到Tangent Space。
// Transform the light direction from object space to tangent space
// ObjSpaceLightDir用于得到模型空间下的光照方向,与rotation相乘得到切线空间下的光照方向
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
// ObjSpaceViewDir用于得到模型空间下的视角方向，同理，与rotation相乘得到切线空间下的视角方向
o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
// 采样得到切线空间下的法线方向，再在切线空间下进行光照计算即可
fixed4 frag(v2f i) : SV_Target {
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.viewDir);
// Get the texel in the normal map
// 法线纹理中存储的是经过映射后得到的像素值,tex2D是对图形进行采样，得到的是像素值
fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
fixed3 tangentNormal;
// If the texture is not marked as "Normal map"
// tangentNormal.xy = (packedNormal.xy * 2 - 1 ) * _BumpScale;
// tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
// Or mark the texture as "Normal map", and use the built-in funciton
//UnpackNormal 对像素值进行处理,得到法线值
tangentNormal = UnpackNormal(packedNormal);
tangentNormal.xy *= _BumpScale;
//法线是单位矢量
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
//对纹理图片进行采样
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal,halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
Fallback "Specular"
}

注：凹凸映射在unity已经写好，并且封装好，本次学习以原理为主。