检测-饼干完整度的检测

本示例通过形态学处理，然后再通过矩形度和孔洞面积作为判断依据，来确认饼干的完整情况。

示例代码：

* 这个例子描叙了饼干质量检测。
* 使用形态学进行提取和检查
* 通过一些形状特征，比如矩形度还有孔洞面积

* 读图像
read_image (Image, 'food/hazelnut_wafer_01')
dev_close_window ()
dev_open_window_fit_image (Image, 0, 0, -1, -1, WindowHandle)
dev_update_window ('off')
dev_set_line_width (3)
dev_set_draw ('margin')
set_display_font (WindowHandle, 20, 'mono', 'true', 'false')
* 
for Index := 1 to 24 by 1
    * 读图像
    read_image (Image, 'food/hazelnut_wafer_' + Index$'.02')
    * 快速二值化，提取出属于饼干区域的亮区域
    binary_threshold (Image, Foreground, 'smooth_histo', 'light', UsedThreshold)
    * 开运算，去掉外围的一些杂点
    opening_circle (Foreground, FinalRegion, 8.5)
    * 计算区域中所有孔洞的面积和
    area_holes (FinalRegion, AreaHoles)
    * 计算区域的矩形度，也就是给该区域打分，越与矩形相似，得分越高
    rectangularity (FinalRegion, Rectangularity)
    dev_display (Image)
    * 以孔洞面积、矩形度来判断饼干的完整性
    * 区域内孔洞面积越大，说明饼干内部碎，如果矩形度得分低，说明饼干的边缘碎
    if (AreaHoles > 300 or Rectangularity < 0.92)
        dev_set_color ('red')
        Text := 'Not OK'
    else
        dev_set_color ('forest green')
        Text := 'OK'
    endif
    dev_display (FinalRegion)
    disp_message (WindowHandle, Text, 'window', -1, -1, '', 'false')
    if (Index < 24)
        disp_continue_message (WindowHandle, 'black', 'true')
        stop ()
    endif
endfor

重点说明：
1. 计算区域内孔洞面积的算子为area_holes，如果在区域内有多个孔洞，该算子会计算所有孔洞的面积和。
2. 得到区域的矩形度算子为rectangularity，如果区域和矩形相似度越高，则得分越高。
3. 判断一块饼干是否完整的判断条件为：如果矩形度得分小于0.92分，或者是孔洞面积大于300，但凡这两个条件有一个满足，则该饼干是不完整的。

更多最新文章，请关注公众号：

执行流程：
完整的饼干图像

完整饼干的区域：

完整饼干的检测结果显示：

破碎的饼干图像：

破碎饼干的区域：

破碎饼干的检测结果显示：