Surface Shader Examples 详解

最新推荐文章于 2024-06-26 13:41:08 发布
最新推荐文章于 2024-06-26 13:41:08 发布
阅读量1.9k 收藏 3
点赞数 5
分类专栏： Unity 文章标签： Unity Shader surface shader 表面着色器 定点着色器

Surface Shader Examples

这里是几个 Surface Shaders的例子. 例子主要使用内置照明模型; 讲解如何实现基于 Surface Shader Lighting.的自定义光照模型.

入门

我们将从一个非常简单的着色器开始。这里有一个把表面颜色设置为“白色”的shader。它使用了unity内置的Lambert (diffuse)照明模型。

  Shader "Example/Diffuse Simple" {
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float4 color : COLOR;
      };
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = 1;
      }
      ENDCG
    }
    Fallback "Diffuse"
  }

它看起来像一个模型有两个lights设置

纯贴图

一个白人对象很无聊,让我们添加一个纹理。我们将添加一个 Properties block（属性块）材质,它是一个的材质选择器。其他的变化以粗体显示如下。

  Shader "Example/Diffuse Texture" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

法显贴图

让我们再添加一个法显贴图

  Shader "Example/Diffuse Bump" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
        o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
        o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

边缘光照

现在,尝试添加一些Rim Lighting（边缘照明）来加强对象的边缘。我们将添加一些基于曲面法线夹角和视图方向的emissive light（放射光）。为此,我们还将使用unity内置表面着色器变量viewDir。

  Shader "Example/Rim" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _RimColor ("Rim Color", Color) = (0.26,0.19,0.16,0.0)
      _RimPower ("Rim Power", Range(0.5,8.0)) = 3.0
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 viewDir;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      float4 _RimColor;
      float _RimPower;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          half rim = 1.0 - saturate(dot (normalize(IN.viewDir), o.Normal));
          o.Emission = _RimColor.rgb * pow (rim, _RimPower);
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

细节纹理

为了实现不同的效果,让我们添加一个结合基础纹理的细节纹理。细节纹理使用相同的UV,但通常不同的材料,所以我们必须使用不同的UV坐标。

  Shader "Example/Detail" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float2 uv_Detail;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= tex2D (_Detail, IN.uv_Detail).rgb * 2;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

使用一个格子纹理没有多少实际意义,但能清楚的说明发生了什么:

屏幕空间细节纹理

下面是一个细节纹理在屏幕空间，它虽然也没有多大意义,但清晰的说明了如何使用一个内置screenPos输入:

  Shader "Example/ScreenPos" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float4 screenPos;
      };
      sampler2D _MainTex;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          float2 screenUV = IN.screenPos.xy / IN.screenPos.w;
          screenUV *= float2(8,6);
          o.Albedo *= tex2D (_Detail, screenUV).rgb * 2;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

法线贴图已经被移除:

反射贴图

这是一个使用unity内置worldRefl输入的shader。效果非常类似于unity内置的反射/漫反射shader:

  Shader "Example/WorldRefl" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float3 worldRefl;
      };
      sampler2D _MainTex;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Emission = texCUBE (_Cube, IN.worldRefl).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

使用了反射颜色后,我们得到了一个非常闪亮的士兵:

如果你想做受法线贴图影响的反射,需要稍微涉及:INTERNAL_DATA，它需要被添加到输入结构,并且在你的输出中使用WorldReflectionVector函数计算单像素反射向量。

  Shader "Example/WorldRefl Normalmap" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldRefl;
          INTERNAL_DATA
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          o.Emission = texCUBE (_Cube, WorldReflectionVector (IN, o.Normal)).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

这是一个受法线贴图映射的士兵。

片状剪切

这里有一个shader,对象被“片状”水平环剪切。它通过基于世界一个像素的位置使用clip()方法（Cg / HLSL函数）来实现。我们使用了unity内置表面着色器变量worldPos。

  Shader "Example/Slices" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      Cull Off
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldPos;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
          clip (frac((IN.worldPos.y+IN.worldPos.z*0.1) * 5) - 0.5);
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

顶点修改器

可以使用“顶点修改器”功能,将修改输入顶点的着色器中的数据。这可以用于过程性动画,沿法线挤压动画等等。表面着色器使用带inout,appdata_full 参数的（vertex:函数名)来编译指令顶点。


