Unity 2D常用Shader

最新推荐文章于 2024-03-03 22:41:17 发布
最新推荐文章于 2024-03-03 22:41:17 发布
阅读量5.1k 收藏 59
点赞数 9
分类专栏： Shader
原文链接：https://blog.csdn.net/dingxiaowei2013/article/details/89216434
版权

前言

Shader效果常用于3D模型，但2D图也有不少常用的效果，例如：圆角头像，图片灰态，边缘着色等等，下面我就依次做一个介绍。

图片灰态

效果

在这里插入图片描述

核心思路

在片元着色器里面对每个图元进行采样，将图元的颜色x，y，z分别乘上灰度系数然后赋值给片源颜色，就将彩色变成了灰色了。

代码
//-----------------------------------------------【Shader说明】--------------------------------------------------------
//     Shader功能：   2D图片变灰  核心思路： 采样之后的图元xyz分别各自乘以灰度系数0.299,0.518,0.184之后的值就是灰色的
//     使用语言：   Shaderlab
//     开发所用IDE版本：Unity2018.3.6 、Visual Studio 2017
//     2016年9月16日  Created by Aladdin(阿拉丁)   
//     更多内容或交流请访问我的博客：http://blog.csdn.net/s10141303/article/category/6670402
//---------------------------------------------------------------------------------------------------------------------


Shader "阿拉丁Shader编程/4-1.2D图片变灰"
{
   Properties
    {
        _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)
        _GrayScale ("GrayScale", Float) = 1
		[Toggle]_Open("Open", Int) = 1	//Toggle控制是否开启
    }

    SubShader
    {
        Tags
        { 
            "Queue"="Transparent" 
            "IgnoreProjector"="True" 
            "RenderType"="Transparent" 
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Blend One OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile _ PIXELSNAP_ON	  //告诉Unity编译不同版本的Shader,这里和后面vert中的PIXELSNAP_ON对应
            #include "UnityCG.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                half2 texcoord  : TEXCOORD0;
            };

            fixed4 _Color;
			fixed _Open;
            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.vertex = UnityObjectToClipPos(IN.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color * _Color;
                #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap (OUT.vertex);
                #endif

                return OUT;
            }

            sampler2D _MainTex;
            float _GrayScale;

            fixed4 frag(v2f IN) : SV_Target
            {
				if(_Open > 0)
				{
					fixed4 c = tex2D(_MainTex, IN.texcoord) * IN.color;
				   float cc = (c.r * 0.299 + c.g * 0.518 + c.b * 0.184);  //乘以一个灰度系数
					cc *= _GrayScale;
					c.r = c.g = c.b = cc;

					c.rgb *= c.a;
					return c;
				}
                else
				{
				   return tex2D(_MainTex, IN.texcoord) * IN.color;
				}
            }
        ENDCG
        }
    }
}

边缘着色

效果

在这里插入图片描述

核心思路

在片源 着色器中每个图元检测alpha跟阀值进行对比就能找到边缘

代码
//-----------------------------------------------【Shader说明】--------------------------------------------------------
//     Shader功能：   2D图片描边	 核心思路：检测某个图元的alpha值是否在某个阀值之间
//     使用语言：   Shaderlab
//     开发所用IDE版本：Unity2018.3.6 、Visual Studio 2017
//     2016年9月16日  Created by Aladdin(阿拉丁)   
//     更多内容或交流请访问我的博客：http://blog.csdn.net/s10141303/article/category/6670402
//---------------------------------------------------------------------------------------------------------------------


