【Unity Shader】基础光照

这两天算是正式从OpenGL来到UnityShader了。毕竟了解清除底层，再来学习上层的东西，会容易理解很多。

今天实现的是一个基础光照（大名鼎鼎的PhoneShading），在这之前，有一些知识点需要注意一下：

1.逐像素光照还是逐顶点光照

在顶点着色器中计算光照被称为逐顶点光照。
在片元着色器中计算光照被称为逐像素光照。

逐顶点光照又叫做高洛德着色（Gouraud Shading）。在逐顶点光照中，是在每个顶点上计算光照，然后在渲染图元内部进行线性插值，最后输出成像素颜色。

逐像素光照是以每个像素为基础，得到它的法线，然后进行光照模型的计算。这种在面片之间对顶点法线进行差值的技术叫做（Phone着色），或者叫做法线插值

2.基础的Phone（包括Bling-Phone模型）的着色组成
着色 = 自发光 + 高光反射 + 漫反射 + 环境光

3.Lambert余弦定理：
反射光线的强度与表面法线和光源方向之间夹角的余弦值成正比

4.坐标系转换注意点：
在计算法线和光源方向的点积时，只有处于统一坐标系空间下才有意义

5.Bling-Phone与Phone：
书上写的差别在于Bling-Phone使用的是半程向量和法线做点积计算。
Phone使用的是反射光线和视线做点积计算

逐顶点光照（高光反射模型）：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/SpecularVertexLevel"
{
    Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)//漫反射颜色
        _Specular("Specular",Color) = (1,1,1,1)//高光区域颜色
        _Gloss("Gloss",Range(8.0,256)) = 20//控制高光区域大小，即幂指数   
    }
    SubShader
    {
        Pass
        {
            Tags {"LightMode" = "ForwardBase"}//只有定义了正确的LightMode，才能得到一些Unity内置光照变量

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            //属性中声明的变量还需要在流水线中定义
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v{//顶点着色器的输入结构体
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f{//顶点着色器的输出结构体
                float4 pos : SV_POSITION;
                fixed3 color : Color;                
            };

            v2f vert(a2v v){
                v2f o;
                //将顶点从模型空间转换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex);

                //得到环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //将法线从模型空间转换到世界空间
                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                //得到世界空间下的光源方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //计算漫反射项
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

                //得到世界坐标系下的反射方向
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                //得到世界坐标系系的视向量
                fixed3 viewDir = normalize(_WorldSpaceLightPos0.xyz - mul(unity_ObjectToWorld,v.vertex).xyz);

                //计算高光项
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                o.color = ambient + diffuse + specular;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                return fixed4(i.color,1.0);
            }

            ENDCG
        }
    }
    Fallback "Specular"
}

逐像素光照（高光反射模型）：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

//逐像素高光反射模型
Shader "Unlit/SpecularPixelLevel"
{
   Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)//漫反射颜色
        _Specular("Specular",Color) = (1,1,1,1)//高光区域颜色
        _Gloss("Gloss",Range(8.0,256)) = 20//控制高光区域大小，即幂指数   
    }
    SubShader
    {
        Pass
        {
            Tags {"LightMode" = "ForwardBase"}//只有定义了正确的LightMode，才能得到一些Unity内置光照变量

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            //属性中声明的变量还需要在流水线中定义
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v{//顶点着色器的输入结构体
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f{//顶点着色器的输出结构体
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;           
            };

            v2f vert(a2v v){
                v2f o;
                //将顶点从模型空间转换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex);

                //将法线从模型空间转换到世界空间
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);

                //将顶点从模型空间转换到世界空间
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                //得到环境光项
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //计算漫反射项
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

                //得到世界坐标下的反射向量
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                //得到世界坐标下的视向量
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                //计算高光项
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);

            }

            ENDCG
        }
    }
    Fallback "Specular"
}

Bling-Phone模型只需要替换片元着色器中的一些计算即可

                //得到世界坐标下的视向量
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                //得到半程向量
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                //计算高光项
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(wolrdNormal,halfDir)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);

需要注意的是，我平时有看到过要减少reflect（）这个函数的使用次数，目的是为了提升计算性能。所以计算高光的时候尽量多使用半程向量。至于具体reflect（）更多消耗在哪里了，我还没有去查证。以后看到了会单开一篇讨论。