unity shader 学习笔记 SpecularVertexLevel

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity Shader Book/Chapter 6/SpecularVertexLevel"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1, 1, 1, 1)
        _Specular("Specular", Color) = (1, 1, 1, 1)
        _Gloss("Gloss", Range(8, 256)) = 20
    }
        SubShader
    {
        Pass
        {
            Tags{ "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; //得到系统环境光源，如系统颜色或者天空盒子
                fixed3 worldNormal = mul(v.normal, (float3x3)unity_WorldToObject); //世界空间的法线
                //fixed3 worldNormal = mul((float3x3)unity_ObjectToWorld, v.normal);
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz); //光源方向
                //在得到了世界空间中的法线和光源方向后，我们需要对它们进行归一化操作。在得到它们点击的结果后，我们使用saturate函数  
                //把参数截取到[0, 1]范围内。最后，再与光源颜色和强度以及材质的漫反射颜色相乘可得到最终的漫反射光照部分
                //光源颜色 * 自身颜色 * 反射角度 =  漫反射颜色
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                //获取世界空间的反射方向  reflect 获取反射方向
                fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));
                //获取世界空间的视图方向  摄像机在世界空间的位置 - 当前模型在世界空间的位置
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
                //计算镜面反射   灯光颜色 * 设置颜色 * pow(反射角度（取值范围0~1）) = 镜面高光反射颜色
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
                //系统光源颜色 + 漫反射颜色 + 高光颜色
                o.color = ambient + diffuse + specular;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(i.color, 1);
            }
            ENDCG
        }
    }

        Fallback "Diffuse"
}