HDLBits答案(16)_Verilog有限状态机(3)

已于 2022-09-12 10:51:10 修改
阅读量5k 收藏 10
点赞数 13
分类专栏： Verilog基础—HDLBits学习心得 文章标签： verilog
于 2020-11-25 18:38:17 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_42334072/article/details/110139746
版权

Verilog有限状态机(3)

HDLBits链接

前言

今天继续更新状态机小节的习题，本章主要编写Lemmings Game部分。

题库

题目描述10：

Game Lemmings1：有个小人左右走，它只有两种状态：向左走和向右走；左边碰到东西之后它就向右走，右边碰到东西之后它就向左走，两边都碰到东西就跟当前方向的反方向走；复位时小人向左走

1.png

Solution10：

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    output walk_left,
    output walk_right); //  

    parameter LEFT=1'b0, RIGHT=1'b1;
    reg state, next_state;
    wire [1:0] bump;
    assign bump = {bump_left,bump_right};

    always @(*) begin
        case(state)
        	LEFT:begin
                if((bump == 2'b10) || (bump == 2'b11))begin
                    next_state = RIGHT;
                end
                else begin
                    next_state = LEFT;
                end
            end
            RIGHT:begin
                if((bump == 2'b01) || (bump == 2'b11))begin
                    next_state = LEFT;
                end
                else begin
                    next_state = RIGHT;
                end
            end
        endcase
    end

    always @(posedge clk, posedge areset) begin
        if(areset)begin
            state <= LEFT;
        end
        else begin
            state <= next_state;
        end
    end

    // Output logic
    assign walk_left = (state == LEFT);
    assign walk_right = (state == RIGHT);

endmodule

题目描述11：

Game Lemmings2：有个小人左右走，它只有两种状态：向左走和向右走；左边碰到东西之后它就向右走，右边碰到东西之后它就向左走，两边都碰到东西就跟当前方向的反方向走；复位时小人向左走；

添加ground信号，ground=1时规则与上述规则相同；ground=0时，记录当前走的方向，并将aaah信号置1，直到ground=1时，走与掉落之前相同的方向。

