凹凸映射

本文借鉴《Unity Shader入门精要》，算是对自己学习的总结，也希望分享下所学知识~~

**凹凸映射：**使用一张纹理来修改模型表面的法线，以便为模型提供更多的细节。

实现方法：
1.高度纹理：模拟表面位移，得到一个修改后的法线值，成为高度映射。
通过黑度值，越白越高。
（基本不用。因为计算复杂，需要通过灰度值计算表面法线，消耗更多的性能。）

2.法线纹理：
法线方向的分量范围在 [-1, 1]，像素的分量范围为 [0, 1]。
需要做一个映射：

法线值 = 像素值 * 2 + 1

在实际中，都使用模型顶点的 切线空间 来存储法线。
对于每个顶点，都有属于自己的切线空间，这个切线空间就是该顶点本身。
z 轴就是法线方向，x 轴是顶点的切线方向，y 轴则是副切线（通过叉乘得到）。

大部分的法线都是和模型本身一致的，也是是（0,0,1），经过映射后变成（0.5,0.5,1）。
也就是切线空间下的法线纹理看起来为什么是浅蓝色的原因。

1.在切线空间计算的代码如下：

Shader "NormalMapTangentSpace"
{
	Properties
	{
		_Color ("Color Tint", Color) = (1,1,1,1)
		_MainTex ("Texture", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump"{}//bump 是Unity内置的法线纹理 当没有提供任何法线信息时 bump就对应了模型自带的法线信息
		_BumpScale ("Bump Scale", Float) = 1.0//控制凹凸程度
		_Specular ("Specular", Color) = (1,1,1,1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
	
	SubShader
	{
		Tags { "LightMode" = "ForwardBase" }

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			struct v2f
			{
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float3 lightDir : TEXCOORD1;
				float3 viewDir : TEXCOORD2;
			};

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;
			fixed4 _Specular;
			float _Gloss;
			
			v2f vert (appdata_tan v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);

				//使用了两张纹理，通常情况下会使用同一组纹理坐标
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				//叉乘得到了切线空间的 bitnormal 向量
				//float3 bitnormal = cross( normalize(v.normal), normalize(v.tangent.xyz) );
				//float3x3类型有接受三个三维行向量的构造函数，以利用三个行向量获得一个3x3矩阵。
				//得到从切线空间到世界空间的变换矩阵
				//float3x3 rotation = float3x3( v.trangent.xyz, binormal, v.normal );
				TANGENT_SPACE_ROTATION;//内置宏 等于上述代码

				//在顶点着色器中计算切线空间下的光照和视角方向
				o.lightDir = mul(rotation, ObjSpaceLightDir( v.vertex )).xyz;
				o.viewDir = mul(rotation, ObjSpaceViewDir( v.vertex )).xyz;

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 tangentLightDir = normalize( i.lightDir );
				fixed3 tangentViewDir = normalize( i.viewDir );

				fixed4 packedNormal = tex2D( _BumpMap, i.uv.zw );//对法线纹理进行采样
				fixed3 tangentNormal = UnpackNormal( packedNormal );//内置函数：纹理类型标识Normal map后，得到正确的法线
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt( 1.0 - saturate( dot(tangentNormal.xy, tangentNormal.xy) ) );//单位向量已知xy求z

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 albedo = tex2D( _MainTex, i.uv ).rgb * _Color.rgb;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
				fixed3 halfDir = normalize( tangentLightDir + tangentViewDir );
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow( max(0, dot(tangentNormal, halfDir)), _Gloss);

				return fixed4(ambient+diffuse+specular, 1.0);
			}
			ENDCG
		}
	}
}

2.在世界空间计算的代码如下：

Shader "zhangjx/_10012NormalMapWorldSpace"
{
	Properties
	{
		_Color ("Color Tint", Color) = (1,1,1,1)
		_MainTex ("Texture", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump"{}
		_BumpScale ("Bump Scale", Float) = 1.0
		_Specular ("Specular", Color) = (1,1,1,1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
	
	SubShader
	{
		Tags { "LightMode" = "ForwardBase" }

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			struct v2f
			{
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;

				float4 TtiW0 : TEXCOORD1;
				float4 TtiW1 : TEXCOORD2;
				float4 TtiW2 : TEXCOORD3;
			};

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;
			fixed4 _Specular;
			float _Gloss;
			
			v2f vert (appdata_tan v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);

				o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

				float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
				fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
				fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;

				//充分利用存储空间，使用w分量存储世界空间下顶点坐标
				//在顶点着色器中计算从切线空间到世界空间的变换矩阵，并把它传递给片元着色器
				o.TtiW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);//TBN 切线空间
				o.TtiW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);//TBN 切线空间
				o.TtiW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);//TBN 切线空间

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				float3 worldPos = float3(i.TtiW0.w, i.TtiW1.w, i.TtiW2.w);

				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));

				fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
				bump.xy *= _BumpScale;
				bump.z = sqrt( 1.0 - saturate( dot(bump.xy, bump.xy) ) );//单位向量已知xy求z
				fixed3 worldNormal = normalize( fixed3(dot(i.TtiW0.xyz, bump), dot(i.TtiW1.xyz, bump), dot(i.TtiW2.xyz, bump)) );

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 albedo = tex2D( _MainTex, i.uv ).rgb * _Color.rgb;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				fixed3 halfDir = normalize( worldLightDir + worldViewDir );
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow( max(0, dot(worldNormal, halfDir)), _Gloss);

				return fixed4(ambient + diffuse + specular, 1.0);
			}
			ENDCG
		}
	}
}