CANoe-第2个仿真工程-XVehicle—3 CAPL编程（操作）

本文内容主要是：XVehicle节点的功能及对应的CAPL详细程序。

本文内容来自于《CANoe开发从入门到精通》。

目录

X-Vehicle工程节点-信号图

创建CAPL文件

Engine节点的CAPL

Door节点的CAPL

Display节点的CAPL

---

X-Vehicle工程节点-信号图

 （图先凑活看一下）

环境变量：节点的IO信号，可用于面板或真实IO

系统变量：ECU节点内部变量

创建CAPL文件

simulation setup界面的ECU由编辑数据库时，将生成的数据库文件，及对应的nodes导入simulation setup生成。

在simulation setup界面，在对应ECU上右键，分别新建engine.can, door.can, display.can，保存在nodes文件夹下。

Engine节点的CAPL

engine节点需要根据用户操作，发送信号，对应的ECU 功能是：

1. 在接收到‘开启关闭引擎’操作时，将OnOff信号 更新到报文EngineState上。
2. 在引擎速度变化时，判断是否需要将EngineSpeed信号更新到报文 EngineState上。
   1. 如果引擎是开启状态On，那么就更新报文EngineState的EngineSpeed信号
   2. 如果引擎是关闭状态Off，那么报文的EngineSpeed应该为0

代码如下：

/*@!Encoding:936*/
/*
功能：
1. 引擎开关动作时，更新报文EngineState中的信号OnOff
2. 引擎开关与引擎速度的逻辑关系：
  - 引擎运行时，引擎速度可以更新
  - 引擎关闭时，引擎速度自动设置为0
*/
includes
{
  
}

variables
{
  
}
//引擎启动时，更新报文的速度信息
On sysvar sysvar::Engine::EngineStateSwitch
{
  $EngineState::OnOff = @this;
  if(@this)
    $EngineState::EngineSpeed = @sysvar::Engine::EngineSpeedEntry;
  else
    $EngineState::EngineSpeed = 0;
}
//速度控制改变时，更新报文的速度信息
On sysvar sysvar::Engine::EngineSpeedEntry
{
  if(@sysvar::Engine::EngineStateSwitch){
    $EngineState::EngineSpeed = @this;
  }
}

Door节点的CAPL

Door节点根据用户操作，发送门的开启消息:

发送报文：DoorState（信号:Door_L,Door_R）

由于在Panel设计中已经将报文与车门开关控制关联上了，所以CAPL中不需要此部分的代码。

下面的代码是，增加一些write窗口的调试输入输出功能。

/*@!Encoding:936*/
/*功能：
write窗口的调试输出功能：通过调用函数，输出用户关心的信息.
SetwriteDbgLevel设定函数和 writeDbgLevel输出函数
(1)key'0'关闭调试信息输出，Key'1'打开调试信息输出
(2)检查报文DoorState的接收方向，
  - 调试信息输出功能打开时，可以输出到Write窗口
  - 理论上，节点Door不应该收到其他节点发送过来的报文DoorState
*/
includes
{
  
}

variables
{
  int gDebugCounterTX = 0;
  int gDebugCounterTXRQ = 0;
  int gDebugCounterRX = 0;
}

On start
{
  setWriteDbgLevel(0);//设定debugLevel为0，禁止输出debug信息
}
//检查报文DoorState的传输 方向
On message DoorState
{
  //如果方向为TX
  if (this.dir == TX)
  {
    gDebugCounterTX++;
    if(gDebugCounterTX==10)
    {
      writeDbgLevel(1,"DoorState TX recieved by node %NODE_NAME% ");
      gDebugCounterTX = 0;
    }
  }
  //如果方向为TXRQ
  if (this.dir == TXREQUEST)
  {
    gDebugCounterTXRQ++;
    if(gDebugCounterTXRQ==10)
    {
      writeDbgLevel(1,"DoorState TXREQUEST recieved by node %NODE_NAME% ");
      gDebugCounterTXRQ = 0;
    }
  }
  //如果方向为RX
  if (this.dir == RX)
  {
    gDebugCounterRX++;
    if(gDebugCounterRX==10)
    {
      writeDbgLevel(1,"Error: DoorState RX recieved by node %NODE_NAME% ");
      gDebugCounterRX = 0;
    }
  }
}
//处理按键'0'事件：禁止debug信息输出
On key '0'
{
  setWriteDbgLevel(0);
}
//处理按键'1'事件：开启debug信息输出
On key '1'
{
  setWriteDbgLevel(1);
}

Display节点的CAPL

Display节点接收来自Door和Engine的报文，读取报文信号，展示在面板上。

因此，Display的功能是监听报文事件。

接收到EngineState报文时，读取EngineState信号，分别展示在仪表盘和数字表上。

接收到DoorState 报文时，读取Door_L、Door_R信号，赋值给自己的环境变量，控制车门开启状态的展示。

/*@!Encoding:936*/
/*接收报文，并展示在面板上。
引擎开启状态：关联了信号EngineState::EngineStateSwitch，会自动更新
引擎速度 展示：on message EngineState
门状态展示：on message DoorState
*/
includes
{
  
}

variables
{
  
}

on message EngineState
{
  if (this.dir ==  RX)
  {
    @sysvar::Engine::EngineSpeedDspMeter = this.EngineSpeed/1000.0;
  }
}

on message DoorState
{
  if (this.dir == RX)
  {
    @EnvDoorState = this.Door_L + this.Door_R*2;
  }
}

至此，节点的程序编辑完毕。

XVehicle工程完成。可正常运行如下。（改天放图）

END