UnityShader基础（一）——基础光照

已于 2023-01-21 13:33:37 修改
阅读量1.2k 收藏 7
点赞数
分类专栏： UnityShader开发 文章标签： unity 技术美术
于 2022-09-11 20:45:04 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/SliverAsh_/article/details/126806472
版权

        在入门系列最后一节中可以看到输出结果，尽管模型是一个立方体，但我们看到的就是一坨，为了丰富细节，会模拟光照使模型表面更加明显，就如同在现实生活中我们看到物体时是借助光线，在Shader也是同样。

1.1 自发光：

        在上一篇文章中已经指明，向外暴露的_Color属性即是物体的自发光。

1.2 环境光：

        绝大多数物体都是没有自发光特性的，因此光照模型计算一般不会让自发光参与，想要计算自发光也可以，只需在最后将自发光颜色与环境光颜色相加后输出。        

Shader "Custom/Test0"
{
    Properties
    {
    }
    SubShader
    {
        
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            fixed4 _Color;
            float4 vert(float4 vertex:POSITION):SV_POSITION
            {
                //坐标转换
                return UnityObjectToClipPos(vertex);                
            }

            fixed4 frag():SV_Target
            {
                //使用内置宏来得到Unity的环境光颜色并返回                
                return fixed4(UNITY_LIGHTMODEL_AMBIENT.rgb,1);
            }
            
            ENDCG
        }
    }
}

1.3 环境光+漫反射：

        注意环境光不应为白色附近，否则无法得到正确光照结果，建议为环境光为黑色,场景中的平行光为白色。

        漫反射光照公式：gif.latex?c_%7Bdiffuse%7D%3D%28c_%7Blight%7D*m_%7Bdiffuse%7D%29max%280%2Cn%5Ccdot%20l%20%29

        gif.latex?c_%7Blight%7D是光源颜色，gif.latex?m_%7Bdiffuse%7D是材质的漫反射颜色，gif.latex?n为表面法线的方向，gif.latex?l为指向光源的方向，注意本系列除特外说明，所用到的方向全是单位矢量。

       1.3.1 逐顶点光照：

Shader "Custom/Test1"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 vertex:SV_POSITION;
                fixed3 color :COLOR;             
            };
            
            v2f vert(a2v i)
            {
                v2f o;
                o.vertex=UnityObjectToClipPos(i.vertex);

                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldNormal = UnityObjectToWorldNormal(i.normal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);
                //向量在同一空间下，计算才有意义
                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*
                               saturate(dot(worldLight,worldNormal));

                o.color=ambient+diffuse;

                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {
                //将已经插值过的颜色输出                            
                return fixed4(i.color,1);
            }
            
            ENDCG
        }
    }
}

       1.3.2 逐像素光照：

Shader "Custom/Test2"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 vertex:SV_POSITION;
                float3 worldNormal :COLOR;             
            };
            
            v2f vert(a2v v)
            {
                v2f o;

                o.vertex=UnityObjectToClipPos(v.vertex);
               
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;
        
                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*
                             saturate(dot(worldLight,worldNormal));
                return fixed4(ambient+diffuse,1);
            }
            
            ENDCG
        }
    }
}

      1.3.3  半兰伯特模型：

Shader "Custom/Test2"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal :COLOR;             
            };
            
            v2f vert(a2v v)
            {
                v2f o;

                o.pos=UnityObjectToClipPos(v.vertex);
               
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;
        
                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*
                             (dot(worldLight,worldNormal)*0.5+0.5);
                return fixed4(ambient+diffuse,1);
            }
            
            ENDCG
        }
    }
}

c6a496467f484ab79dffec91d7797e6c.png

 左一侧为逐顶点，左二为逐像素，左三为半兰伯特。

        区别：逐像素的光照因为计算频率更高，得到的效果也普遍更好。

1.4 环境光+漫反射+高光反射：

        1.4.1 逐顶点：

Shader "Custom/Test1"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
        _Specular("高光反射系数",Color)=(1,1,1,1)
        _Gloss("光泽度",Range(0,256))=20
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;
            fixed4 _Specular;
            fixed _Gloss;
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                fixed3 color :COLOR;             
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;
                //漫反射计算
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*
                            saturate(dot(worldLight,worldNormal));
                //高光反射计算
                fixed3 reflectDir=normalize(reflect(-worldLight,v.normal));

                fixed3 viewDir=normalize(WorldSpaceViewDir(v.vertex));
                
                fixed3 specular=_LightColor0*_Specular*
                            pow(saturate(dot(viewDir,reflectDir)),_Gloss);
                
                o.color=ambient+diffuse+specular;

                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {                            
                return fixed4(i.color,1);
            }
            
            ENDCG
        }
    }
}

        1.4.2 常规逐像素：

