Shader（代码篇之光照模型）

最新推荐文章于 2024-06-25 16:00:24 发布

萧寒大大

最新推荐文章于 2024-06-25 16:00:24 发布

阅读量416

点赞数

分类专栏： shader 文章标签：算法 shader Powered by 金山文档

本文链接：https://blog.csdn.net/m0_46712616/article/details/129342626

版权

shader 专栏收录该内容

13 篇文章 1 订阅

订阅专栏

一.光源

Lambert(漫反射)

Shader "Shader/Custom/Lambert"
{
    Properties
    {
        
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来
            };
            // 输出结构
            struct v2f
            {
                float4 vertex : SV_POSITION;// 由模型顶点信息换算而来的顶点屏幕位置
                float3 nDirWS : TEXCOORD0; // 由模型法线信息换算来的世界空间法线信息
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.vertex = UnityObjectToClipPos(v.vertex);// 变换顶点信息 并将其塞给输出结构
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线信息 并将其塞给输出结构
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                float3 nDir = i.nDirWS;                         // 获取nDir
                float3 lDir = _WorldSpaceLightPos0.xyz;         // 获取lDir
                float nDotl = dot(nDir, lDir);              // nDir点积lDir
                float lambert = max(0.0, nDotl);                  // 截断负值
                return float4(lambert, lambert, lambert, 1.0);                                   // 输出最终颜色
            }
            ENDCG
        }
    }
}

Half-Lambert(漫反射)

Shader "Shader/Custom/HalfLambert"
{
    Properties
    {
        
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来
            };
            // 输出结构
            struct v2f
            {
                float4 vertex : SV_POSITION;// 由模型顶点信息换算而来的顶点屏幕位置
                float3 nDirWS : TEXCOORD0; // 由模型法线信息换算来的世界空间法线信息
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.vertex = UnityObjectToClipPos(v.vertex);// 变换顶点信息 并将其塞给输出结构
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线信息 并将其塞给输出结构
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                float3 nDir = i.nDirWS;                         // 获取nDir
                float3 lDir = _WorldSpaceLightPos0.xyz;         // 获取lDir
                float nDotl = dot(nDir, lDir);              // nDir点积lDir
                float halfLambert = nDotl * 0.5 + 0.5;          // 映射至0~1
                return float4(halfLambert, halfLambert, halfLambert, 1.0); // 输出最终颜色
            }
            ENDCG
        }
    }
}

Phong（镜面反射）

Shader "Shader/Custom/Phong"
{
    Properties
    {
        _SpecularPow("SpecularPow", range(1, 90)) = 30
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            uniform float _SpecularPow;  // 标量 float

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float3 nDirWS : TEXCOORD0; // 世界空间法线方向
                float4 posWS : TEXCOORD1;  // 世界空间顶点位置
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 变换顶点位置 OS>WS
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线方向 OS>WS
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                float3 nDir = normalize(i.nDirWS); //法线向量
                float3 lDir = _WorldSpaceLightPos0.xyz;//光线向量
                float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);//视野向量
                float3 rDir = reflect(-lDir, nDir); //反射向量
                float vdotr = dot(vDir, rDir);  //视野和反射点积
                float phong = pow(max(0.0, vdotr), _SpecularPow); //phong
                return float4(phong, phong, phong, 1.0);      // 输出最终颜色
            }
            ENDCG
        }
    }
}

BlinnPhong（镜面反射）

Shader "Shader/Custom/BlinnPhong"
{
    Properties
    {
        _SpecularPow("SpecularPow", range(1, 90)) = 30
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            uniform float _SpecularPow;  // 标量 float

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float3 nDirWS : TEXCOORD0; // 世界空间法线方向
                float4 posWS : TEXCOORD1;  // 世界空间顶点位置
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 变换顶点位置 OS>WS
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线方向 OS>WS
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                float3 nDir = normalize(i.nDirWS); //法线向量
                float3 lDir = _WorldSpaceLightPos0.xyz;//光线向量
                float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);//视野向量
                float3 hDir = normalize(lDir + vDir);   //半程向量
                float blinnPhong = pow(max(0.0, dot(nDir, hDir)), _SpecularPow);//blinnPhong
                return float4(blinnPhong, blinnPhong, blinnPhong, 1.0);      // 输出最终颜色
            }
            ENDCG
        }
    }
}

二.环境

TriColorAmbient（漫反射）