Solution11：

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    output walk_left,
    output walk_right,
    output aaah ); 
    
    parameter LEFT = 2'b0;
    parameter RIGHT = 2'b1;
    parameter AH_LEFT = 2'b10;
    parameter AH_RIGHT = 2'b11;
    reg [1:0] state,next_state;
    wire [1:0] bump;
    assign bump = {bump_left,bump_right};
    
    always @(*)begin
        case(state)
        	LEFT:begin
                if(ground == 1'b0)begin
                	next_state = AH_LEFT;
                end
                else if((bump == 2'b10) || (bump == 2'b11))begin
                    next_state = RIGHT;
                end
                else begin
                    next_state = LEFT;
                end
            end
            RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = AH_RIGHT;
                end
                else if((bump == 2'b01) || (bump == 2'b11))begin
                    next_state = LEFT;
                end
                else begin
                	next_state = RIGHT;
                end
            end
            AH_LEFT:begin
                if(ground == 1'b0)begin
                	next_state = AH_LEFT;
                end
                else begin
                	next_state = LEFT;
                end
            end
            AH_RIGHT:begin
                if(ground == 1'b0)begin
                	next_state = AH_RIGHT;
                end
                else begin
                	next_state = RIGHT;
                end
            end
        endcase
    end
    
    always@(posedge clk,posedge areset)begin
        if(areset)begin
            state <= LEFT;
        end
        else begin
            state <= next_state;
        end
    end
    
    assign walk_left = (state == LEFT);
    assign walk_right = (state == RIGHT);
    assign aaah = ((state == AH_LEFT) | (state == AH_RIGHT));

endmodule

题目描述12：

Game Lemmings3：有个小人左右走，它只有两种状态：向左走和向右走；左边碰到东西之后它就向右走，右边碰到东西之后它就向左走，两边都碰到东西就跟当前方向的反方向走；复位时小人向左走；

添加ground信号，ground=1时规则与上述规则相同；ground=0时，记录当前走的方向，并将aaah信号置1，直到ground=1时，走与掉落之前相同的方向。

添加dig信号，ground=1时一直挖，ground=0时，进入aaah状态，直到ground再次为1，方向与dig开始的方向相同。

优先级：fall>dig>switch direction

1.png

手绘状态转移图：

IMG_0161.JPG

Solution12：

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 

    parameter LEFT = 3'b0;
    parameter RIGHT = 3'b1;
    parameter DIG_LEFT = 3'b10;
    parameter DIG_RIGHT = 3'b11;
    parameter FALL_LEFT = 3'b100;
    parameter FALL_RIGHT = 3'b101;
    
    reg [2:0] state,next_state;
    wire [1:0] bump;
    assign bump = {bump_left,bump_right};
    
    always @(*)begin
        case(state)
            LEFT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_LEFT;
                end
                else if(dig == 1'b1)begin
                    next_state = DIG_LEFT;
                end
                else if((bump == 2'b10) || (bump == 2'b11))begin
                    next_state = RIGHT;
                end
                else begin
                	next_state = LEFT;
                end
            end
            RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_RIGHT;
                end
                else if(dig == 1'b1)begin
                    next_state = DIG_RIGHT;
                end
                else if((bump == 2'b01) || (bump == 2'b11))begin
                    next_state = LEFT;
                end
                else begin
                	next_state = RIGHT;
                end
            end
            DIG_LEFT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_LEFT;
                end
                else begin
                    next_state = DIG_LEFT;
                end
            end
            DIG_RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_RIGHT;
                end
                else begin
                    next_state = DIG_RIGHT;
                end
            end
            FALL_LEFT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_LEFT;
                end
                else begin
                    next_state = LEFT;
                end
            end
            FALL_RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_RIGHT;
                end
                else begin
                    next_state = RIGHT;
                end
            end
        endcase
    end
    
    always @(posedge clk,posedge areset)begin
        if(areset)begin
            state <= LEFT;
        end
        else begin
            state <= next_state;
        end
    end
    
    assign walk_left = (state == LEFT);
    assign walk_right = (state == RIGHT);
    assign digging = ((state == DIG_LEFT) | (state == DIG_RIGHT));
    assign aaah = ((state == FALL_LEFT) | (state == FALL_RIGHT));
    
endmodule

题目描述13：

Game Lemmings4：小人行动规则与上述规则相同，添加小人会die的规则：

如果小人fall超过20cycles，则当其接触地面时直接die（未接触地面时不会die） dig，fall，left和right输出全部置零，直到reset信号来临。

2.png

手绘状态转移图：(Dead状态少个自己到自己的状态)

E12988C93DE1D991E7D347BEBF92998E.png

Solution13：

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 
    
    parameter LEFT = 3'b0;
    parameter RIGHT = 3'b1;
    parameter DIG_LEFT = 3'b10;
    parameter DIG_RIGHT = 3'b11;
    parameter FALL_LEFT = 3'b100;
    parameter FALL_RIGHT = 3'b101;
    parameter DEAD = 3'b110;
    parameter SPLATTER = 3'b111;
    
    reg [2:0] state,next_state;
    reg [4:0] Cycle_Count;
    
    wire [1:0] bump;
    assign bump = {bump_left,bump_right};
    
    always @(*)begin
        case(state)
            LEFT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_LEFT;
                end
                else if(dig == 1'b1)begin
                    next_state = DIG_LEFT;
                end
                else if((bump == 2'b10) || (bump == 2'b11))begin
                    next_state = RIGHT;
                end
                else begin
                    next_state = LEFT;
                end
            end
            
            RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_RIGHT;
                end
                else if(dig == 1'b1)begin
                    next_state = DIG_RIGHT;
                end
                else if((bump == 2'b01) || (bump == 2'b11))begin
                    next_state = LEFT;
                end
                else begin
                    next_state = RIGHT;
                end
            end
            
            DIG_LEFT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_LEFT;
                end
                else begin
                    next_state = DIG_LEFT;
                end
            end
            
            DIG_RIGHT:begin
                if(ground == 1'b0)begin
                    next_state = FALL_RIGHT;
                end
                else begin
                    next_state = DIG_RIGHT;
                end
            end
            
            FALL_LEFT:begin
                if((ground == 1'b0) && (Cycle_Count < 5'd20))begin
                    next_state = FALL_LEFT;
                end
                else if((ground == 1'b0) && (Cycle_Count >= 5'd20))begin
                    next_state = SPLATTER;
                end
                else begin
                    next_state = LEFT;
                end
            end
            
            FALL_RIGHT:begin
                if((ground == 1'b0) && (Cycle_Count < 5'd20))begin
                    next_state = FALL_RIGHT;
                end
                else if((ground == 1'b0) && (Cycle_Count >= 5'd20))begin
                    next_state = SPLATTER;
                end
                else begin
                    next_state = RIGHT;
                end
            end
            
            SPLATTER:begin
                if(ground == 1'b1)begin
                    next_state = DEAD;
                end
                else begin
                    next_state = SPLATTER;
                end
            end
            
            DEAD:begin
                next_state = DEAD;
            end
            
        endcase
    end
    
    always @(posedge clk,posedge areset)begin
        if(areset)begin
            state <= LEFT;
        end
        else begin
            state <= next_state;
        end
    end
    
    always @(posedge clk,posedge areset)begin
        if(areset)begin
            Cycle_Count <= 5'd0;
        end
        else if((next_state == FALL_LEFT) || (next_state == FALL_RIGHT)) begin
            Cycle_Count <= Cycle_Count + 1'b1;
        end
        else begin
            Cycle_Count <= 5'd0;
        end
    end
    
    assign walk_left = (state == LEFT);
    assign walk_right = (state == RIGHT);
    assign aaah = ((state == FALL_LEFT) || (state == FALL_RIGHT) || (state == SPLATTER));
    assign digging = ((state == DIG_LEFT) || (state == DIG_RIGHT));

endmodule

结语

今天更新的几道旅鼠题非常有意思，大家可以先自己尝试。代码若有问题的话可以与我交流。

日拱一卒_未来可期
关注
  • 13
    点赞
  • 踩
  • 10
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 8
    评论
专栏目录
Hdlbit:状态机Fsm serial参考答案及解析
m0_56158239的博客
08-31 454
Tip:首先定义四个状态,s1为开始状态检测输入in是否为0,是的话进入s2,s2为传输数据状态,定义了一个计数器,计数到8进入下一状态,s3判断in是否为1 module top_module( input clk, input in, input reset, // Synchronous reset output done ); parameter s1=0,s2=1,s3=2,Done=3,waitt=4; reg [3:0] stat...
Verilog HDL实现状态机（一）
weixin_38496610的博客
09-16 1605
1.状态机简介 状态机简写为FSM（Finite State Machine），也称为同步有限状态机。 分类：Moore型状态机，输出与输入相关，与当前无关； Mealy型状态机，输出与输入及当前相关； 2.可乐机状态机 可乐机状态机模拟功能：投入3枚硬币，出一瓶可乐； 模块框图如下： 状态转移图如下： Moore型状态机： Mealy型状态机： 其中，ID...
HDLBits答案(14)_Verilog有限状态机(1)
谦豫
11-03 7540
Verilog有限状态机(1) HDLBits链接 前言 今天来到了重要的部分：状态机。对该部分内容，可能不会一次更新一个小节；一方面是题目难度，另一方面是代码量过大；所以该节会分批更新，大家见谅。 题库 题目描述1： 实现下图所示的摩尔状态机，复位为异步复位。 Solution1： module top_module( input clk, input areset, // Asynchronous reset to state B input in, outp
HDLBits答案汇总
最新发布
kamo
06-03 836
四.Verificaton: Reading Simulation。五.Verification: Writing Testbench。一.Getting Started。三.Circuits。
HDLBits答案(20)_Verilog有限状态机(7)
谦豫
02-08 3288
Verilog有限状态机(7) HDLBits链接 前言 今天继续更新状态机小节的习题。 题库 Q3a:FSM 题目里说当s为0时，进入B状态，然后会检查w的值，如果在接下来的三个周期中w值恰好有两个周期都为1，那么z输出1，否则z输出0。注意，由示例的波形图看应该是不重叠检测。 Solution module top_module ( input clk, input reset, // Synchronous reset input s, input w,
HDLBits答案(18)_Verilog有限状态机(5)
谦豫
02-07 5098
Verilog有限状态机(5) HDLBits链接 前言 今天继续更新状态机小节的习题。 题库 题目描述1： 第一道题目比较容易，题目中的in信号包含了一个起始位（0），8个数据位和一个停止位（1），开始in为1，也就是IDLE状态，当in为0时，进入START状态，然后经过8个周期，如果in为1，则进入STOP状态，接着如果in为0，进入第二轮START状态，否则进入IDLE状态。 这里我用了很多个状态，实际上可以用计数器来代替中间的8个状态，这里是8个周期，如果是100个、200个周期，那么需要10
HDLBits答案
j1499的博客
07-24 888
HDLBit答案记录
Verilog HDLbits:Exams/2013 q2bfsm(有限元状态机)
m0_46272475的博客
11-02 794
题目 Consider a finite state machine that is used to control some type of motor. The FSM has inputs x and y, which come from the motor, and produces outputs f and g, which control the motor. There is also a clock input called clk and a reset input called res
Verilog HDLbits:Lemmings3（Moore型有限元状态机）
m0_46272475的博客
10-26 250
题目 In addition to walking left and right, Lemmings will fall (and presumably go “aaah!”) if the ground disappears underneath them. In addition to walking left and right and changing direction when bumped, when ground=0, the Lemming will fall and say “aaah!
HDLBits Verilog编程题139 Mealy状态机时序检测设计
Utopia_sy的博客
04-08 1018
Mearly状态机时序检测设计 139.Exams/ece241 2013 q8（Q8:Design a Mealy FSM） 原题：Implement a Mealy-type finite state machine that recognizes the sequence “101” on an input signal named x. Your FSM should have an ou...
Verilog HDLbits:Lemmings4（Moore型有限元状态机）
m0_46272475的博客
10-26 901
题目 Although Lemmings can walk, fall, and dig, Lemmings aren’t invulnerable. If a Lemming falls for too long then hits the ground, it can splatter. In particular, if a Lemming falls for more than 20 clock cycles then hits the ground, it will splatter and ce
HDL bits 网站刷题答案
11-08
这是HDL bits 刷题网站上的答案 大家可以参考下，里面的答案很全面，仅供参考，想要提升还是需要自己写，而不是嫖
FPGA学习笔记五：Moore状态机与Mealy状态机的区别（基于Verilog）
m0_51272018的博客
02-24 2243
eeww
HDLBits Verilog编程题128-131 Lemmings系列游戏状态机
Utopia_sy的博客
03-26 637
HDLBits Lemmings系列游戏状态机Lemmings1Lemmings2Lemmings3Lemmings4 为直观易于理解，状态机采用三段式写法，每个转移条件单独给出。输出需使用逻辑电路， 使用时序电路会比参考波形晚一个时钟周期。 注意：在设计状态机时需要充分考虑转换条件和优先级问题。 Lemmings1 当前进方向发生碰撞时调转方向 Lemmings1 状态转换图 此题较为简单直接...
HDLBits--答案
qq_56617535的博客
11-23 1068
2.2.7Vectorr first seconde always 内部用for循环，需要定义interger类型变量,同时在always内部不能使用assign连续赋值。 generate...endgenerate可有可无 third for语句在always 外部，或者使用for循环例化模块，需要定义genvar变量,同时for()begin:名字（必须要有名字），genvar i;可以放在generate........endgenerate里面 2.28 ...
HDLbits答案1
weixin_41543509的博客
03-16 476
目录 1. 入门 1.1 入门 1.2 输出零 2. 基本语言 2.1 简易电路 2.2 四线 2.3 逆变器 2.4 与门 2.5 或非门 2.6 XNOR门 2.7 宣告电线 2.8 7458芯片 1.入门 1.1 入门 module top_module (one); output one; assign one=1’b1; endmodule 1.2 输出零 module top_module(zero); output zero; assign zero=1’b0; endmodule `` 2.
HDLBits答案(17)_Verilog有限状态机(4)
谦豫
11-26 4703
Verilog有限状态机(4) HDLBits链接 前言 今天继续更新状态机小节的习题。 题库 题目描述1： One-hot FSM 独热编码，根据状态转移图输出下一状态与结果。 Solution1： module top_module( input in, input [9:0] state, output [9:0] next_state, output out1, output out2); parameter S0 = 4'd0;
Fsm3onehot
weixin_45614076的博客
11-29 1374
“通过检查得出方程”是什么意思？ One-hot 状态机编码保证恰好有一个状态位为 1。这意味着可以通过仅检查一个状态位而不是所有状态位来确定状态机是否处于特定状态。通过检查状态转换图中每个状态的输入边，这导致了状态转换的简单逻辑方程。 比如上面的状态机中，状态机如何才能达到状态A？它必须使用两个传入边之一：“当前处于状态 A 且 in=0”或“当前处于状态 C 且 in = 0”。由于 one-hot 编码，用于测试“当前处于状态 A”的逻辑方程只是状态 A 的状态位。这导致状态位 A 的下一个状态的最.
HDLbits答案（5 Building Larger Circuits)
weixin_42693865的博客
01-12 436
目录5 Building Larger Circuits5.1 Counter with period 1000（Exams/review2015 count1k）5.2 4-bit shift register and down counter（Exams/review2015 shiftcount）5.3 FSM:Sequence 1101 recognizer（Exams/review2015 fsmseq）5.4 FSM: Enable shift register（Exams/review2015
verilog有限状态机
09-14
Verilog有限状态机是使用硬件描述语言Verilog HDL编写的一种数学模型，用于表示有限个状态之间的转移和动作等行为。有限状态机在各种应用场景下都被广泛应用，如电机控制、通信协议解析等。 在Verilog中，可以使用一段式状态机来实现有限状态机的功能。一段式状态机只选择一个状态标志位，并根据输入的决定来选择跳转到下一个状态或维持原有状态。在每个状态下，通过检测状态标志位和输入来确定状态的跳转和输出。这种实现方式可以在一个always循环块中执行。 一个简单的例子可以是这样的： always @(posedge clk) begin case(state) S0: begin state <= (in) ? S0 : S1; out <= ...; end S1: begin state <= (in) ? S1 : S2; out <= ...; end S2: ... endcase end 在上述代码中，使用了一个时钟信号clk来驱动状态机的运行。根据当前状态state和输入信号in，判断下一个状态和输出信号out的值，并将其赋给相应的寄存器变量。根据实际需求，可以在每个状态中编写不同的逻辑来决定状态的转移和输出。 需要注意的是，这只是一个简单的示例，实际的Verilog有限状态机的实现可能会更加复杂，涉及更多的状态和逻辑。具体的实现方式和规范可以根据具体的应用需求和设计要求进行调整。
评论 8
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

日拱一卒_未来可期

若复习顺利望有闲钱的同学支持下

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值