Shader "Custom/Test2"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
        _Specular("高光反射系数",Color)=(1,1,1,1)
        _Gloss("光泽度",Range(0,256))=20
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;
            fixed4 _Specular;
            fixed _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 vertex:SV_POSITION;
                float3 worldNormal :TEXCOORD0;                
                float3 worldPos:TEXCOORD1;
          
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                o.vertex=UnityObjectToClipPos(v.vertex);               
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                //unity有一个内置API，只能负责向量变化，顶点不能使用
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;   
                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb
                            *saturate(dot(worldLight,worldNormal));

                //高光反射计算
                fixed3 reflectDir=normalize(reflect(-worldLight,i.worldNormal));

                fixed3 viewDir=normalize(_WorldSpaceCameraPos-i.worldPos);
  
                fixed3 specular=_LightColor0.rgb*_Specular
                            *pow(saturate(dot(viewDir,reflectDir)),_Gloss);
                
                return fixed4(ambient+diffuse+specular,1);
            }
            
            ENDCG
        }
    }
}

        1.4.3 Blinn-Phong逐像素：

Shader "Custom/Test2"
{
    Properties
    {
        _Diffuse("漫反射系数",Color)=(1,1,1,1)
        _Specular("高光反射系数",Color)=(1,1,1,1)
        _Gloss("光泽度",Range(0,256))=20
    }
    SubShader
    {
        
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"
            fixed4 _Diffuse;
            fixed4 _Specular;
            fixed _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;                                
            };

            struct v2f
            {
                float4 vertex:SV_POSITION;
                float3 worldNormal :TEXCOORD0;                
                float3 worldPos:TEXCOORD1;
          
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                o.vertex=UnityObjectToClipPos(v.vertex);               
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                //unity有一个内置API，只能负责向量变化，顶点不能使用
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;   
                return o;
                
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb
                            *saturate(dot(worldLight,worldNormal));
               
                //高光反射计算
                fixed3 viewDir=normalize(_WorldSpaceCameraPos-i.worldPos);
                
                fixed3 halfDir=normalize(viewDir+worldLight);
                
                fixed3 specular=_LightColor0.rgb*_Specular
                            *pow(saturate(dot(worldNormal,halfDir)),_Gloss);
                
                return fixed4(ambient+diffuse+specular,1);
            }
            
            ENDCG
        }
    }
}

546dda175e594c43b5ffbdffc166d286.png

        左一侧为逐顶点，左二为常规逐像素，左三为Blinn-Phong。

        一般使用Blinn-Phong光照模型的更多。逐顶点的高光部分表现并不好，主要是高光计算是非线性的，而插值过程是线性的，非线性的计算会破坏线性的插值，使得线性的结果变的非线性，也就导致高光不平滑。