Shader "Shader/Custom/TriColorAmbient"
{
    Properties
    {
        _Occlusion("Occlusion", 2d) = "white" {}
        _EnvUpCol("EnvUpCol", color) = (1.0, 1.0, 1.0, 1.0)
        _EnvSideCol("EnvSideCol", color) = (0.5, 0.5, 0.5, 1.0)
        _EnvDownCol("EnvDownCol", color) = (0.0, 0.0, 0.0, 1.0)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入参数
            uniform float3 _EnvUpCol;
            uniform float3 _EnvSideCol;
            uniform float3 _EnvDownCol;
            uniform sampler2D _Occlusion;

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来
                float2 uv0 : TEXCOORD0;     // 将模型UV信息输入进来 0通道 共4通道
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float3 nDirWS : TEXCOORD0; // 世界空间法线方向
                float2 uv : TEXCOORD1;      // 追加UV信息用语像素Shader采样贴图
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS               
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线方向 OS>WS
                o.uv = v.uv0;
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                // 准备向量
               float3 nDir = i.nDirWS;                         // 获取nDir
               // 计算各部位遮罩
               float upMask = max(0.0, nDir.g);                // 获取朝上部分遮罩
               float downMask = max(0.0, -nDir.g);             // 获取朝下部分遮罩
               float sideMask = 1.0 - upMask - downMask;       // 获取侧面部分遮罩
               // 混合环境色
               float3 envCol = _EnvUpCol * upMask + _EnvSideCol * sideMask + _EnvDownCol * downMask;
               // 采样Occlusion贴图
               float occlusion = tex2D(_Occlusion, i.uv);
               // 计算环境光照
               float3 envLighting = envCol * occlusion;
               return float4(envLighting, 1.0);      // 输出最终颜色
            }
            ENDCG
        }
    }
}

Fresnel （镜面反射）

Shader "Shader/Custom/Fresnel"
{
    Properties
    {
        _FresnelPow("FresnelPow", Range(0, 10)) = 1
        
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入参数
            uniform float _FresnelPow;

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float4 normal : NORMAL;  // 将模型法线信息输入进来     
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float4 posWS : TEXCOORD0;       // 世界顶点位置
                float3 nDirWS : TEXCOORD1;      // 世界法线方向
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS               
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线方向 OS>WS
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 顶点位置 OS>WS
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz); // 视野向量

                float vdotn = dot(vDirWS, i.nDirWS);
                float fresnel = pow(max(0.0, 1.0 - vdotn), _FresnelPow);//fresnel
                return float4(fresnel, fresnel, fresnel, 1.0); // 输出最终颜色
            }
            ENDCG
        }
    }
}

MatCap（镜面反射）

Shader "Shader/Custom/MatCap"
{
    Properties
    {
        _NormalMap("NormalMap", 2D) = "bump" {}
        _Matcap("Matcap", 2D) = "gray" {}
        _FresnelPow("FresnelPow", Range(0, 10)) = 1
        _EnvSpecInt("EnvSpecInt", Range(0, 5)) = 1
        
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入参数
            uniform sampler2D _NormalMap;
            uniform sampler2D _Matcap;
            uniform float _FresnelPow;
            uniform float _EnvSpecInt;

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float2 uv0      : TEXCOORD0;    // uv信息
                float3 normal   : NORMAL;       // 法线信息
                float4 tangent  : TANGENT;      // 切线信息    
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float2 uv0 : TEXCOORD0;         // uv信息
                float4 posWS : TEXCOORD1;       // 世界顶点位置
                float3 nDirWS : TEXCOORD2;      // 世界法线方向
                float3 tDirWS : TEXCOORD3;      // 世界切线方向
                float3 bDirWS : TEXCOORD4;      // 世界副切线方向
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS               
                o.uv0 = v.uv0;                                  // 传递uv信息
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 顶点位置 OS>WS
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 法线方向 OS>WS
                o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
                o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w);  // 根据nDir tDir求bDir
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                // 准备向量
                float3 var_NormalMap = UnpackNormal(tex2D(_NormalMap, i.uv0)).rgb; // 采样法线纹理并解码 切线空间nDir
                float3x3 TBN = float3x3(i.tDirWS, i.bDirWS, i.nDirWS);
                float3 nDirWS = normalize(mul(var_NormalMap, TBN));        // 计算nDirWS 计算Fresnel
                float3 nDirVS = mul(UNITY_MATRIX_V, nDirWS);        // 计算MatcapUV
                float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz); // 计算Fresnel
                // 准备中间变量
                float vdotn = dot(vDirWS, nDirWS);
                float2 matcapUV = nDirVS.rg * 0.5 + 0.5;
                // 光照模型
                float3 matcap = tex2D(_Matcap, matcapUV);
                float fresnel = pow(max(0.0, 1.0 - vdotn), _FresnelPow);
                float3 envSpecLighting = matcap * fresnel * _EnvSpecInt;

                return float4(envSpecLighting, 1.0); // 输出最终颜色
            }
            ENDCG
        }
    }
}

CubeMap（镜面反射）

