技术美术TA之深度缓冲区

本文是视频课程《Unity技术美术TA：Shader篇》，算是对自己学习的总结，也希望分享下所学知识~~

Depth Buffer：深度缓冲区
xyz是坐标，模型的z轴是由离相机的远近转换而来的
每个顶点的深度信息，在光栅化阶段会被差值，写入到深度缓冲区中
深度值范围0-1，非线性（近处精度高）

深度缓冲区的作用：
消隐（同时不用绘制会优化一定性能）

深度缓冲区的操作
1.更新 ZWrite，默认是1，更新后越小越靠前
代码如下：

[Enum(On,1, Off,0)]_ZWrite("ZWrite",int )=1

ZWrite [_ZWrite]

不透明物体一定是 ZWrite On
半透明物体大部分都是 ZWrite Off
如果半透明比较复杂，多加一个 Pass

Pass
{
	ZWrite On
	ColorMask 0
}

2.测试 ZTest
是否通过可设置，通过后才会渲染出来

[Enum(UnityEngine.Rendering.CompareFunction)] _ZTest("ZTest",int)=1
ZTest [_ZTest]

默认是 LEqual（小于等于）
Less | Greater | LEqual | GEqual | Equal | NotEqual | Never | Always

常用的效果如 XRay 就可以基于深度实现

新增文件 XRay.shader

Shader "Custom/TA/XRay"
{
    SubShader
    {

        Pass
        {
        	//定义名字，其他的shade可以直接引用这个Pass
        	//	UsePass "Custom/TA/XRay/XRAY"
            Name "XRAY"
            
            Tags
            {
                "Queue" = "Transparent"
            }

            Blend One One
            ZWrite Off
            ZTest Greater

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldPos : TEXCOORD1;
                float3 worldNormal : TEXCOORD2;
            };

            fixed4 _Color;

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //菲涅尔
                fixed4 c = 1;
                fixed3 v = normalize(_WorldSpaceCameraPos - i.worldPos);
                fixed3 n = normalize(i.worldNormal);

                fixed vdn = dot(v, n);
                fixed fresnel = 2 * pow(1 - vdn, 2); //2 * 亮度提升， pow 把边缘拉开

                c.rgb = fresnel * fixed3(0,0.3,0.9);

                //分段，取小数部分，一直是0-1的区间
                fixed f = frac(i.worldPos.y * 20 - _Time.y);
                c.rgb *= f;
                return c;
            }
            ENDCG
        }
    }
}

参考图