Testbench编写指南（2）文件的读写操作

Testbench编写指南是博主新开的一个系列，主要介绍在编写testbench时使用到的技巧，让编写者的水平不再仅仅停留在时钟信号、复位信号等简单信号的设置上，更好的完成对设计的仿真工作。

第2篇的题材是文件的读写控制，仿真时经常需要从文件中读取测试激励，还要将仿真结果存取在文件中供其它程序读取调用。

---

读取txt文件数据

示例代码如下：

integer i;   //数组坐标
reg [9:0] stimulus[1:data_num];  //数组形式存储读出的数据

initial 
begin
    $readmemb("SinIn.txt", stimulus);  //将txt文件中的数据存储在数组中
    i = 0;
    repeat(data_num) begin   //重复读取数组中的数据
        i = i + 1;
        din = stimulus[i]; 
        #clk_period;         //每个时钟读取一次
    end
end           

用“数组”来表述Verilog HDL中的定义并不准确，但对大多数人来说应该更好理解。可以将stimulus视作一个存储器，[9:0]定义了数据的位宽，[1:data_num]定义了存储器的深度。stimulus的定义应该与txt文件中的数据相匹配。txt文件中每行存储一个数据，则上述定义对应的是txt中存储了data_num个数据，每个数据的最大位宽为10bit。

读取二进制格式的文件是用系统任务$readmemb；读取十六进制格式文件使用$readmemh。其命令为$readmemb(“filename”, mem_name)，将filename中的内容读取到mem_name中。

注意filename文件路径中应该用反斜杠“/”，与windows系统中的文件路径使用的“\”不同。如果不指定路径，向上面程序一样直接写文件名字，那么该文件必须和testbench文件在同一路径下。

repeat(n) begin … end中的内容应该根据设计的需要编写。

---

将数据写入txt文件

示例代码如下：

integer file_out;
initial
begin
    file_out = $fopen("mixer_out.txt");
    if (!file_out) begin
        $display("can't open file");
        $finish;
    end
end            

wire signed [19:0] dout_s = dout;
wire rst_write = clk & rst_n;         //复位期间不应写入数据
always @ (posedge rst_write)   
    $fdisplay(file_out, "%d", dout_s);

写入文件需要先用$fopen系统任务打开文件，这个系统任务在打开文件的同时会清空文件，并返回一个句柄，如果句柄为0则表示打开文件失败。

如果原来不存在该文件，则会自动创建该文件。

打开文件之后便可以用得到的句柄和$fdisplay系统任务向文件中写入数据。这个系统任务和我们在C++中常用的fprintf函数的用法很像。

上面的程序中是将数据转换为带符号数signed后再写入，必须说明转换与否是有差别的，如果按默认的unsigned的格式写入txt的是无符号数。

另外，每使用一次$fdisplay，都会在数据后插入一个换行符。