【基础知识】~ 分频器

已于 2022-07-06 22:36:30 修改
阅读量1.2w 收藏 258
点赞数 38
分类专栏： IC设计/验证、FPGA 文章标签： fpga开发 单片机 嵌入式硬件
于 2022-05-31 23:17:33 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_40549426/article/details/125067905
版权

本章目录：

1. 什么是分频

分频就是生成一个新时钟，该新时钟的频率是原有时钟频率的整数分之一倍，新周期是原有周期的整数倍。再简单来说，让你手撕一个四分频电路，就是写代码生成一个周期是原来四倍的时钟，如果手撕一个三分频电路，就是写代码生成一个周期是原来三倍的时钟。但是奇数分频会比偶数分频复杂一些。

2. 偶数分频

2.1 怎么实现二分频呢？

检测参考时钟，每一个上升沿到来时，新的时钟翻转一次。

2.2 代码实现：

module div_2(
		input clk,
		input rst_n,
		output reg clk_out	
);

parameter n_div = 2;
reg [2:0] cnt;

always @ (posedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out <= 1'b0;
		cnt <= 3'b0;
	end
	else begin
		if(cnt == n_div/2 - 1) begin
			clk_out <= ~clk_out;
			cnt <= 3'b0;
		end
		else begin
			cnt <= cnt + 1'b1;
		end
	end
end 
endmodule

2.3 testbench文件

`timescale 1 ns/ 1 ps


module div_2_tb();

	reg clk;
	reg rst_n;
	// wires                                               
	wire clk_out;

	div_2 i1 (
		.clk(clk),
		.clk_out(clk_out),
		.rst_n(rst_n)
	);

	initial                                                
		begin                                                                      
			clk <= 0;
			rst_n <= 1;
			#50
			rst_n <= 0;
			#50
			rst_n <= 1;
			#50000;
			$stop;                                                              
		end    															
	always                                                                 
		begin                                                                         
			  #10 clk = ~clk;                                                                                                                                      
		end                                                  
endmodule

2.4 仿真波形

搞定！从图中可以看到，clk_out每过两个clk时钟上升沿就flip-flop一次，这样一个clk_out的周期就是clk周期的两倍，也即实现了二分频。
在这里插入图片描述

那如果是任意偶数分频呢，这就得数经过了多少上升沿，如果是四分频，那就每过两个时钟上升沿（两周期），新信号flip-flop一次，flip-flop两次为新信号的一个周期，即是周期是原时钟的四倍。同理，8分频就是每数4个上升沿，flip-flop一次，以此类推，可以实现任意偶数分频了。

2.5 笔试面试变式题

占空比分析：我们上面写的任意偶数分频代码的占空比都是50%，实际上面试手撕代码不会让你50%占空比，那怎么办？

答：进行计数，对于一个八分频，开始就把时钟设为高电平，我用cnt 计数到两个时钟上升沿后再把它拉低，计数到7后cnt 拉低 时钟拉高，这样就实现了两个周期高，六个周期低，占空比为2/8 即 25% 的八分频。

参考文献：分频器

3. 奇数分频（除了1分频）

怎么写一个三分频呢？一个占空比不是50%的三分频是好写的，同样利用一个cnt变量对上升沿计数来实现。比如实现占空比为1/3的三分频，那么只要数一个上升沿，输出高电平，数两个上升沿输出低电平就能解决。

3.1 代码实现（3分频，非50%占空比）

module odd_div (
			input clk,
			input rst_n,
			output reg clk_out,
			output reg [1:0] cnt
);

always @ (posedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out <= 1'b0;
		cnt <= 2'b00;
	end
	else begin
		if(cnt == 0) begin
			clk_out <= 1'b0;
			cnt <= cnt + 1'b1;
		end
		else if(cnt == 2) begin
			clk_out <= 1'b1;
			cnt <= 2'b00;
		end
		else begin
			cnt <= cnt + 1'b1;
		end
	end
end 

endmodule

3.2 testbench文件

`timescale 1ns/1ps

module odd_div3_tb ();

reg clk;
reg rst_n;
wire clk_out;
wire [1:0] cnt;

initial begin
		clk <= 0;
		rst_n <= 1;
		#50
		rst_n <= 0;
		#50
		rst_n <= 1;
		#1000
		$stop;
end

always begin
	#10 clk = ~clk;
end

odd_div div3 (
			.clk(clk),
			.rst_n(rst_n),
			.clk_out(clk_out),
			.cnt(cnt)
);

endmodule

3.3 仿真

在这里插入图片描述
这里抛出一个小问题，3分频之后为什么有延时呢？
我觉得应该是我用的门级仿真，所以会有一定的延时存在。

3.4 那么如何实现一个占空比50%的三分频呢？

答：将一个占空比1/3 上升沿采样的三分频和一个占空比1/3下降沿采样的三分频结果，做或运算。

什么意思？怎么想到这样做的？下面来解答！

任何奇数 2N-1 （除1分频外）分频都可以表示由 N-1个高电平周期和 N个低电平周期组成。（占空比最接近50%，但小于50%）

写两个这样的分频器，一个上升沿采样的分频器——div1，一个下降沿采样的分频器——div2，在相同 cnt 判断切换高低电平的条件下，就一定有 div1 领先（或滞后）于 div2 半个参考周期，这样他们相或后会使得新的结果还是 2N-1 分频，但是高电平周期变为 N-1+1/2=N-1/2，低电平周期变为 N-1/2，从而高低电平持续时间相等，实现50%占空比的任意奇数分频器。

3.4.1 代码实现（以50%占空比的七分频举例）

module odd_div7_half (
input clk,
input rst_n,
output reg [2:0] cnt1,
output reg [2:0] cnt2,
output reg clk_out1,
output reg clk_out2,
output clk_out
);

localparam div_cnt = 7;

always @ (posedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out1 <= 1'b0;
		cnt1 <= 3'b000;
	end
	else begin
		if(cnt1 == (div_cnt-1)/2) begin
			clk_out1 <= 1'b1;
			cnt1 <= cnt1 + 1;
		end
		else if(cnt1 == div_cnt-1) begin
			clk_out1 <= 1'b0;
			cnt1 <= 3'b000;
		end
		else begin
			cnt1 <= cnt1 + 1;
		end
	end
end

always @ (negedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out2 <= 1'b0;
		cnt2 <= 3'b000;
	end
	else begin
		if(cnt2 == (div_cnt-1)/2) begin
			clk_out2 <= 1'b1;
			cnt2 <= cnt2 + 1;
		end
		else if(cnt2 == div_cnt-1) begin
			clk_out2 <= 1'b0;
			cnt2 <= 3'b000;
		end
		else begin
			cnt2 <= cnt2 + 1;
		end
	end
end

assign clk_out = clk_out1 | clk_out2;

endmodule

3.4.2 testbench文件

`timescale 1ns/1ps

module div7_half_tb();

	reg clk;
	reg rst_n;
	wire [2:0] cnt1;
	wire [2:0] cnt2;
	wire clk_out1;
	wire clk_out2;
	wire clk_out;

initial begin
	clk <= 0;
	rst_n <= 1;
	#50
	rst_n <= 0;
	#50
	rst_n <= 1;
	#1000
	$stop;
end

always begin
	#10 clk = ~clk;
end

odd_div7_half u0(
		.clk(clk),
		.rst_n(rst_n),
		.cnt1(cnt1),
		.cnt2(cnt2),
		.clk_out1(clk_out1),
		.clk_out2(clk_out2),
		.clk_out(clk_out)
);
endmodule

3.4.3 仿真结果

在这里插入图片描述 到此，我们就实现了任意50%占空比的奇数分频器，总结一下。说了那么多我们已经可以独立写出任意合理占空比的偶数分频器，以及任意50%占空比的奇数分频器。但是，如果让手撕一个不是50%占空比的奇数分频器怎么办？？？

3.5 如何实现一个非常规占空比的奇数分频器

2022数字IC秋招面经，面试被问了一个非常规占空比的奇数分频器，比如 3/10占空比的五分频， 5/18占空比的九分频？怎么做呢。

这个和上面实现50%任意奇数分频器的原理是类似的，但是采用与运算。用占空比为 2/5 上升沿采样的信号和 2/5占空比下降沿采样的信号相与，这样由于下降沿采样信号滞后上升沿采样信号半个参考周期。
所以相与后，占空比就为 2/5 - 1/10 = 3/10 ，示意图如下：
在这里插入图片描述

3.5.1 代码实现

module div5_3to10_half(
input clk,
input rst_n,
output reg clk_out1,
output reg clk_out2,
output clk_out,
output reg [2:0] cnt1,
output reg [2:0] cnt2
);

localparam div_cnt = 5;

always @ (posedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out1 <= 1'b0;
		cnt1 <= 3'b0;
	end
	else begin
		if(cnt1==(div_cnt/2)-1) begin
			clk_out1 <= 1'b0;
			cnt1 <= cnt1 + 1;
		end
		else if(cnt1==div_cnt-1) begin
			clk_out1 <= 1'b1;
			cnt1 <= 3'b0;
		end
		else begin
			cnt1 <= cnt1 + 1;
		end
	end
end 

always @ (negedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out2 <= 1'b0;
		cnt2 <= 3'b0;
	end
	else begin
		if(cnt2==(div_cnt/2)-1) begin
			clk_out2 <= 1'b0;
			cnt2 <= cnt2 + 1;
		end
		else if(cnt2==div_cnt-1) begin
			clk_out2 <= 1'b1;
			cnt2 <= 3'b0;
		end
		else begin
			cnt2 <= cnt2 + 1;
		end
	end
end 

assign clk_out = clk_out1 & clk_out2;
endmodule

3.5.2 testbench文件

`timescale 1ns/1ps

module div_3to10half_tb();

reg clk;
reg rst_n;
wire clk_out1;
wire clk_out2;
wire clk_out;
wire [2:0] cnt1;
wire [2:0] cnt2;

initial begin
	clk <= 0;
	rst_n <= 1;
	#50
	rst_n <= 0;
	#50
	rst_n <= 1;
	#10000
	$stop;
end

always begin
	#10 clk = ~clk;
end

div5_3to10_half u0(
		.clk(clk),
		.rst_n(rst_n),
		.clk_out1(clk_out1),
		.clk_out2(clk_out2),
		.clk_out(clk_out),
		.cnt1(cnt1),
		.cnt2(cnt2)	
);

endmodule

3.5.3 仿真结果

在这里插入图片描述
不论之后遇到让你实现什么样子的奇数分频，具体修改只需要改cnt判断数值以及把clk_out 的赋值从clk_out1,clk_out2相或改成相与。 大功告成！！！

参考文献：2

4. 小数分频

上边讲完了任意占空比任意偶数分频器，以及任意占空比任意奇数分频器后，下面讨论更加夸张的小数分频。什么是小数分频？以及怎么实现 9/4，17/3 ，6.3 等任意小数分频？？

编码小数分频，就不能看微观了，要用宏观的眼界去看，比如实现一个 17/3 分频，表达成：17 除以 3 得商为 5 余2。

那么我们就可以通过5（商）分频和7（商+余数）分频 来实现 17/3 分频。

现在我们来确定5分频和7分频的次数，设：

5分频的次数为a , 7分频的次数为b;

那么应该有：

    a+b=3（除数）

    5a+7b = 17（被除数）

解得a=2，b=1，也就是说通过2次5分频和1次7分频可得到 17/3 分频。

这样编程完之后就实现了17/3分频，那么自然会有个疑问，为什么这样就实现了？详细看，仍然是五分频管五分频的，七分频管七分频的，大家各管各的，这算哪门子的小数分频啊？？

所以就要提到我们前面说的宏观来看。宏观来看，总共是17个时钟周期，由三个分频器均分，那么平均每个分频器就是分到17/3了，这就是小数分频，这是一个宏观的平均概念。解释完概念，我们下面开始手撕代码。

4.1 代码实现

module div_decimal(
input clk,
input rst_n,
output reg clk_out,
output reg [4:0] cnt,
output reg [2:0] cnt_2to5,
output reg [2:0] cnt_1to7
);

//17/3 小数分频
always @ (posedge clk or negedge rst_n) begin
	if(!rst_n) begin
		clk_out <= 0;
		cnt <= 5'b0;
		cnt_2to5 <= 3'b0;
		cnt_1to7 <= 3'b0;
	end
	else begin
		//2次5分频
		if(cnt<10) begin
			if(cnt_2to5==0) begin
				clk_out <= 0;
				cnt_2to5 <= cnt_2to5 + 1;
			end
			else if(cnt_2to5==4) begin
				clk_out <= 1;
				cnt_2to5 <= 3'b0;
			end
			else begin
				cnt_2to5 <= cnt_2to5 + 1;
			end
			cnt <= cnt + 1;
		end
		//1次7分频
		else if(cnt>9 && cnt<17) begin
			if(cnt_1to7==0) begin
				clk_out <= 0;
				cnt_1to7 <= cnt_1to7 + 1;
			end
			else if(cnt_1to7==6) begin
				clk_out <= 1;
				cnt_1to7 <= 3'b0;
				cnt <= 5'b0;
			end
			else begin
				cnt_1to7 <= cnt_1to7 + 1;
			end
			cnt <= cnt + 1;
		end
	end
end



endmodule

4.2 testbench文件

`timescale 1ns/1ps

module div_decimal_tb();
reg clk;
reg rst_n;
wire clk_out;
wire [4:0] cnt;
wire [2:0] cnt_2to5;
wire [2:0] cnt_1to7;

initial begin
	clk <= 0;
	rst_n <= 1;
	#20
	rst_n <= 0;
	#20
	rst_n <= 1;
	#5000
	$stop;
end

always begin
	#10 clk = ~clk;
end

div_decimal u0(
.clk(clk),
.rst_n(rst_n),
.clk_out(clk_out),
.cnt(cnt),
.cnt_2to5(cnt_2to5),
.cnt_1to7(cnt_1to7)
);
endmodule

4.3 仿真结果

在这里插入图片描述
如同我们分析的一样，两个五分频，一个七分频，每十七个周期循环一次。即每十七个周期有三个分频器，平摊下来就是 17/3 。

小数分频的缺点就是 占空比不为50%，要想实现50%占空比的小数分频，涉及很多算法，具体算法十分复杂，一般不会作为手撕代码题。

参考文献：3

若有同学对工程文件感兴趣的，可以后台私信我发送工程文件。如有错误，及时更正，本资料仅提供学习，不可做为商业用途，因为我是一个菜鸡！！！

==========================================================================

声明

本人所有系列的文章，仅供学习，不可商用，如有侵权，请告知，立删！！！

本人主要是记录学习过程，以供自己回头复习，再就是提供给后人参考，不喜勿喷！！！

如果觉得对你有用的话，记得收藏+评论！！！

IC二舅
关注
  • 38
    点赞
  • 踩
  • 258
    收藏
    觉得还不错? 一键收藏
  • 5
    评论
专栏目录
小白学懂分频器（二）
jackack的博客
07-15 3471
第一个上升沿来临后，计数器从0开始自加1，同时输出1，第二个上升沿来临后，计数器值自加1，输出变为0，第三个上升沿来临计数为2，下一个上升沿来临时，计数器满足要求，开始翻转输出，这样循环。当n不是2的整数次幂时，如n为5，从0计数到n-1，其最高位作为时钟输出（占空比不一定为 50%），即从0计数到4后又返回0，那么需要定义一个三位的寄存器。当进行2、4、8（2的n次）分频时，输出2的n次最高位即为相应分频，并且占空比为50%，但6、10这样的分频，占空比就不是50%了，该怎么办呢？那我们该怎样实现呢？
占空比1：1的2、4、8分频器FPGA设计verilog源码quartus工程文件.zip
05-10
占空比1：1的2、4、8分频器FPGA设计verilog源码quartus工程文件 module fengping_1(clk_50M,f_2,f_4,f_8); input clk_50M; //输入时钟，50M,周期为20ns output f_2,f_4,f_8; //输出分频时钟，分别为2分频，4分频，8分频 reg f_2,f_4,f_8; //输出分频寄存器 reg[2:0] cnt; //计数寄存器 always@(posedge clk_50M) //在每个时钟的上升沿触发，执行begin_end里面的语句 begin cnt<=cnt+3'b1; //每个时钟周期计数寄存器自加一 f_2<=cnt[0]; //把计数寄存器的最低位赋予f_2，输出即使2分频 f_4<=cnt[1]; //把计数寄存器的第2位赋予f_4，输出即使4分频
深入理解小数锁相环和整数锁相环，附带详细教程，适用于新手入门，非周期小数分频的杂散更低，工艺为tsnc40nm，包含AFC自动频率控制，VDD=1.8V，PS多模分频器，前仿真，无版图，解析小数锁相环
最新发布
rqUfaAwRh的博客
06-07 441
通过对Mash1-1-1小数分频器的周期性和非周期性特点以及其非周期的小数杂散降低的工艺tsnc40nm的介绍，探讨该技术在AFC自动频率控制方面的应用。以上是一篇技术文章的大致框架，根据提供的主题进行展开阐述，以小数锁相环、整数锁相环和AFC自动频率控制为核心内容进行分析和讨论，并结合具体的工艺和应用场景进行详细论述。Mash1-1-1的小数分频，有周期性的和非周期性的，非周期的小数杂散更低，工艺是tsnc40nm，会送工艺库，再送AFC自动频率控制。标题：小数锁相环和整数锁相环的综合技术分析。
时钟分频简介
XJTU_Richthofen的博客
02-21 8199
分频顾名思义就是分的的频率，频率是在电子中例如方波信号中指每秒钟周期的次数。所谓分频就是吧周期通过一定的办法给分解了。所以，n分频就是指，原来的信号经过n的周期，新的信号跳变一次。这样20Mhz，2分频就是10mhz，5分频就是4mhz，10分频就是1mhz。晶振频率是单片机内部的，单片机里的分频指的是时钟频率的分频，而晶振震荡两次才会产生一个时钟频率。所以，先要将晶振频率二分频，得到时钟频率，然
分频器
erzayi的博客
08-07 2313
分频器rst一般不与clk的时钟沿同步，所以时钟分频的第一个周期不是整周期，从0开始计数略小，从1开始计数略大。一般选0开始，时钟开始之后第一个上升沿开始操作。 偶数分频（2N） 模为N的计数器，实现50%占空比的时钟信号，每次计数到N。 module Clk_div4(clk_in,clk_out,rst); input clk_in; input rst; output clk_out;reg
偶分频（八分频）
cjl24的博客
03-07 1879
八分频意味着时钟在一半的时刻就要取反（1~7的计数，在3就要判断发生翻转） 方式1 最常见的方式，但是在高精度情况使用容易出现误差 module oufenpin( input wire sys_clk, input wire rst_n, output reg clk ); parameter M=4'd8; //分频数 reg [2:0] count; always@(posedge sys_clk or neg
Logisim分频器
11-28
总结来说，“Logisim分频器”实验是一个极好的实践平台，它结合理论知识与实际操作，让学生亲手构建和测试分频器，从而深化对数字逻辑和计时设备的理解。通过分析和修改不同模值的分频器设计，学生可以提升其在数字...
fenpinqi_vhdl_分频器_
09-30
总的来说，"fenpinqi_vhdl_分频器_"是一个关于VHDL编程和分频器设计的学习资源，它涵盖了数字电路设计的基础知识，包括时序逻辑、计数器和参数化设计。对于电子工程的学生和工程师来说，掌握这些技能是至关重要的。
分频器空芯电感计算器
03-27
总结，音箱分频器中的空芯电感计算是一个涉及多方面知识的技术活。了解其计算原理，掌握合适的计算工具，结合实际的音频设备特性，才能设计出性能优良的分频器，提升整个音响系统的音质表现。通过"空芯电感计算器....
使用VHDL进行分频器设计
07-01
"基于VHDL高级编程语言的分频器应用设计"这一描述进一步强调了我们将在高级编程层面来实现分频器，这意味着我们将探讨如何利用VHDL的高级特性，如过程（process）、结构体（structure）以及包（package）等，来构建...
占空比1：3的4分频分频器FPGA设计verilog源码quartus工程文件.zip
05-10
占空比1：3的4分频分频器FPGA设计verilog源码quartus工程 module f_13(clk_50M,f_13); input clk_50M; //输入时钟,50M,20ns output f_13; //输出4分频，占空比为1:3 reg f_13; //分频寄存器 reg[2:0] cnt; //计数寄存器 always@(posedge clk_50M) //在每个时钟的上升沿触发 begin if(cnt==3'b011) //当cnt为3的时候，执行以下程序 begin f_13<=1'b1; //f_13置1 cnt<=3'b0; //cnt清0 end else begin cnt<=cnt+3'b1; //cnt自加1
div2_二分频数控分频器_
09-30
在VHDL编程中，设计一个二分频数控分频器涉及到以下几个关键知识点： 1. **VHDL语言基础**：VHDL是一种硬件描述语言，用于描述数字系统，包括逻辑门、触发器、计数器、存储器等。了解VHDL的基本语法，如实体、...
基于verilog的时钟分频器
05-14
总之，基于Verilog的时钟分频器设计涉及硬件描述语言编程、时序约束、逻辑综合和仿真等多个步骤，是数字系统设计中的基础部分。通过理解和掌握这些知识点，开发者可以更加灵活地构建和定制自己的数字系统，以适应...
三分频的奇数分频器设计程序+报告
12-24
本项目聚焦于一个特定的数字电路设计——三分频的奇数分频器，它是频率处理中的一个重要组件。 三分频器，顾名思义，是将输入信号的频率降低到三分之一的装置。在数字系统中，分频器通常用于时钟生成或频率合成。...
计算分频器
03-27
在本文中，我们将深入探讨计算分频器的相关知识点，包括其原理、设计要素以及与电阻相关的应用。 首先，理解分频器的工作原理是至关重要的。分频器主要由电容器和电感器组成，它们构建了滤波网络，允许特定频率的...
分频器——(任意奇分频（50%占空比、非50%占空比），任意偶分频，任意小数分频）
m0_53333865的博客
11-17 4058
分频器——(任意奇分频（50%占空比、非50%占空比），任意偶分频，任意小数分频）,你能遇到的所有分频器的集合。
时钟分频原理
热门推荐
luoyir1997的博客
08-22 1万+
时钟分频原理 - 时钟分频原理详解     时钟分频原理 　　如果cpu是计算机的大脑，电流是计算机的血液，那么时钟则是计算机的心脏，时钟频率决定了处理器运算的快慢，它的每一次“跳动”都驱动着处理器不停的执行命令。不同的是，人的各个部位心率是一样的，但计算机却有多个频率，而且每个部位可能有不同的频率，比如“大脑”有一个频率，“手“有一个频率，“脚”使用的是另外一个频率，这样就产生了两个问题...
时钟分频
weixin_37603007的博客
11-09 5318
时钟分频器 偶数分频 奇数分频（占空比50%） 非整数分频（占空比也非50%） 本文参考《硬件架构的艺术》，主要介绍偶数分频时钟，计数分频（3,5分频），以及非整数分频（4.5分频） 1、偶数分频 偶数分频比较容易实现。实现一个N分频（N为偶数），每隔N/2个源时钟，分频时钟信号翻转一次。比如N=6时，在计数器等于2时，源时钟上升沿使信号翻转。 module even_clk_...
stm32f103的基础知识
04-02
STM32F103是一款32位微控制器，采用ARM Cortex-M3内核，具有高性能、低功耗、集成化等优点。以下是STM32F103的基础知识： 1. CPU：基于ARM Cortex-M3内核，最高主频可达72MHz。 2. 存储器：内置64KB闪存、20KB SRAM，还支持外部存储器。 3. 通信接口：支持多种通信协议，包括SPI、I2C、USART、CAN等。 4. 定时器：具有多个定时器，支持输入捕获、输出比较、PWM等功能。 5. 中断控制器：支持多级中断控制，可以实现多任务处理。 6. GPIO：具有多个GPIO引脚，可以实现各种输入输出功能。 7. ADC：具有12位ADC，可以实现模拟信号采集和转换。 8. DAC：具有12位DAC，可以实现模拟信号输出。 9. 时钟管理：支持多种时钟源和时钟分频器，可以实现精准时钟控制。 10. 低功耗模式：支持多种低功耗模式，可以实现节能和延长电池寿命。 以上是STM32F103的基础知识，需要注意的是，STM32F103还有很多高级功能，如DMA、USB、SDIO等，可以根据具体应用需求进行选择和配置。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 5
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值