【Unity Shader】纹理颜色代替漫反射颜色

写在前面

这篇主要是介绍基础纹理知识，图片参数设置、UV，最后实现用图片纹理颜色替代漫反射颜色

纹理基础

在Unity中uv的含义就是将图片纹理分配至0~1的坐标内，u代表横坐标，v代表纵坐标

Alpha Source

Input Texture Alpha：导入图片本身的alpha通道
From Gray Scale：从图片本身灰度信息生成alpha通道

Advanced

Generate Mip Map：生成多级纹理

Wrap Mode

当纹理坐标超出0~1时展现出什么纹理
Repeat:重复展现0~1之间
Clamp：大于1取1，小于0取0.

Filter Mode

纹理放大缩小时会采用的滤波模式
Point：纹理采样最近1个像素点
Bilinear：纹理采样最近4个像素点
Trilinear:纹理采样最近4个像素点，如果开启多级纹理，则在多级纹理间混合得出

Max Size

图片将会被缩放为此分辨率
原图最好长宽为2的幂次方

步骤

声明属性

 Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}

Pass中定义属性

	fixed4 _Color;
	sampler2D _MainTex;
	float4 _MainTex_ST;
	fixed4 _Specular;
	float _Gloss;

对UV进行缩放和平移
纹理名称+_ST得到的是纹理的Tiling和Offset

o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
//o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);内置函数转换

计算纹理颜色
使用tex2D函数，传入纹理和uv，乘上_Color调节颜色

fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;

计算漫反射

fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

完整代码

Shader "Single Texture" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {		
		Pass { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;//获得纹理坐标
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				// Or just call the built-in function
//				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				
				// Use the texture to sample the diffuse color
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				
				return fixed4( diffuse , 1.0);
			}
			
			ENDCG
		}
	} 
	//FallBack "Specular"
}

效果图

1是标准材质
2是只有纹理漫反射