《Unity Shader入门精要》第六章 笔记

整理之后的 shader

Shader "Unity Shaders Book/Chapter6" {

    Properties 
    {
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular", Color) = (1,1,1,1)
        _Gloss("Gloss", Range(8.0,256)) = 20
    }

    SubShader
    {
        Pass
        {
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM

            //定义顶点着色器函数和片段着色器函数
            #pragma vertex vert
            #pragma fragment frag

            //为了访问光源相关参数，要引入 Lighting 库
            #include "Lighting.cginc"

            float4 _Diffuse;
            float4 _Specular;
            float _Gloss;

            //传入顶点着色器的参数
            struct a2v 
            {
                float4 vertex : POSITION; //顶点坐标
                float3 normal : NORMAL; //法线坐标
            };

            //片元着色器参数，在顶点着色器返回值上进行插值后传入
            struct v2f 
            {
                float4 pos : SV_POSITION; //必须的参数，而且是固定的转换方式，把顶点坐标从模型空间转到裁剪空间中，利用 UnityObjectToClipPos(vertex)
                float3 worldNormal : TEXCOORD0; //世界空间中的法线向量
                float3 worldPos : TEXCOORD1; //像素点在世界空间中的坐标
            };

            //顶点着色器，顶点着色器只作用在每个顶点，其它像素点通过插值传入片元着色器处理
            v2f vert(a2v v)
            {
                v2f o;
                //固定写法，把顶点坐标从模型空间转换到世界坐标
                o.pos = UnityObjectToClipPos(v.vertex); 

                //把顶点法线向量从模型空间转换到世界空间，如果直接用 ObjectToWorld，法线方向会错乱。
                //法线必须要用 ObjectToWorld 的逆矩阵的转置矩阵相成，通过调换乘法位置，可以去掉逆矩阵转换的步骤，
                //所以下面的代码相当于 mul(transpose((float3x3)unity_WorldToObject), v.normal); 
                //因为 ( ` 符号相当于转置操作)  (M`v)`` = (vM)` 但结果是矢量，所以 (vM)` = vM
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                //把顶点坐标从模型空间转换到世界空间中
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //获取环境光部分，环境光直接加到输出结果中即可
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //世界空间中的法线向量归一化
                fixed3 worldNormal = normalize(i.worldNormal);

                //世界空间中光线的方向，指向光源的方向
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                //计算漫反射，注意 _LightColor0.rgb * _Diffuse.rgb 是一个矢量，而不是标量，它的结果 = (_LightColor0.r * _Diffuse.r, _LightColor0.g * _Diffuse.g, _LightColor0.b * _Diffuse.b)
                //注意用了 max 操作之后，与光线方向夹角大于 90 的面是完全不吃光的，这样背光的地方看起来就完全一样
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));

                //半兰伯特模型
                //fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (dot(worldNormal, worldLightDir) * 0.5 + 0.5);

                //计算高光反射 Bilinn 模型
                //世界坐标下的视角方向，从点到相机的方向
                fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                //求视角方向和光线方向的平均方向
                fixed3 halfDir = normalize(worldViewDir + worldLightDir);

                //计算高光反射的值，因为是 pow 的关系，而且 dot(worldNormal, halfDir) 小于 1，所以 _Gloss 越大 高光部分越小
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);

                //返回最终颜色，把 环境光 加 漫反射 加 高光反射 写入结果
                return fixed4(ambient + diffuse + specular, 1.0);
            }

            ENDCG
        }
    }

    //如果上面的 shader 都不行，则用默认的 Specular Shader
    FallBack "Specular"
}