下面就是一个沿着指定法线贴图的顶点移动的shader。

  Shader "Example/Normal Extrusion" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Amount ("Extrusion Amount", Range(-1,1)) = 0.5
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
      };
      float _Amount;
      void vert (inout appdata_full v) {
          v.vertex.xyz += v.normal * _Amount;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

沿着法线贴图顶点移动 生成了一个肥胖的士兵。

单顶点自定义数据

顶点着色器也可以使用顶点修饰符函数计算定制数据,然后再传递到表面着色器函数中的单像素。使用相同的编译指令顶点函数，但是函数（vertex:函数名)需要两个参数:inout appdata_full和out Input。你可以自定义Input因为它不是系统内置属性。

注意:这种自定义输入成员的方式不能使用uv作为名字开头。

下面的例子在顶点计算功能中定义了一个定制float3 customColor成员。

  Shader "Example/Custom Vertex Data" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
          float3 customColor;
      };
      void vert (inout appdata_full v, out Input o) {
          UNITY_INITIALIZE_OUTPUT(Input,o);
          o.customColor = abs(v.normal);
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= IN.customColor;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

在这个例子中customColor设置为法线贴图的绝对值:

更实际的用途可以计算任何没有提供内置的输入变量的“单顶点数据”，优化shader计算。例如,它可以计算边缘照明的对象的顶点,而不是处理表面材质的单像素。

最终颜色修改

可以使用一个“最终颜色修改器”功能,来修改着色器最终颜色。用于表面着色器编译指令需要函数（finalcolor:函数名）,并需要参数Input IN,SurfaceOutput o,inout fixed4 color 参数。

下面是一个简单应用于最终颜色的的shader。这与色彩应用到表面反照率不同颜色:这个色彩也会受任何来自光照贴图,光探测器和类似的来源的影响。

  Shader "Example/Tint Final Color" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _ColorTint ("Tint", Color) = (1.0, 0.6, 0.6, 1.0)
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert finalcolor:mycolor
      struct Input {
          float2 uv_MainTex;
      };
      fixed4 _ColorTint;
      void mycolor (Input IN, SurfaceOutput o, inout fixed4 color)
      {
          color *= _ColorTint;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

最终颜色修改器自定义雾化效果

常见的用例最终颜色修饰符(见上图)将实现完全定制的雾。雾需要影响着色器最终计算像素的颜色,这是finalcolor修改器。

还有一个shader适用于基于距离屏幕中心的雾色。它结合顶点修饰符使用自定义顶点数据(雾)和最终的颜色修饰符。在前向渲染通道使用时,雾会消失在黑暗的颜色,如果你检测一下UNITY_PASS_FORWARDADD的话，这个示例会做的更好。

  Shader "Example/Fog via Final Color" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _FogColor ("Fog Color", Color) = (0.3, 0.4, 0.7, 1.0)
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert finalcolor:mycolor vertex:myvert
      struct Input {
          float2 uv_MainTex;
          half fog;
      };
      void myvert (inout appdata_full v, out Input data)
      {
          UNITY_INITIALIZE_OUTPUT(Input,data);
          float4 hpos = mul (UNITY_MATRIX_MVP, v.vertex);
          data.fog = min (1, dot (hpos.xy, hpos.xy) * 0.1);
      }
      fixed4 _FogColor;
      void mycolor (Input IN, SurfaceOutput o, inout fixed4 color)
      {
          fixed3 fogColor = _FogColor.rgb;
          #ifdef UNITY_PASS_FORWARDADD
          fogColor = 0;
          #endif
          color.rgb = lerp (color.rgb, fogColor, IN.fog);
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

线性雾化

Shader "Example/Linear Fog" {
  Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
  }
  SubShader {
    Tags { "RenderType"="Opaque" }
    LOD 200
    
    CGPROGRAM
    #pragma surface surf Lambert finalcolor:mycolor vertex:myvert

    sampler2D _MainTex;
    uniform half4 unity_FogColor;
    uniform half4 unity_FogStart;
    uniform half4 unity_FogEnd;

    struct Input {
      float2 uv_MainTex;
      half fog;
    };

    void myvert (inout appdata_full v, out Input data) {
      UNITY_INITIALIZE_OUTPUT(Input,data);
      float pos = length(mul (UNITY_MATRIX_MV, v.vertex).xyz);
      float diff = unity_FogEnd.x - unity_FogStart.x;
      float invDiff = 1.0f / diff;
      data.fog = clamp ((unity_FogEnd.x - pos) * invDiff, 0.0, 1.0);
    }
    void mycolor (Input IN, SurfaceOutput o, inout fixed4 color) {
      fixed3 fogColor = unity_FogColor.rgb;
      #ifdef UNITY_PASS_FORWARDADD
      fogColor = 0;
      #endif
      color.rgb = lerp (fogColor, color.rgb, IN.fog);
    }

    void surf (Input IN, inout SurfaceOutput o) {
      half4 c = tex2D (_MainTex, IN.uv_MainTex);
      o.Albedo = c.rgb;
      o.Alpha = c.a;
    }
    ENDCG
  } 
  FallBack "Diffuse"
}
TxNet.Ltd.
关注
专栏目录
Surface Shader examples 表面着色器示例 - Unity Shader Reference 系列3
cangod的博客
10-16 271
Surface Shader examples 表面着色器示例 本文档主要是对Unity官方手册的个人理解与总结（其实以翻译记录为主：>） 仅作为个人学习使用，不得作为商业用途，欢迎转载，并请注明出处。 文章中涉及到的操作都是基于Unity2018.2版本 参考链接：https://docs.unity3d.com/Manual/SL-SurfaceShaderExamples.html T...
Shader 笔记一 表面着色器 Surface Shader
王王王渣渣的博客
04-15 2082
参考 猫都能学会的Unity3D Shader入门指南（一） 猫都能学会的Unity3D Shader入门指南（二） https://docs.unity3d.com/Manual/SL-SurfaceShaders.html 概念 Shader和Material： Shader（着色器）实际上就是一小段程序，它负责将输入的Mesh（网格）以指定的方式和输入的贴图或者颜色等组合作...
Unity Shader - Surface Shader examples 表面着色器的例子
Jave.Lin 的学习笔记
06-13 405
目录：Unity Shader - 知识点目录（先占位，后续持续更新） 原文：Surface Shader examples 版本：2019.1 Surface Shader examples 表面着色器的例子 在此页面的Surface Shaders的例子，都将向你展示如果使用内置的光照模型。例如，如何实现自定义的光照模型，查看Surface Shader Lighting Examples。 ...
【知识学习】Unity3D——Surface Shader&lightning的概念及使用方法示例
最新发布
Richard_shen的博客
06-26 914
Unity3D是一个广泛使用的跨平台游戏引擎，它提供了强大的图形渲染功能。在Unity中，Shader是用于控制图形渲染过程的程序，它们运行在GPU上，用于计算屏幕上每个像素的颜色。Surface Shader和Lighting是Unity Shader编程中非常重要的概念。
表面着色器示例 Surface Shader Examples
ZON
08-12 2452
Here are some examples of Surface Shaders. The examples below focus on using built-in lighting models; examples on how to implement custom lighting models are in Surface Shader Lighting Examples.
Shader编程学习笔记（七）—— Surface Shader 1
weixin_30878501的博客
05-23 152
Surface Shader 　　本小结对Unity的Surface Shader做一个大概的了解。主要了解在Surface Shader当中比较重要的几个部分，分别是: SurfaceOutput Input lighing shadow 　　首先查看一下Unity的官方手册中的Writing Surface Shaders，其中描述道：如果要编写一个shader去和光进行交...
Surface Shader
Potter：I am not for learning and learning, but for study and work
03-23 1175
SurfaceOutput: input: lighting:光照 shadow：阴影 属性声明类型对应关系： Simpler2D-2D half-Rang fixed4-4元向量Tags {“RenderType”=”Opaque”} 描述一种渲染类型,Opaque：不透明的物体 LOD 200 ：层级细节CGPROGRAM 开始 ENDCG 结束
Unity Shader - Vertex and fragment shader examples 顶点和片段着色器的例子-附件资源
03-05
Unity Shader - Vertex and fragment shader examples 顶点和片段着色器的例子-附件资源
Surface Shader（可编程渲染管线 表面着色器）
Champion_Lee的专栏
01-28 4212
1、Unity 3d官方文档上对WorldNormalVector的解释 float3 worldNormal； INTERNAL_DATA -will contain world normal vector if surface shader writes to o.Normal. Toget the normal vector based on per-pixel normal map, u
Unity Surface Shader 示例分析
清道夫的专栏（3D程序员，炼心，终生编程）
01-31 3217
对于Unity中的表面着色器（Surface Shader），它的代码整体结构如下所示：      Shader "name" {          Properties {               // 第一部分          }          SubShader {               // 第二部分          }
Surface Shader
Young的博客
03-01 726
surface shader是一种对vertex and fragment shader的一种包装，不能加pass通道，加pass会编译报错 #pragma  surface  surf  standard  fullforwardshadows pragma ：表示是一条编译指令 surface ：表示这个Shader是一个表面着色器 surf ：函数名，在之后的代码块中
【Unity3D Shader编程】之六 暗黑城堡篇: 表面着色器(Surface Shader)的写法(一)
热门推荐
【浅墨的游戏编程Blog】毛星云（浅墨）的专栏
12-28 4万+
本文主要讲解了Unity中SurfaceShader的具体写法，以及几个常用的CG函数的用法。 在这里先说明一下，表面着色器将分为两次讲解，本文介绍表面着色器的基本概念和一些写法，用内置的兰伯特光照模式来进行Surface Shader的书写，而下次将介绍Surface Shader+自定义的光照模式的写法。 PS：最近几天，在完美世界、腾讯互娱工作多年的几个朋友们问了浅墨一些表面着色器相关的Shader写法，浅墨当时回答他们的时候自己也是似懂非懂。通过这篇文章的书写，现在算是对这方面知识有了进一步的理
SurfaceShader
hqyellows的博客
08-15 231
表面shader：是unity自己封装处理的shader；    unity封装了一些光照模型，可以直接使用； Surface Shader:   1，没有pass通道，系统自动生成；   2，SubShader { Tags { "RenderType"="Opaque" "Queue"="Transparent"} LOD 200  层次细节 CGPROGRAM //
SHADER学习笔记（一）：Surface Shader
真像大白阿的博客
05-30 1360
Surface Shader是Unity为了方便shader编写提供的特殊功能，它对底层的vertex/fragment shader做了封装，省去了一些重复代码编写的工作量。我的理解是它同时具有vertex/fragment shader的功能，只是写法上更加简洁，更容易上手。 Unity的官方manual上就提供了几个最好的学习例子，我在学习的过程中加上了注释。 简单的漫反射（SIMPLE） Shader "Example/Diffuse Simple" { SubShad.
Unity Shader 表面着色器(Surface Shader)
jk823394954的专栏
10-06 9783
Unity Shader分为表面着色器(Surface Shader)，顶点着色器(Vertex Shader),片段着色器(Fragment Shader) 我们先来看个简单的Surface Shader，看看它都能做什么。 首先我们通过"Create->3D Object ->Plane"创建一个面板 然后通过"Create->Shader->Standard Surface S
7.Surface Shaders
小感悟
07-21 269
描述一种光学现象，当光线照射到物体表面，一部分反射，一部分进入物体内部发生折射或散射。生活中的例子，就是你在湖上，看到脚下的水是透明的可以看到水下，远处的水却波光粼粼看不到水下。几乎所有物体都有这样的菲涅尔效果。在实时渲染中常用来根据视角方向控制反射程度。真实世界的菲涅尔反射公式比较复杂，这里有两个应用比较著名的近似公式。Schlick菲涅尔公式Fschlick(v,n)=F0+(1−F0(1−v⋅n)5Fschlick​。...
Pyfvcom表面示例 - pyfvcom_surface_example
CHEN_BR/BLOG
06-01 553
%matplotlib inline import numpy as np import matplotlib.pyplot as plt from cmocean import cm from mpl_toolkits.basemap import Basemap from mpl_toolkits.axes_grid1 import make_axes_locatable from PyFVCOM.read import ncread # Load the model output. fvcom
Shader基础：5、表面着色器Surface Shader
真像大白阿的博客
05-30 543
表面着色器是通过Unity给我们制定好的一套标准，计算出需要填充输入什么，输出什么等相关信息，并产生真实的顶点(vertex)&像素(pixel)着色器，以及把渲染路径传递到正向或延时渲染路径。 输出结构 struct SurfaceOutput { half3 Albedo; //反射率，也就是纹理颜色值（r,g,b) half3 Normal; //法线，法向量(x, y, z) half3 Em...
Unity Shader——Writing Surface Shaders(0)
weixin_30651273的博客
05-12 99
　　从今天起，开始翻译Unity关于shader的官方文档。翻译水平比较一般，目的主要是通过翻译来提升对shader的见解，也让其他人更容易的了解shader。以下开始正文内容： 编写Surface Shaders 　　和光交互的shader写起来很复杂，有不同的光照类型、阴影选项、渲染路径（正向渲染和延迟渲染），有时shader需要考虑所有的复杂性。 　　Unity中的Surface...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值