Shader "阿拉丁Shader编程/4-2.2D图片描边"
{
	Properties
	{
		[PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
		_Color ("Tint", Color) = (1,1,1,1) //图像回合颜色
		_OutLineColor("OutLineColor", Color) = (1,1,1,1) //边缘颜色
		_CheckRange("CheckRange",Float) = 1	  //检测的范围
		_CheckAccuracy("CheckAccuracy",Float) = 0.5
		_LineWidth("LineWidth",Float) = 2	   //边缘宽度
	}
 
	SubShader
	{
		Tags
		{ 
			"Queue"="Transparent" 
			"IgnoreProjector"="True" 
			"RenderType"="Transparent" 
			"PreviewType"="Plane"
			"CanUseSpriteAtlas"="True"
		}
 
		Cull Off         //关闭背面剔除
		Lighting Off     //关闭灯光
		ZWrite Off       //关闭Z缓冲
		Blend One OneMinusSrcAlpha     //混合源系数one(1)  目标系数OneMinusSrcAlpha(1-one=0)
 
		Pass
		{
		CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile _ PIXELSNAP_ON       //告诉Unity编译不同版本的Shader,这里和后面vert中的PIXELSNAP_ON对应
			#include "UnityCG.cginc"
			sampler2D _MainTex;
			float4 _MainTex_TexelSize;
			
			fixed4 _Color;
			fixed4 _OutLineColor;
			float _CheckAccuracy;
			float _LineWidth;
			float _CheckRange;
			struct appdata_t                           //vert输入
			{
				float4 vertex   : POSITION;
				float4 color    : COLOR;
				float2 texcoord : TEXCOORD0;
			};
 
			struct v2f                                 //vert输出数据结构
			{
				float4 vertex   : SV_POSITION;
				fixed4 color    : COLOR;
				float2 texcoord  : TEXCOORD0;
			};
 
			v2f vert(appdata_t IN)
			{
				v2f OUT;
				OUT.vertex = UnityObjectToClipPos(IN.vertex);
				OUT.texcoord = IN.texcoord;
				OUT.color = IN.color * _Color;
				#ifdef PIXELSNAP_ON
				OUT.vertex = UnityPixelSnap (OUT.vertex);
				#endif
 
				return OUT;
			}
 
			fixed4 SampleSpriteTexture (float2 uv)
			{
				fixed4 color = tex2D (_MainTex, uv);
				return color;
			}
			
			fixed4 frag(v2f IN) : SV_Target
			{
				fixed4 c = SampleSpriteTexture (IN.texcoord) * IN.color;
				c.rgb *= c.a;
				float isOut = step(abs(1/_LineWidth),c.a);	//检测每个图元的aplha是否在某个值 那么他就是边缘	  //step(a, x) Returns (x >= a) ? 1 : 0	   abs(x) 返回绝对值
				if(isOut != 0)
				{
					fixed4 pixelUp = tex2D(_MainTex, IN.texcoord + fixed2(0, _MainTex_TexelSize.y*_CheckRange));  
					fixed4 pixelDown = tex2D(_MainTex, IN.texcoord - fixed2(0, _MainTex_TexelSize.y*_CheckRange));  
					fixed4 pixelRight = tex2D(_MainTex, IN.texcoord + fixed2(_MainTex_TexelSize.x*_CheckRange, 0));  
					fixed4 pixelLeft = tex2D(_MainTex, IN.texcoord - fixed2(_MainTex_TexelSize.x*_CheckRange, 0));  
					float bOut = step((1-_CheckAccuracy),pixelUp.a*pixelDown.a*pixelRight.a*pixelLeft.a);
					c = lerp(_OutLineColor,c,bOut);
					return c;
				}
				return c;
			}
		ENDCG
		}
	}
}

圆角头像

效果

在这里插入图片描述

核心思路

在这里插入图片描述
根据圆相关的知识，将正方形图分成四块象限区域然后每个象限一个最大的半径为0.5的圆，计算像素是否在圆角之内是关键核心，首先计算四个圆心中间的像素，然后在根据像素距离圆心的长度是否交于半径，小于则在圆角之内，否则舍弃。

代码
//-----------------------------------------------【Shader说明】--------------------------------------------------------
//     Shader功能：   2D圆角头像	
//	   核心思路：根据圆相关的知识，将正方形图分成四块象限区域然后每个象限一个最大的半径为0.5的圆，计算像素是否在圆角
//     之内是关键核心，首先计算四个圆心中间的像素，然后在根据像素距离圆心的长度是否交于半径，小于则在圆角之内，否则舍弃
//     使用语言：   Shaderlab
//     开发所用IDE版本：Unity2018.3.6 、Visual Studio 2017
//     2016年9月16日  Created by Aladdin(阿拉丁)   
//     更多内容或交流请访问我的博客：http://blog.csdn.net/s10141303/article/category/6670402
//---------------------------------------------------------------------------------------------------------------------

Shader "阿拉丁Shader编程/4-3.2D圆角头像" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_RADIUSBUCE("Radius(圆角半径)",Range(0,0.5))= 0.2   //圆角半径
	}
	SubShader
	{
		pass
		{
			CGPROGRAM
			#pragma exclude_renderers gles
			#pragma vertex vert
			#pragma fragment frag
			#include "unitycg.cginc"
			float _RADIUSBUCE;
			sampler2D _MainTex;

			struct v2f
			{
				float4 pos : SV_POSITION;
				float2 ModeUV: TEXCOORD0;
				float2 RadiusBuceVU : TEXCOORD1;
			};
			v2f vert(appdata_base v)
			{
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex); //v.vertex;
				o.ModeUV=v.texcoord;
				o.RadiusBuceVU=v.texcoord-float2(0.5,0.5);       //将模型UV坐标原点置为中心原点,为了方便计算  原本坐标原点在左下角
				return o;
			}


			fixed4 frag(v2f i):COLOR
			{
				fixed4 col;
				col=(0,1,1,0);

				if(abs(i.RadiusBuceVU.x)<0.5-_RADIUSBUCE||abs(i.RadiusBuceVU.y)<0.5-_RADIUSBUCE)   //像素点坐标在中间一块	不在四个角落	渲染原本的图元颜色
				{
					col=tex2D(_MainTex,i.ModeUV);
				}
				else //如果在四个角落
				{
					if(length(abs(i.RadiusBuceVU)-float2(0.5-_RADIUSBUCE,0.5-_RADIUSBUCE)) <_RADIUSBUCE)  //在圆角的内的像素 坐标到圆心的距离是否小于半径 小于则在圆角之内
					{
						col=tex2D(_MainTex,i.ModeUV);
					}
					else
					{
						discard;  //舍弃图元 相当于clip
					}		
				}
				return col;		
			}
			ENDCG
		}
	}
}

