ROS CmakeLists.txt解读

        CMakeLists.txt原本是Cmake编译系统的规则文件，而Catkin编译系统基本沿用了CMake的编译风格，只是针对ROS工程添加了一些宏定义。所以在写法上，catkin的CMakeLists.txt与CMake的基本一致。
        该文件规定了这个package要依赖哪些package，要编译生成哪些目标，如何编译等等流程，它指定了由源码到目标文件的规则，catkin编译系统在工作时首先会找到每个package下的CMakeLists.txt，然后按照规则来编译构建。

cmake和catkin_make区别：

        简单来讲就是catkin_make是cmake的高级封装

        cmake只能编译指定的package，但是不同package之间的关系没办法链接，而且cmake只能编译C++。而catkin_make不仅仅可以编译C++还支持python，在编译使用的时候，支持包与包之间的链接。
（1）程序在cmake编译是这样的流程, cmake指令依据你的CMakeLists.txt 文件,生成makefiles文件，make再依据此makefiles文件编译链接生成可执行文件.
（2）catkin_make是将cmake与make的编译方式做了一个封装的指令工具, 规范了工作路径与生成文件路径。

cmake_minimum_required()	#CMake版本号
project()					#项目名称，包名
find_package()				#找到编译需要的其他CMake/Catkin package，如roscpp,std_msgs...
catkin_python_setup()		#catkin新加宏，打开catkin的Python Module的支持
add_message_files()			#catkin新加宏，添加自定义Message/Service/Action文件
add_service_files()
add_action_files()
generate_message()			#catkin新加宏，生成不同语言版本的msg/srv/action接口
catkin_package()			#catkin新加宏，生成当前package的cmake配置，供依赖本包的其他软件包调用
add_library()				#生成库
add_executable()			#生成可执行二进制文件
add_dependencies()			#定义目标文件依赖于其他目标文件，确保其他目标已被构建
target_link_libraries()		#链接
catkin_add_gtest()			#catkin新加宏，生成测试
install()					#安装至本机

        turtlesim的CMakeLists.txt的写法如下：

cmake_minimum_required(VERSION 2.8.3)   		#CMake至少为2.8.3版
project(turtlesim)								#项目(package)名称为turtlesim，在后续文件中可使用变量${PROJECT_NAME}来引用项目名称turltesim
find_package(catkin REQUIRED COMPONENTS geometry_msgs message_generation rosconsole roscpp roscpp_serialization roslib rostime std_msgs std_srvs)	
												#cmake宏，指定依赖的其他pacakge，实际是生成了一些环境变量，如<NAME>_FOUND, <NAME>_INCLUDE_DIRS, <NAME>_LIBRARYIS
												#此处catkin是必备依赖，其余的如geometry_msgs，message_generation等为被依赖组件，定义这些package是关于catkin所依赖的package，注意：是关于catkin。
												#REQUIRED为可选字段。表示一定要找到包，找不到的话就立即停掉整个cmake
												#COMPONENTS 为可选字段，表示查找的包中必须要找到的组件(components），如果有任何一个找不到就算失败，类似于REQUIRED，导致cmake停止执行

find_package(Qt5Widgets REQUIRED)				#Qt Widgets模块提供了一组UI元素来创建经典的桌面风格的用户界面。  
find_package(Boost REQUIRED COMPONENTS thread)

include_directories(include ${catkin_INCLUDE_DIRS} ${Boost_INCLUDE_DIRS})		#指定C++的头文件路径

link_directories(${catkin_LIBRARY_DIRS})										#指定链接库的路径

#引入自定义msg文件 DIRECTORY为目录msg，FILES 文件为Color.mgs和Pose.msg
add_message_files(DIRECTORY msg FILES
					  Color.msg
					   Pose.msg)

#引入自定义srv文件
add_service_files(DIRECTORY srv FILES
					   Kill.srv
					 SetPen.srv
					  Spawn.srv
		   TeleportAbsolute.srv
		   TeleportRelative.srv)

generate_messages(DEPENDENCIES geometry_msgs std_msgs std_srvs)
#在add_message_files、add_service_files宏之后必须加上这句话，用于生成srv，msg头文件，生成的文件位于devel/include文件夹中