implosion98
关注
  • 0
    点赞
  • 踩
  • 7
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
（三）unity shader基础之——————unity shader基础
cgy56191948的博客
10-03 486
前面的文章讲过，shader其实就是渲染流水线某些特定阶段，如顶点着色器阶段、片元着色器阶段等。 一、unity shader概述 1.1材质和untiy shader untiy中药配合使用材质和shader才能达到需要的效果，shader定义了渲染所需的各种代码（如顶点着色器和片元着色器）、属性（使用哪些纹理）和指令（渲染和标签设置等），而材质允许我们调节这些属性，最终赋值给相应模型。 ...
（十二）unity shader基础之——————基础光照：下篇（unity中实现漫反射）
cgy56191948的博客
10-11 321
基础光照上篇主要讲的是unity中的光照模型及其原理，还有几种光照类型（自发光、环境光、漫反射、高光反射），后面几篇文章就开始在unity中实现这几种光照类型，本篇在unity实现漫反射。 一、在unity shader中实现漫反射光照模型 下面我们来实现光照模型中的漫反射光照部分，计算公式如下： 基本光照模型中漫反射部分的计算公式： Cdiffuse=(Clight · mdiffus...
Unity Shader 入门精要——第6章Unity中的基础光照
weixin_38844255的博客
05-05 210
反射方向可通过表面法线、光源方向信息计算得到。假设这些矢量都是单位向量。计算高光反射需要知道的信息比较多，如表面法线(
Unity Shader入门精要——光照衰减
weixin_51327051的博客
09-16 844
在前向渲染中我们提到Unity使用一张纹理作为查找表来在片元着色器中计算逐像素光照的衰减。这样的好处在于，计算衰减不依赖于数学公式的复杂性，我们只要使用一个参数值去纹理中采样即可。但使用纹理查找来计算衰减也有一些弊端。 ●需要预处理得到采样纹理，而且纹理的大小也会影响衰减的精度。 ●不直观，同时也不方便，因此- -旦把数据存储到查找表中，我们就无法使用其他数学公式 来计算衰减。 但由于这种方法可以在一-定程度 上提升性能，而且得到的效果在大部分情况下都是良好的，因此Unity默认就是使用这种纹理查找的方
Unity Shader入门精要——第3章 Unity Shader基础
qq_41044598的博客
08-15 1282
Unity Shader入门精要读书笔记第3章
UnityShader——基础篇之UnityShader基础
Aubyn11的博客
06-23 839
Unity Shader 是 Unity 为研发者提供的高层记得渲染抽象层，Unity 希望以这种方式来让开发者更加轻松的控制渲染，见下图：在 Unity 中，所有的 Unity Shader 都是使用 ShaderLab 来编写的ShaderLab 是 Unity 编写 Unity Shader 的一种说明性语言，它使用了一些嵌套在花括号内部的**语义&&（syntax。
Unity Shader入门精要——几种光照模型
weixin_51327051的博客
09-08 501
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject' // Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld' // Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld' // Upgrade NOTE: replaced '_World2Object' with.
Chapter3 Unity Shader 基础——Shader入门精要学习笔记
weixin_70073176的博客
06-11 1193
创建一个材质创建一个Unity shader，赋给材质把材质赋给传输的对象在材质面板调节unity shader的属性。
（二十八）unity shader之——————基于光照贴图（lightmap）的烘焙详细介绍
cgy56191948的博客
12-25 3317
光照贴图（Lightmap）是一种效果明显的模拟光照的方法，这种光照贴图需要提前渲染，因此可以应用在静态效果图中，属于全局照明技术。但是这种方法一般只适用于静态物体。当然unity做了很多工作，可以让我们混合使用静态光照贴图和动态实时光源，无缝地照亮场景中静态或动态的物体。 注意，受到光照贴图的影响的物体只能在静态物体上合并批次渲染。动态和GPU Instancing两种合并批次的方式unit...
unity Shader编写一个流动的云效果
10-08
在Unity中，通常使用CG或HLSL语言来编写Shader，它们可以被编译为Unity支持的Shader语言——Surface Shader或者Vertex/Fragment Shader。 流动的云效果通常涉及到时间变化和纹理动画。我们可以通过以下步骤实现这一...
基于Shader开发的Unity碎屏特效
03-01
在Unity游戏引擎中，Shader是一种强大的工具，用于控制场景中的物体如何被光照、颜色和纹理影响。Shader可以实现各种复杂的视觉效果，从简单的颜色变换到高级的物理模拟。本教程聚焦于利用Shader开发一个独特的...
unity_shaders_book_chapter_4_unityshader_SHADER_unity_
10-03
《Unity Shader编程进阶——第四章：Unity Shader与Shader基础知识》 在Unity引擎中，Shader是一种强大的工具，用于控制游戏中的图形渲染效果。本章主要围绕Unity Shader的基础知识展开，涵盖了在Shader编程过程中...
Unity 超强 Shader 源码
09-22
4. **DefaultResources和DefaultResourcesExtra**：这两个文件夹可能包含了Unity默认的一些Shader资源和扩展资源，比如基础材质效果、光照模型等，开发者可以查看和学习这些预设Shader的工作原理。 5. **Editor文件...
《Unity Shader入门精要》源代码.rar
05-20
同时，这也有助于理解和适应Unity引擎的Shader语言——Surface Shader和CG HLSL，这两种语言是Unity Shader开发的核心。 在学习过程中，读者应注重理论与实践相结合，理解Shader背后的数学原理，如向量运算、矩阵...
AI与技术美术（TechArt）
OkizukiNanami的博客
04-02 1271
-
qt练习控件label控件-lineEdit控件样例代码
最新发布
07-30
qt练习控件label控件-lineEdit控件样例代码
【JCR一区级】麻雀搜索算法SSA-CNN-LSTM-Attention故障诊断分类预测【含源码 5689期】.zip
07-30
CSDN海神之光上传的全部代码均可运行，亲测可用，直接替换数据即可，适合小白； 1、代码压缩包内容 主函数：Main .m； 数据； 调用函数：其他m文件；无需运行 运行结果效果图； 2、代码运行版本 Matlab 2019b；若运行有误，根据提示修改；若不会，可私信博主； 3、运行操作步骤 步骤一：将所有文件放到Matlab的当前文件夹中； 步骤二：双击打开除Main.m的其他m文件； 步骤三：点击运行，等程序运行完得到结果； 4、仿真咨询 如需其他服务，可私信博主或扫描博主博客文章底部QQ名片； 4.1 CSDN博客或资源的完整代码提供 4.2 期刊或参考文献复现 4.3 Matlab程序定制 4.4 科研合作 智能优化算法-CNN-LSTM-Attention分类系列程序定制或科研合作方向： 4.4.1 遗传算法GA/蚁群算法ACO-CNN-LSTM-Attention分类 4.4.2 粒子群算法PSO/蛙跳算法SFLA-CNN-LSTM-Attention分类 4.4.3 灰狼算法GWO/狼群算法WPA-CNN-LSTM-Attention分类 4.4.4 鲸鱼算法WOA/麻雀算法SSA-CNN-LSTM-Attention分类 4.4.5 萤火虫算法FA/差分算法DE-CNN-LSTM-Attention分类
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值