Shader "Shader/Custom/CubeMap"
{
    Properties
    {
        _Cubemap("Cubemap", Cube) = "_Skybox" {}
        _NormalMap("NormalMap", 2D) = "bump" {}
        _CubemapMip("CubemapMip", Range(0, 7)) = 0
        _FresnelPow("FresnelPow", Range(0, 5)) = 1
        _EnvSpecInt("EnvSpecInt", Range(0, 5)) = 0.2
        
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 输入参数
            uniform samplerCUBE _Cubemap;
            uniform sampler2D _NormalMap;
            uniform float _CubemapMip;
            uniform float _FresnelPow;
            uniform float _EnvSpecInt;

            // 输入结构
            struct appdata
            {
                float4 vertex : POSITION;// 将模型顶点信息输入进来
                float2 uv0      : TEXCOORD0;    // uv信息
                float3 normal   : NORMAL;       // 法线信息
                float4 tangent  : TANGENT;      // 切线信息    
            };
            // 输出结构
            struct v2f
            {
                float4 posCS : SV_POSITION;// 裁剪空间顶点位置
                float2 uv0 : TEXCOORD0;         // uv信息
                float4 posWS : TEXCOORD1;       // 世界顶点位置
                float3 nDirWS : TEXCOORD2;      // 世界法线方向
                float3 tDirWS : TEXCOORD3;      // 世界切线方向
                float3 bDirWS : TEXCOORD4;      // 世界副切线方向
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.posCS = UnityObjectToClipPos(v.vertex);     // 变换顶点位置 OS>CS               
                o.uv0 = v.uv0;                                  // 传递uv信息
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 顶点位置 OS>WS
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 法线方向 OS>WS
                o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
                o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w);  // 根据nDir tDir求bDir
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                // 准备向量
                float3 var_NormalMap = UnpackNormal(tex2D(_NormalMap, i.uv0)).rgb; // 采样法线纹理并解码 切线空间nDir
                float3x3 TBN = float3x3(i.tDirWS, i.bDirWS, i.nDirWS);
                float3 nDirWS = normalize(mul(var_NormalMap, TBN));        // 计算nDirWS 计算Fresnel
                float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz); // 计算Fresnel
                float3 vrDirWS = reflect(-vDirWS, nDirWS);// 采样Cubemap
                // 准备中间变量
                float vdotn = dot(vDirWS, nDirWS);
                
                // 光照模型
                float3 var_Cubemap = texCUBElod(_Cubemap, float4(vrDirWS, _CubemapMip)).rgb;
                float fresnel = pow(max(0.0, 1.0 - vdotn), _FresnelPow);
                float3 envSpecLighting = var_Cubemap * fresnel * _EnvSpecInt;

                return float4(envSpecLighting, 1.0); // 输出最终颜色
            }
            ENDCG
        }
    }
}

三.传统光照模型实践