catkin_package(CATKIN_DEPENDS geometry_msgs message_runtime std_msgs std_srvs)
# 声明依赖于此包的包的依赖关系，意思是当别的包想依赖此包时，不仅需要当前包，还需要依赖catkin_package定义的包。注意:catkin_package与find_package正好相反，前者是把依赖项声明出去，而后者是声明进来
# catkin宏命令，用于配置ROS的package配置文件和CMake文件，这个命令必须在add_library()或者add_executable()之前调用，该函数有5个可选参数：
# (1) INCLUDE_DIRS 		- 导出包的include路径
# (2) LIBRARIES 		- 导出项目中的库
# (3) CATKIN_DEPENDS 	- 该项目依赖的其他catkin项目
# (4) DEPENDS 			- 该项目所依赖的非catkin CMake项目 / 该项目依赖的其它功能包
# (5) CFG_EXTRAS 		- 其他配置选项

set(turtlesim_node_SRCS src/turtlesim.cpp src/turtle.cpp src/turtle_frame.cpp)
set(turtlesim_node_HDRS include/turtlesim/turtle_frame.h)
#指定turtlesim_node_SRCS、turtlesim_node_HDRS变量  定义CmakeLists的内部变量，turtlesim_node_SRCS可以被后面引用，方式是${turtlesim_node_SRCS}

qt5_wrap_cpp(turtlesim_node_MOCS ${turtlesim_node_HDRS})

add_executable(turtlesim_node ${turtlesim_node_SRCS} ${turtlesim_node_MOCS})
# 指定可执行文件目标turtlesim_node  它的作用是添加一个可执行文件构建目标，这里面引用了set标签设置的内部变量，实际上也可以直接写链接地址src/turtlesim.cpp ...

target_link_libraries(turtlesim_node Qt5::Widgets ${catkin_LIBRARIES} ${Boost_LIBRARIES})
# 指定链接可执行文件  该指令的作用为将目标文件与库文件进行链接，保证当前目标文件可以访问到库，与add_executable连用，并且必须在其后。

add_dependencies(turtlesim_node turtlesim_gencpp)
# 对于编译时遇到的依赖问题，很多时候我们只需要一句target_link_libraries就可以搞定。一般来说用不到。用到的情况就是两个targets有依赖关系
#（通过target_link_libraries解决）并且依赖库也是通过编译源码产生的。这时候一句add_dependencies可以在直接编译上层target时，自动检查下层
# 依赖库是否已经生成。没有的话先编译下层依赖库，然后再编译上层target，最后link depend target。

add_executable(turtle_teleop_key tutorials/teleop_turtle_key.cpp)
target_link_libraries(turtle_teleop_key ${catkin_LIBRARIES})
add_dependencies(turtle_teleop_key turtlesim_gencpp)

add_executable(draw_square tutorials/draw_square.cpp)
target_link_libraries(draw_square ${catkin_LIBRARIES} ${Boost_LIBRARIES})
add_dependencies(draw_square turtlesim_gencpp)

add_executable(mimic tutorials/mimic.cpp)
target_link_libraries(mimic ${catkin_LIBRARIES})
add_dependencies(mimic turtlesim_gencpp)
# 同样指定可执行目标、链接、依赖

install(TARGETS turtlesim_node turtle_teleop_key draw_square mimic RUNTIME DESTINATION ${CATKIN_PACKAGE_BIN_DESTINATION})
# 安装目标文件到本地系统/某个地址

install(DIRECTORY images DESTINATION ${CATKIN_PACKAGE_SHARE_DESTINATION} FILES_MATCHING PATTERN "*.png" PATTERN "*.svg")
# 将某个目录保存到某个地址

其他额外的语句：

1、设置编译类型为release，因为在发布时需要选择release

set(CMAKE_BUILD_TYPE "Release")

2、添加编译参数：按照C++2011或2014标准来进行编译

ADD_COMPILE_OPTIONS(-std=c++11 )
ADD_COMPILE_OPTIONS(-std=c++14 )

3、CMAKE_CXX_FLAGS为设置g++编译选项

-O3表示开始编译优化等级为3；-Wall编译后显示所有警告；-g表示调试，即可执行程序中包含调试信息

set(CMAKE_CXX_FLAGS_RELEASE "-O3 -Wall -g")

4、include_directories

设置包含的目录，当编译一个需要第三方库的项目时，为了让cmake知道在该项目中包含的外部头文件。相应文件中搜索头文件目录

include_directories( 
    SYSTEM 添加的头文件应按系统头文件处理
    include 
    ${catkin_INCLUDE_DIRS} 将引用每一个功能包的include目录的头文件
    ${Eigen3_INCLUDE_DIRS} 
    ${PCL_INCLUDE_DIRS}
)

5、add_library  制定编译包含的源文件
即制定编译的源文件为path_searching文件夹下的src目录下的dyn_a_star.cpp文件

add_library( path_searching 
    src/dyn_a_star.cpp
    )

6、动态参数配置：

generate_dynamic_reconfigure_options(cfg/DynReconf1.cfg  cfg/DynReconf2.cfg)