图片模糊

前言

图片模糊是比较常用的效果，想必我们都听过高斯模糊，模糊常用于屏幕后期处理，还有UI为了凸显某个窗体然后将背景图模糊等。

效果

在这里插入图片描述

核心思路

对片源着色器里对单个图元的颜色叠加混合周边的颜色然后再取平均，最典型的应当属于高斯模糊，涉及到高斯正态分布公式。

一维高斯分布如图：
在这里插入图片描述
二维高斯分布如图：

在这里插入图片描述
高斯公式：
在这里插入图片描述

代码
//-----------------------------------------------【Shader说明】--------------------------------------------------------
//     Shader功能：   2D模糊
//	   核心思路：  在片源着色器里对单个图元累加周边的颜色然后再取平均，高斯模糊涉及到高斯公式(高斯正太分布公式)
//     使用语言：   Shaderlab
//     开发所用IDE版本：Unity2018.3.6 、Visual Studio 2017
//     2016年9月16日  Created by Aladdin(阿拉丁)
//     更多内容或交流请访问我的博客：http://blog.csdn.net/s10141303/article/category/6670402
//---------------------------------------------------------------------------------------------------------------------

Shader "阿拉丁Shader编程/4-4.2D模糊"
{
    Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_BlurRadius ("BlurRadius", Range(2, 15)) = 5  //模糊半径
		_TextureSize ("TextureSize", Float) = 640
	}
	SubShader
	{
		Cull Off ZWrite Off ZTest Always

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}

			sampler2D _MainTex;
			int _BlurRadius;
			float _TextureSize;

			//这一步其实可以用计算出来的常量来替代，不需要在循环中每一步计算
			float GetGaussWeight(float x, float y, float sigma)
			{
				float sigma2 = pow(sigma, 2.0f);		//pow 次方公式 这里是平方
				float left = 1 / (2 * sigma2 * 3.1415926f);
				float right = exp(-(x*x+y*y)/(2*sigma2));	 //e的指数幂
				return left * right;
			}

			fixed4 GaussBlur(float2 uv)		 //高斯模糊 根据高斯公式计算出的颜色值
			{
				//因为高斯函数中3σ以外的点的权重已经很小了，因此σ取半径r/3的值
				float sigma = (float)_BlurRadius / 3.0f;
				float4 col = float4(0, 0, 0, 0);
				for (int x = - _BlurRadius; x <= _BlurRadius; ++x)
				{
					for (int y = - _BlurRadius; y <= _BlurRadius; ++y)
					{
						//获取周围像素的颜色
						//因为uv是0-1的一个值，而像素坐标是整形，我们要取材质对应位置上的颜色，需要将整形的像素坐标
						//转为uv上的坐标值
						float4 color = tex2D(_MainTex, uv + float2(x / _TextureSize, y / _TextureSize));
						//获取此像素的权重
						float weight = GetGaussWeight(x, y, sigma);
						//计算此点的最终颜色
						col += color * weight;	//颜色乘以权重
					}
				}
				return col;
			}

			fixed4 SimpleBlur(float2 uv)
			{
				float4 col = float4(0, 0, 0, 0);
				for (int x = - _BlurRadius; x <= _BlurRadius; ++x)
				{
					for (int y = - _BlurRadius; y <= _BlurRadius; ++y)
					{
						float4 color = tex2D(_MainTex, uv + float2(x / _TextureSize, y / _TextureSize));
						//简单的进行颜色累加
						col += color;
					}
				}
				//取平均数，所取像素为边长为(半径*2+1)的矩阵
				col = col / pow(_BlurRadius * 2 + 1, 2.0f);
				return col;
			}

			fixed4 frag (v2f i) : SV_Target
			{
				//float4 col = GaussBlur(i.uv);
				float4 col = SimpleBlur(i.uv);
				return col;
			}
			ENDCG
		}
	}
    FallBack "Diffuse"
}

