单张纹理
单张纹理: 使用一张纹理来代替物体的漫反射颜色,通过tex2D内置函数来对纹理进行采样。
关键代码如下:
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
Shader "cc/shader9" {
Properties {
_Color ("Color Tint",Color) = (1,1,1,1)
_MainTex("Main Tex",2D) = "white"{}
_Specular ("Specular",Color) = (1,1,1,1) // 反射颜色
_Gloss ("Gloss",Range(8.0,256)) = 20 // 高光区域大小
}
SubShader {
Pass {
Tags {"LightMode" = "ForwardBase"} // 光照流水线,定义了才能得到一些内置光照变量
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc" // 后面用到 _LightColor0
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Specular;
fixed _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert (a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
return o;
}
fixed4 frag(v2f i) : SV_Target {
//纹理采样
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(worldNormal,worldLightDir));
// 视觉方向v
//fixed viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
// 单位向量h
fixed3 halfDir = normalize(worldLightDir + viewDir);
// 套公式
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
凹凸映射、渐变纹理、遮罩纹理(未完待续)