基础概念
- 辐照度(irradiance):对光进行量化使用
- 散射(scattering):改变光的方向,但不改变光的密度和颜色,一般光线在物体表面进行散射后的结果
- 折射(refraction)或透射(transmission):散射到物体内部
- 不透明物体:光在内部的颗粒进行相交,多次弹射后最终也会有部分光会重新射出表面,另外的部分就被吸收;
- 反射(reflection):散射到外部
- 吸收(absorption):只改变光的密度和颜色
- 出射度(exitance):射出光线的数量和方向,辐照度和出射度是满足线性关系(?不理解);
光照模型
- 计算机图形学第一定律:如果它看起来是对的,那么它就是对的
- BRDF光照模型:
- 标准光照模型:自发光 + 高光反射 + 漫反射 + 环境光
- 兰伯特定律(Lambert`s law):反射光线的强度与表面法线和光源方向之间夹角余弦值成正比
- Phong光照模型
- Blinn-Phong光照模型:利用半程向量对Phong光照模型进行计算优化;
- 局限性:无法表现很多重要的物理现象,例如菲涅尔反射、物体材质是各项异性(固定视角和光源方向,旋转物体表面时反射发生变化)
着色频率
- 逐平面:Flat Shading
- 逐顶点:Gouraud Shading
- 逐像素:Phong Shading
环境光配置
Unity中实现漫反射光照模型
逐顶点光照
- 注意:
- 书中
Fallback "Diffuse"
已经不满足Unity2023.2.20版本下的ShaderLab语法,因此暂时没有添加成功,所以我先临时移除 - 辐射度的计算中需要将法线方向转换为世界坐标空间,主要是光照方向是Unity提供的内建变量且在世界坐标空间中,只有在相同的坐标空间下点成计算才有意义
Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level" {
Properties{
_Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
}
SubShader{
Pass{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
struct a2v {
float4 vertex : POSITION;
float3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
fixed3 color: COLOR;
};
v2f vert(a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
o.color = ambient + diffuse;
return o;
}
fixed4 frag(v2f i): SV_Target {
return fixed4(i.color, 1.0);
}
ENDCG
}
}
}
逐像素光照
- 注意:
v2f.worldNormal
是使用TEXCOORD0
,但其实不太理解为何如此;
Shader "Unity Shaders Book/Chapter 6/Diffuse Pixel-Level" {
Properties{
_Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
}
SubShader{
Pass{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
struct a2v {
float4 vertex : POSITION;
float3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
float3 worldNormal: TEXCOORD0;
};
v2f vert(a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
return o;
}
fixed4 frag(v2f i): SV_Target {
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(i.worldNormal, worldLight));
fixed3 color = ambient + diffuse;
return fixed4(color, 1.0);
}
ENDCG
}
}
}
半兰伯特光照模型(Half Lambert Light Model)
- 背景:针对背光面阴暗的问题,即使通过环境光也并不是很好解决,因此提出了改善技术:半兰伯特光照模型
- 注意:没有物理依据,仅仅是视觉加强技术
- 兰伯特光照模型:背光处失去了模型的细节
- 半兰伯特光照名:相同的角度下改用半兰伯特材质效果
- 对比不同模型的效果,半兰伯特虽然在光照背面能看到对象细节,但正面看起来有点塑料感(不真实)
Shader "Unity Shaders Book/Chapter 6/Half Lambert" {
Properties{
_Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
}
SubShader{
Pass{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
struct a2v {
float4 vertex : POSITION;
float3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
float3 normal: NORMAL;
};
v2f vert(a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.normal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
return o;
}
fixed4 frag(v2f i): SV_Target {
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (0.5 * dot(i.normal, worldLight) + 0.5);
fixed3 color = ambient + diffuse;
return fixed4(color, 1.0);
}
ENDCG
}
}
}
实现高光反射模型
逐顶点光照
- 注意
- 反射方向计算中注意normalize归一化以及worldLight要取反方向(主要是reflect函数对传入参数的要求如此)
- dot函数是传入2个参数(以为是Eigen库中的用法)
- Unity的内建变量要多记忆和使用(刻意练习)
- 效果表现:整体看高光部分不够平滑,相对粗糙
Shader "Unity Shaders Book/Chapter 6/Specular Vertex-Level"{
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader{
Tags {
"LightMode" = "ForwardBase"
}
Pass{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
fixed3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
fixed3 color: COLOR;
};
v2f vert(a2v i){
v2f o;
o.pos = UnityObjectToClipPos(i.vertex);
float3 worldNormal = mul(i.normal, (float3x3)unity_WorldToObject);
float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
float3 r = normalize(reflect(-worldLight, worldNormal));
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, i.vertex).xyz);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, worldNormal));
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(r, viewDir)), _Gloss);
o.color = ambient + diffuse + specular;
return o;
}
fixed4 frag(v2f i): SV_Target {
return fixed4(i.color, 1.0);
}
ENDCG
}
}
}
逐像素高光(Phong光照模型)
Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader{
Tags {
"LightMode" = "ForwardBase"
}
Pass{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
fixed3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
};
v2f vert(a2v i){
v2f o;
o.pos = UnityObjectToClipPos(i.vertex);
o.worldNormal = mul(i.normal, (float3x3)unity_WorldToObject);
o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
return o;
}
fixed4 frag(v2f i): SV_Target {
float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
float3 r = normalize(reflect(-worldLight, i.worldNormal));
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, i.worldNormal));
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(r, viewDir)), _Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color, 1.0);
}
ENDCG
}
}
}
Blinn-Phong光照模型
- 效果对比:Blinn-Phong光照模型的高光效果看起来更亮,更大
Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader{
Tags {
"LightMode" = "ForwardBase"
}
Pass{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
fixed3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
};
v2f vert(a2v i){
v2f o;
o.pos = UnityObjectToClipPos(i.vertex);
o.worldNormal = normalize(mul(i.normal, (float3x3)unity_WorldToObject));
o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
return o;
}
fixed4 frag(v2f i): SV_Target {
float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
fixed3 h = normalize(viewDir + worldLight);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, i.worldNormal));
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, h)), _Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color, 1.0);
}
ENDCG
}
}
}
改用内建函数
Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader{
Tags {
"LightMode" = "ForwardBase"
}
Pass{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
fixed3 normal: NORMAL;
};
struct v2f {
float4 pos: SV_POSITION;
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
};
v2f vert(a2v i){
v2f o;
o.pos = UnityObjectToClipPos(i.vertex);
o.worldNormal = normalize(UnityObjectToWorldNormal(i.normal));
o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
return o;
}
fixed4 frag(v2f i): SV_Target {
float3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 h = normalize(viewDir + worldLightDir);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLightDir, i.worldNormal));
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, h)), _Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color, 1.0);
}
ENDCG
}
}
}