像素风格

效果

在这里插入图片描述

核心思路

对UV进行放大，然后截取整数部分，然后再缩回原大小，UV精度丢失，就形成马赛克效果

代码
//-----------------------------------------------【Shader说明】--------------------------------------------------------
//     Shader功能：   2D像素风格
//	   核心思路：   对UV进行放大，然后截取整数部分，然后再缩回原大小，UV精度丢失，就形成马赛克效果
//     使用语言：   Shaderlab
//     开发所用IDE版本：Unity2018.3.6 、Visual Studio 2017
//     2016年9月16日  Created by Aladdin(阿拉丁)   
//     更多内容或交流请访问我的博客：http://blog.csdn.net/s10141303/article/category/6670402
//---------------------------------------------------------------------------------------------------------------------

Shader "阿拉丁Shader编程/4-5.2D像素风格" {
	Properties
	{
		_MainTex("Texture", 2D) = "white" {}
		_PixelSize("Pixel Size", Range(1,256)) = 64
	}
		SubShader
		{
			Tags { "Queue" = "Transparent" }
			Blend SrcAlpha OneMinusSrcAlpha

			Pass
			{
				CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag

				#include "UnityCG.cginc"

				struct appdata
				{
					float4 vertex : POSITION;
					float2 uv : TEXCOORD0;
				};

				struct v2f
				{
					float2 uv : TEXCOORD0;
					float4 vertex : SV_POSITION;
				};

				sampler2D _MainTex;
				float4 _MainTex_ST;
				float _PixelSize;

				v2f vert(appdata v)
				{
					v2f o;
					o.vertex = UnityObjectToClipPos(v.vertex);
					o.uv = TRANSFORM_TEX(v.uv, _MainTex);
					return o;
				}

				fixed4 frag(v2f i) : SV_Target
				{
					fixed4 col;

					float ratioX = (int)(i.uv.x * _PixelSize) / _PixelSize;
					float ratioY = (int)(i.uv.y * _PixelSize) / _PixelSize;

					col = tex2D(_MainTex, float2(ratioX, ratioY));

					if (col.a < 0.5)
					{
						col.a = 0;
					}

					return col;
				}
				ENDCG
			}
		}
}

