Shaderlab编程入门四

接下来的几个章节，专门写一些关于顶点与片段着色器的相关应用

一、模型上显示顶点信息

Shader "chen/ShowPositionMsg"
{
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
            };//定义输入的结构体及语义

            struct v2f
            {
                float4 vertex : SV_POSITION;
                fixed4 color : TEXCOORD0;
            };//定义输出的结构体及语义

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);//矩阵变换，顶点从模型空间转换到裁剪空间,等同于mul(UNITY_MATRIX_MVP,v.vertex)
                                                          //另外还有：
                                                          //UnityObjectToViewPos(v.vertex) 顶点从模型空间转换为观察空间，等同于mul(UNITY_MATRIX_MV, v.vertex)
                                                          //UnityObjectToWorldDir(v.vertex) 顶点从模型空间转换到世界空间
                                                          //UnityViewToClipPos(v.vertex) 顶点从观察空间转为裁剪空间
                                                          //UnityWorldToClipPos(v.vertex) 顶点从世界空间转到裁剪空间
                                                          //UnityObjectToWorldNormal(v.vertex) 法线从模型空间转换到世界空间
                                                          //UnityWorldToObjectDir(v.vertex)  法线世界空间转到模型空间
                o.color = v.vertex;//记录模型空间顶点信息
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return i.color;
            }
            ENDCG
        }
    }
}

二、顶点动画

最常见的就是同时相对简单的就是翻页效果：

Shader "chen/MoveWithVertex"
{
    Properties
    {
        _MainPageTex("正面贴图",2D) = "white"{}
        _BackPageTex("背面贴图",2D) = "white"{}
        _TurnAngle("翻页角度",Range(0,180)) = 0
        _WaveLength("波长",float) = 0
        _WeightY("收缩程度",float) = 0
        [Toggle]_IsOpen("打开/闭合",int) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue" = "Geometry" "IgnoreProjector" = "True" "DisableBatching" = "True" }

        Pass
        {
            Cull back  //剔除背面渲染
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile _ _ISOPEN_ON
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 pos : POSITION;
                float2 uv : TEXCOORD0;
            };
            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };
            sampler2D _MainPageTex;
            float _TurnAngle,_WaveLength,_WeightY;
            float4 _MainPageTex_ST;            
            v2f vert (appdata v)
            {
                v2f o;
                v.pos +=float4 (5,0,0,0);//平移5个单位后，相当于围绕Y轴转动
                float s = 0,c = 0;
                sincos(radians(-_TurnAngle),s,c);//计算出该角度的正余弦值
                float4x4 rotate = {
                    c,s,0,0,
                    -s,c,0,0,
                    0,0,1,0,
                    0,0,0,1
                };

                #if _ISOPEN_ON                
                    v.pos.y +=sin(v.pos.x*_WaveLength)*s*_WeightY;                
                #else                
                    v.pos.y -=sin(v.pos.x*_WaveLength)*s*_WeightY;
                #endif
                
                v.pos = mul(rotate,v.pos);
                v.pos -=float4 (5,0,0,0);
                o.pos = UnityObjectToClipPos(v.pos);
                o.uv = TRANSFORM_TEX(v.uv, _MainPageTex);	
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {				
                fixed4 col = tex2D(_MainPageTex, i.uv);				
                return col;
            }
            ENDCG
        }
    }
}

代码加了变体，便于切换是展开还是合上效果。此处只做了正面渲染，一般的纸张都是双面的，只需要仿照这个思路加个PASS即可，有兴趣的读者可以尝试一下。