Shader "Shader/Custom/OldSchool"
{
    Properties
    {
         [Header(Texture)]
            _MainTex("RGB:基础颜色 A:环境遮罩", 2D) = "white" {}
            _NormTex("RGB:法线贴图", 2D) = "bump" {}
            _SpecTex("RGB:高光颜色 A:高光次幂", 2D) = "gray" {}
            _EmitTex("RGB:环境贴图", 2d) = "black" {}
            _Cubemap("RGB:环境贴图", cube) = "_Skybox" {}
        [Header(Diffuse)]
            _MainCol("基本色",      Color) = (0.5, 0.5, 0.5, 1.0)
            _EnvDiffInt("环境漫反射强度",  Range(0, 1)) = 0.2
            _EnvUpCol("环境天顶颜色", Color) = (1.0, 1.0, 1.0, 1.0)
            _EnvSideCol("环境水平颜色", Color) = (0.5, 0.5, 0.5, 1.0)
            _EnvDownCol("环境地表颜色", Color) = (0.0, 0.0, 0.0, 0.0)
        [Header(Specular)]
            _SpecPow("高光次幂",    Range(1, 90)) = 30
            _EnvSpecInt("环境镜面反射强度", Range(0, 5)) = 0.2
            _FresnelPow("菲涅尔次幂", Range(0, 5)) = 1
            _CubemapMip("环境球Mip", Range(0, 7)) = 0
        [Header(Emission)]
            _EmitInt("自发光强度", range(1, 10)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            // 追加投影相关包含文件
            #include "AutoLight.cginc"
            #include "Lighting.cginc"
            // 输入结构
            // Texture
            uniform sampler2D _MainTex;
            uniform sampler2D _NormTex;
            uniform sampler2D _SpecTex;
            uniform sampler2D _EmitTex;
            uniform samplerCUBE _Cubemap;
            // Diffuse
            uniform float3 _MainCol;
            uniform float _EnvDiffInt;
            uniform float3 _EnvUpCol;
            uniform float3 _EnvSideCol;
            uniform float3 _EnvDownCol;
            // Specular
            uniform float _SpecPow;
            uniform float _FresnelPow;
            uniform float _EnvSpecInt;
            uniform float _CubemapMip;
            // Emission
            uniform float _EmitInt;
            struct appdata
            {
                float4 vertex   : POSITION;   // 顶点信息
                float2 uv0      : TEXCOORD0;  // UV信息
                float4 normal   : NORMAL;     // 法线信息
                float4 tangent  : TANGENT;    // 切线信息
            };
            // 输出结构
            struct v2f
            {
                float4 pos    : SV_POSITION;  // 屏幕顶点位置
                float2 uv0      : TEXCOORD0;  // UV0
                float4 posWS    : TEXCOORD1;  // 世界空间顶点位置
                float3 nDirWS   : TEXCOORD2;  // 世界空间法线方向
                float3 tDirWS   : TEXCOORD3;  // 世界空间切线方向
                float3 bDirWS   : TEXCOORD4;  // 世界空间副切线方向
                LIGHTING_COORDS(5, 6)          // 投影相关
            };
            // 输入结构>>>顶点Shader>>>输出结构
            v2f vert (appdata v)
            {
                v2f o;// 新建一个输出结构
                o.pos = UnityObjectToClipPos(v.vertex);       // 顶点位置 OS>CS
                o.uv0 = v.uv0;                                  // 传递UV
                o.posWS = mul(unity_ObjectToWorld, v.vertex);   // 顶点位置 OS>WS
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 法线方向 OS>WS
                o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
                o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w);  // 副切线方向
                TRANSFER_VERTEX_TO_FRAGMENT(o)                  // 投影相关
                return o;
            }
            // 输出结构>>>像素
            fixed4 frag (v2f i) : SV_Target
            {
                // 准备向量
                float3 var_NormalMap = UnpackNormal(tex2D(_NormTex, i.uv0)).rgb;//解包法线贴图
                float3x3 TBN = float3x3(i.tDirWS, i.bDirWS, i.nDirWS); //TBN矩阵
                float3 nDirWS = normalize(mul(var_NormalMap, TBN));//法线世界坐标
                float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);//视野世界坐标
                float3 vrDirWS = reflect(-vDirWS, nDirWS);//Cubemap使用
                float3 lDirWS = _WorldSpaceLightPos0.xyz;//光世界坐标
                float3 lrDirWS = reflect(-lDirWS, nDirWS);//反射世界坐标

                // 准备点积结果
                float ndotl = dot(nDirWS, lDirWS);//lambert使用
                float vdotr = dot(vDirWS, lrDirWS);//phong使用
                float vdotn = dot(vDirWS, nDirWS);//fresnel使用

                // 采样纹理
                float4 var_MainTex = tex2D(_MainTex, i.uv0);
                float4 var_SpecTex = tex2D(_SpecTex, i.uv0);
                float3 var_EmitTex = tex2D(_EmitTex, i.uv0).rgb;
                float3 var_Cubemap = texCUBElod(_Cubemap, float4(vrDirWS, lerp(_CubemapMip, 0.0, var_SpecTex.a))).rgb;

                // 光照模型(直接光照部分)
                float3 baseCol = var_MainTex.rgb * _MainCol;
                float lambert = max(0.0, ndotl);

                float specCol = var_SpecTex.rgb;
                float specPow = lerp(1, _SpecPow, var_SpecTex.a);
                float phong = pow(max(0.0, vdotr), specPow);

                float shadow = LIGHT_ATTENUATION(i);

                float3 dirLighting = (baseCol * lambert + specCol * phong) * _LightColor0 * shadow;

                // 光照模型(环境光照部分)
                float upMask = max(0.0, nDirWS.g);          // 获取朝上部分遮罩
                float downMask = max(0.0, -nDirWS.g);       // 获取朝下部分遮罩
                float sideMask = 1.0 - upMask - downMask;   // 获取侧面部分遮罩
                float3 envCol = _EnvUpCol * upMask +
                                _EnvSideCol * sideMask +
                                _EnvDownCol * downMask;     // 混合环境色

                float fresnel = pow(max(0.0, 1.0 - vdotn), _FresnelPow);    // 菲涅尔

                float occlusion = var_MainTex.a;

                float3 envLighting = (baseCol * envCol * _EnvDiffInt + var_Cubemap * fresnel * _EnvSpecInt * var_SpecTex.a) * occlusion;

                // 光照模型(自发光部分)
                float emitInt = _EmitInt * (sin(frac(_Time.z)) * 0.5 + 0.5);
                float3 emission = var_EmitTex * emitInt;

                // 返回结果
                float3 finalRGB = dirLighting + envLighting + emission;
                return float4(finalRGB, 1.0);                                // 输出最终颜色
            }
            ENDCG
        }
    }
}