更多效果待添加。。。

更多优质文章：[Aladdin的博客](http://dingxiaowei.cn)

工程地址

https://github.com/dingxiaowei/AladdinShader

Shader交流群

316977780

更多精品文章

Aladdin的博客

时间不会说谎shane
关注
  • 9
    点赞
  • 踩
  • 59
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
2d shader unity 阴影_Unity里实现Sprite Renderer的阴影
weixin_39727934的博客
12-21 211
最近有个2D游戏要做，有一个要做的点是，让Sprite Renderer产生阴影。将以下脚本附到产生Shadow的物体上：voidOnEnable(){GetComponent().receiveShadows =true;GetComponent().castShadows =true;}但是这是不够的，还需要Shader帮忙,下面的Shader请放到产生Shadow的物体上：Shader "C...
【实现100个unity特效之8】使用ShaderGraph实现2d贴图中指定部分局部发光效果
最新发布
向宇
07-24 2074
我们的主纹理中有部分是透明的，而我们的这个黑白纹理中都是不透明的，虽然我们黑色的部分它的RGB都是O，但它的A是1，当我们直接使用这个（黑白纹理的）RGBA和主纹理（的RGBA)进行相加时，它的A会把主纹理的A给覆盖了，这样就会导致主纹理中的透明度都设为1了，透明部分都被覆盖了。(阈值)：控制哪些亮度的像素会受到泛光效果的影响。当我们使用add的时候，Unity会自动进行转换，比如我们R是0，Unity会自动把它转换成RGBA都是0的值，而我们R是1的时候，Unity就会自动转换成RGBA都是1的值。
Unity Shader实现2D天空日夜循环
qq_50906930的博客
03-03 621
【代码】Unity Shader实现2D Day Night Cycle日夜循环。
UnityShader 实现2D流光效果
05-09
很多游戏Logo中都可以看到流光效果，实现方案就是对带有光条的图片uv根据时间进行移动，然后和原图进行叠加实现。
Unity Shader实现2D水流效果
12-20
水流的模拟主要运用了顶点变换和纹理动画的结合； 顶点变换中，利用正弦函数模拟河流的大致形态，例如波长，振幅等。 纹理动画中，将纹理坐标朝某一方向持续滚动以形成流动的效果。 脚本如下： Shader "MyUnlit/ScrollWater" { Properties { _MainTex ("Texture", 2D) = "white" {} _Color("Color Tint",color)=(1,1,1,1) //控制水流波动的幅度，也就是三角函数中的振幅（值域范围） _Magnitude("Distortion Magnitude",float)=0.3 /
Unity 2D外描边Shader
super41的博客
06-15 2340
今天，我们来实现一个2D外描边的效果。外描边：即在边缘透明像素周围加上一层描边，不占用原来的像素。思路：我们可以在片元着色器实现此效果，当一个像素本身不是透明的（alpha>0），那么让它返回自身的颜色；当一个像素本身是透明的，并且它上下左右4个像素的alpha值总和不等于0，那么我们可以判定该像素处于边缘，让它变成描边颜色就可以。
Unity 2D内描边Shader
super41的博客
06-15 1006
今天，我们来实现一个2D内描边的效果。内描边：即把边缘像素变成描边的颜色，占用原来的像素。思路：我们可以在片元着色器实现此效果：当一个像素本身不是透明的（alpha>0），而且它上下左右4个像素的alpha值的乘积等于0，那么我们可以判定该像素处于边缘，让它变成描边颜色就可以。
Unity2d软体shader
11-07
自制Unity2d软体shader
unity用shader来实现2D涟漪/水波纹特效
04-25
下面将详细阐述如何使用Unity的shader来制作2D涟漪特效。 首先，我们需要理解shader的基本概念。Shader是运行在GPU上的程序，它控制着像素和顶点的渲染。在Unity中，我们可以使用Surface Shader或Vertex Fragment ...
2D Shader Collection.unitypackage
04-03
Features: - Sprite Renderer Support - Unity UI Support - Anima 2D Support - Demo scenes included - More than 104 Shaders available with parameters - Shaders and Materials available
UnityShader3实现2D描边效果
08-26
主要为大家详细介绍了UnityShader3实现2D描边效果，具有一定的参考价值，感兴趣的小伙伴们可以参考一下
Unity 下雨雨滴特效Shader
08-09
Unity是一款强大的跨平台游戏开发引擎，广泛用于创建2D和3D游戏以及实时可视化应用。在Unity中，Shader是用于定义场景中物体表面颜色、光照、纹理等视觉效果的程序。"Unity 下雨雨滴特效Shader"是一个专门设计用于...
Unity 2D Computer Shader Water
02-18
Unity 2D Computer Shader Water
【实现100个unity特效之2】使用shader和shader Graph实现2d图片描边效果(附源码)
向宇
07-09 4908
最近在学习shader Graph相关内容，其实关于实现2d图片描边效果，网上可以看到很多教程，但是我发现大多数都是基于比较老旧的2018unity版本，可是我们实际开发使用可能是比较新的2021及以上版本，差别还是有的，实际在升级或者使用过程中，会遇到诸多问题，而且也很少有人会分享shader Graph的连线图源码没有的话我就想着把我的学习笔记和整理源码分享出来吧，我想于是就有了这篇文章。
Unity urp2d ShaderGraph 实现一个黑白转彩色的场景渐变效果 设计思路
m0_51776409的博客
10-29 3845
那只能走走别的方向了，仔细想想，原来的shader也确实不太完美，因为我们要的是整个画面的黑白，而上面的shader则需要给每个场景物品都安装这个shader跑计算的话，无疑是降低了性能和扩展性的。我们可以放弃if节点，改用lerp在两个色域中做插值，就可以优化渐变效果，插值需要一个0-1的参数，我们选择使用“Saturate”节点，这个节点可以将一个浮点值映射到[0,1]的范围内，即输入大于1时=1，输入小于0时等于0，然后将结果连接到Lerp节点就可以了。这样我们这个效果就成功实现了。
Unity shader 2d描边
Fanstasic的博客
03-01 3922
Shader "Custom/ShaderForTest2" { Properties { _MainTex("Main Texture", 2D) = "white"{} _EdgeAlphaThreshold("Edge Alpha Threshold", Float) = 1.0 _EdgeColor("Edge Color", Color) = (0,0,0,1) _...
Unity Shader学习：2D图形绘制(蓝天白云大海)
咪咪博客
01-30 2993
Unity Shader学习：2D图形绘制 基本是一些数学上的算法 shader部分: Shader &quot;Unlit/2D-Ocean&quot; { Properties { _MainTex (&quot;Texture&quot;, 2D) = &quot;white&quot; {} _SunColor(&quot;SunColor&quot;,Color) = (1,1,1,1) _Sun
unity 2d流光shader
05-01
Unity 2D流光shader是一种可用于渲染2D图形的着色器效果，其使用了特殊的技术来模拟流光效果。该效果能够通过改变颜色和亮度来让图像看起来像是有移动的光线在画面上流动。 流光shader是使用Unity ShaderLab编写的，其中包含了一系列的OpenGL语言和Unity自定义的着色器语言，并可以自由调整各个参数。例如，流光的强度，颜色，方向等等，都可以通过调整shader中的参数来实现。 这种效果在游戏设计中具有非常广泛的应用。流光shader可以用来增强游戏场景的气氛，比如可以用来制作神秘的夜晚效果、地下城效果等等。此外，在游戏菜单和UI设计上，也可以使用流光shader来为菜单字体、按钮等元素添加动态效果，从而使游戏更加生动。 总之，Unity 2D流光shader 是一种非常有趣的2D图形渲染效果，它可以给游戏增加流动感，同时也为游戏的视觉效果和用户体验带来了更多的乐趣。
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值