第六章-Unity中的基础光照

已于 2024-10-03 11:56:22 修改
阅读量688 收藏 13
点赞数 14
分类专栏： Unity Shader入门精要 文章标签： unity 游戏引擎
于 2024-10-03 09:59:35 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_15792541/article/details/142685052
版权

基础概念

  • 辐照度（irradiance）：对光进行量化使用
  • 散射（scattering）：改变光的方向，但不改变光的密度和颜色，一般光线在物体表面进行散射后的结果
    • 折射（refraction）或透射（transmission）：散射到物体内部
      • 不透明物体：光在内部的颗粒进行相交，多次弹射后最终也会有部分光会重新射出表面，另外的部分就被吸收；
    • 反射（reflection）：散射到外部
  • 吸收（absorption）：只改变光的密度和颜色
  • 出射度（exitance）：射出光线的数量和方向，辐照度和出射度是满足线性关系（？不理解）；

光照模型

  • 计算机图形学第一定律：如果它看起来是对的，那么它就是对的
    • 《3D数学基础：图形与游戏开发》-作者：邓恩
  • BRDF光照模型：
  • 标准光照模型：自发光 + 高光反射 + 漫反射 + 环境光
  • 兰伯特定律（Lambert`s law）：反射光线的强度与表面法线和光源方向之间夹角余弦值成正比
  • Phong光照模型
  • Blinn-Phong光照模型：利用半程向量对Phong光照模型进行计算优化；
    • 局限性：无法表现很多重要的物理现象，例如菲涅尔反射、物体材质是各项异性（固定视角和光源方向，旋转物体表面时反射发生变化）

着色频率

  • 逐平面：Flat Shading
  • 逐顶点：Gouraud Shading
  • 逐像素：Phong Shading

环境光配置

在这里插入图片描述

Unity中实现漫反射光照模型

逐顶点光照
  • 注意：
    • 书中Fallback "Diffuse"已经不满足Unity2023.2.20版本下的ShaderLab语法，因此暂时没有添加成功，所以我先临时移除
    • 辐射度的计算中需要将法线方向转换为世界坐标空间，主要是光照方向是Unity提供的内建变量且在世界坐标空间中，只有在相同的坐标空间下点成计算才有意义
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level" {
    Properties{
        _Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
    }
    SubShader{
        Pass{
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                fixed3 color: COLOR;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                o.color = ambient + diffuse;
                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                return fixed4(i.color, 1.0);
            }


            ENDCG


        }

    }
}

在这里插入图片描述

逐像素光照

  • 注意：
    • v2f.worldNormal是使用TEXCOORD0，但其实不太理解为何如此；
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Unity Shaders Book/Chapter 6/Diffuse Pixel-Level" {
    Properties{
        _Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
    }
    SubShader{
        Pass{
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(i.worldNormal, worldLight));

                fixed3 color = ambient + diffuse;

                return fixed4(color, 1.0);
            }


            ENDCG


        }

    }
}

在这里插入图片描述

半兰伯特光照模型（Half Lambert Light Model）

  • 背景：针对背光面阴暗的问题，即使通过环境光也并不是很好解决，因此提出了改善技术：半兰伯特光照模型
  • 注意：没有物理依据，仅仅是视觉加强技术
  • 兰伯特光照模型：背光处失去了模型的细节在这里插入图片描述
  • 半兰伯特光照名：相同的角度下改用半兰伯特材质效果
    在这里插入图片描述
  • 对比不同模型的效果，半兰伯特虽然在光照背面能看到对象细节，但正面看起来有点塑料感（不真实）
    在这里插入图片描述
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Unity Shaders Book/Chapter 6/Half Lambert" {
    Properties{
        _Diffuse ("Diffuse", COLOR) = (1, 1, 1, 1)
    }
    SubShader{
        Pass{
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                float3 normal: NORMAL;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.normal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (0.5 * dot(i.normal, worldLight) + 0.5);

                fixed3 color = ambient + diffuse;

                return fixed4(color, 1.0);
            }


            ENDCG


        }

    }
}

实现高光反射模型

逐顶点光照
  • 注意
    • 反射方向计算中注意normalize归一化以及worldLight要取反方向（主要是reflect函数对传入参数的要求如此）
    • dot函数是传入2个参数（以为是Eigen库中的用法）
    • Unity的内建变量要多记忆和使用（刻意练习）
  • 效果表现：整体看高光部分不够平滑，相对粗糙
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unity Shaders Book/Chapter 6/Specular Vertex-Level"{
    Properties {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader{
        Tags {
            "LightMode" = "ForwardBase"
        }
        Pass{
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                fixed3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                fixed3 color: COLOR;
            };


            v2f vert(a2v i){
                v2f o;
                o.pos = UnityObjectToClipPos(i.vertex);
                
                float3 worldNormal = mul(i.normal, (float3x3)unity_WorldToObject);

                float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                float3 r = normalize(reflect(-worldLight, worldNormal));

                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, i.vertex).xyz);
                
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, worldNormal));

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(r, viewDir)), _Gloss);

                o.color = ambient + diffuse + specular;

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                return fixed4(i.color, 1.0);
            }

            ENDCG
        }
    }
}

在这里插入图片描述

逐像素高光（Phong光照模型）
  • 效果对比：逐像素后高光效果更加平滑
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
    Properties {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader{
        Tags {
            "LightMode" = "ForwardBase"
        }
        Pass{
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                fixed3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
            };


            v2f vert(a2v i){
                v2f o;
                o.pos = UnityObjectToClipPos(i.vertex);
                
                o.worldNormal = mul(i.normal, (float3x3)unity_WorldToObject);
                
                o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
                

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                float3 r = normalize(reflect(-worldLight, i.worldNormal));

                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
                
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, i.worldNormal));

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(r, viewDir)), _Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color, 1.0);
            }

            ENDCG
        }
    }
}

在这里插入图片描述

Blinn-Phong光照模型

  • 效果对比：Blinn-Phong光照模型的高光效果看起来更亮，更大
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
    Properties {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader{
        Tags {
            "LightMode" = "ForwardBase"
        }
        Pass{
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                fixed3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
            };


            v2f vert(a2v i){
                v2f o;
                o.pos = UnityObjectToClipPos(i.vertex);
                
                o.worldNormal = normalize(mul(i.normal, (float3x3)unity_WorldToObject));
                
                o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
                

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
                
                fixed3 h = normalize(viewDir + worldLight);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLight, i.worldNormal));

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, h)), _Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color, 1.0);
            }

            ENDCG
        }
    }
}

在这里插入图片描述

改用内建函数

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"{
    Properties {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader{
        Tags {
            "LightMode" = "ForwardBase"
        }
        Pass{
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                fixed3 normal: NORMAL;
            };

            struct v2f {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
            };


            v2f vert(a2v i){
                v2f o;
                o.pos = UnityObjectToClipPos(i.vertex);
                
                //o.worldNormal = normalize(mul(i.normal, (float3x3)unity_WorldToObject));
                o.worldNormal = normalize(UnityObjectToWorldNormal(i.normal));
                
                o.worldPos = mul(unity_ObjectToWorld, i.vertex).xyz;
                

                return o;
            }

            fixed4 frag(v2f i): SV_Target {
                float3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                
                fixed3 h = normalize(viewDir + worldLightDir);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLightDir, i.worldNormal));

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, h)), _Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color, 1.0);
            }

            ENDCG
        }
    }
}

在这里插入图片描述

KS_128
关注
专栏目录
unity入门精要之第6 章 Unity 中的基础光照概述-1
aoxuestudy的专栏
04-17 1240
渲染总是围绕着一个基础问题：我们如何决定一个像素的颜色？从宏观上来说，渲染包含了 两大部分：决定一个像素的可见性，决定这个像素上的光照计算。而光照模型就是用于决定在一 个像素上进行怎样的光照计算。 我们首先会在6.1 节介绍在真实世界中，我们是如何看到一个物体的，以此来帮助读者理解 光照模型背后的原理。随后在6.2 节中，我们将解释什么是标准光照模型，以及如何在Unity Shader 中实现标准光照模型。6.3 节介绍如何计算光照模型中的环境光和自发光部分。在6.4 节和6.5 节 中，我们将学习两种最基
Unity Shader 入门精要——第6章Unity中的基础光照
weixin_38844255的博客
05-05 237
反射方向可通过表面法线、光源方向信息计算得到。假设这些矢量都是单位向量。计算高光反射需要知道的信息比较多，如表面法线(
《Unity Shader入门精要》第六章-Unity中的基础光照
lrf的学习记录
01-18 245
unity版本2018.1.1，有些内置方法用的是新的。 漫反射光照模型 // 漫反射光照模型-逐顶点光照（兰伯特光照模型） Shader "Custom/DiffuseVertextLevelShader" { Properties { _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) } SubShader { pass { Tags { "LightMode" = "ForwardBase" } CGPROGRAM #p
第六章——Unity中的基础光照
qq_63388834的博客
01-15 1171
虽然标准光照模型仅仅是一个经验模型，也就是说，它并不完全符合真实世界中的光照现象。但由于它的易用性、计算速度和得到的效果都比较好，因此仍然被广泛使用。而也是由于它的广泛使用性，这种标准光照模型有很多不同的叫法。例如，一些资料中称它为Phong光照模型，因为裴祥风(Bui Tuong Phong）首先提出了使用漫反射和高光反射的和来对反射光照进行建模的基本思想，并且提出了基于经验的计算高光反射的方法（用于计算漫反射光照的兰伯特模型在那时已经被提出了)。
unity入门精要之第6 章 Unity 中的基础光照---实现高光反射光照模型
aoxuestudy的专栏
04-23 2384
实现高光反射光照模型
Unity Shader入门精要 第六章——Unity中的基础光照
buzhengli的博客
07-21 2093
逐像素光照，以每个像素为基础，得到它的法线（可以是对顶点法线插值得到的，也可以是从法线纹理中采样得到的），然后进行光照模型计算，这种在面片之间对顶点法线进行插值的技术称为Phong着色，也被称为Phong插值或法线插值技术，这不同于Phong光照模型。上面两个模型(也叫兰伯特光照模型)有个问题就是，光照没有照射到的地方是全黑的，没有明暗变化，导致背面就像是有个平面一样。与原来的兰伯特光照模型相比，半兰伯特光照模型没有使用max操作来防止n*I的点积为负值，而是进行了一个α倍的缩放和β大小的偏移。
第6章 Unity 中的基础光照
m1234567q的专栏
10-24 902
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。 ...
unity入门精要之第6 章 Unity 中的基础光照--环境光和自发光
aoxuestudy的专栏
04-23 6095
在Unity Shader 中实现漫反射光照模型在了解了上述的理论后，我们现在来看一下如何在Unity 中实现这些基本光照模型。首先， 我们来实现标准光照模型中的漫反射光照部分。 在6.2.3 节中，我们给出了基本光照模型中漫反射部分的计算公式：
《Unity Shader 入门精要》第6章 Unity 中的基础光照
m0_37979033的博客
01-23 1700
Unity 基础光照模型
dotnet-Unity中的第一人称多人射击游戏示例项目
08-15
1. **Unity基础知识**：包括场景管理、对象实例化、组件系统、动画系统、光照和阴影、物理引擎等。 2. **C#编程**：掌握Unity脚本的基本结构，如MonoBehaviours，以及事件驱动的编程模式，例如Update()、LateUpdate...
Adv-CS-Unity:高级计算机科学课-Unity游戏开发
04-11
总之，《高级计算机科学课-Unity游戏开发》是一门全面的教程，涵盖了从基础到进阶的Unity开发知识，结合C#语言的学习，将帮助学习者在游戏开发领域建立起坚实的基础。通过不断实践和探索，你将能够创造出富有创意和...
第六章 Unity中的基础光照
s178435865的专栏
04-16 1191
第六章 Unity中的基础光照
Unity Shader入门精要学习笔记 - 第6章 开始 Unity 中的基础光照
那远远的云端
12-27 1689
Unity Shader入门精要学习笔记 - 第6章 开始 Unity 中的基础光照本系列为UnityShader入门精要读书笔记总结， 原作者博客链接：http://blog.csdn.net/candycat1992/article/ 书籍链接：http://product.dangdang.com/23972910.html第6章 开始 Unity 中的基础光照6.1 我们是如何看到这个
C# 游戏引擎中的协程
m0_73087695的博客
09-23 1891
简单来讲，协程是轻量级，用户级的线程，通过“分时复用” 的方式模拟多线程操作。协程是一个“伪线程”，它其实只在一个线程上执行，但是通过执行“挂起”和“恢复”等操作，可以实现“不同时间执行不同任务”或者说“一个任务分到多个帧内完成”。协程的优点就是缺点，缺点就是优点。它没有直接操作线程繁琐，也无法发挥多核处理器的优势，所以它并非“必要的”。不过对于游戏开发而言，游戏一般只有一个“主循环”，或者说一个主要线程，所以资源和数据（也可以说“上下文”（context））主要就只在一个线程中。
滑板开关端子折弯机_三维3D设计图纸.zip
10-05
滑板开关端子折弯机_三维3D设计图纸.zip
基于Vue框架的毕业生离校管理系统设计源码
最新发布
10-05
本项目为基于Vue框架开发的毕业生离校管理系统设计源码，包含322个文件，涵盖147个Vue组件、95个JavaScript脚本、46个SVG图形、9个SCSS样式表、3个Handlebars模板、2个YAML配置、2个Markdown文件、2个JSON数据、2个PNG图片和2个CSS样式文件。系统采用Vue、JavaScript、CSS和HTML等多种编程语言和技术构建，旨在实现毕业生的离校管理功能。
基于SpringBoot和Vue的桂林旅游景点导游平台设计源码
10-05
本项目是一款基于SpringBoot和Vue构建的桂林旅游景点导游平台源码，包含798个文件，涵盖了162个SVG图形、152个JavaScript文件、107个Java文件、79个GIF动画、50个PNG图片、48个JPG图像、46个Vue组件、44个CSS样式表、44个HTML模板、16个地图文件。该平台利用JavaScript、Java、Vue、CSS和HTML等多种语言和技术，为用户提供全面的旅游导览服务。
数据手册-AT45DB161B-datasheet.zip
10-05
数据手册-AT45DB161B-datasheet.zip
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值