当我们在使用discard命令的时候模型会破面,因为discard截的是像素,截掉的地方并没有网格,是空的,所以要生成面才能组成一个封闭的模型,这里基于Unity的GeometryShader进行面的绘制。
使用两个pass,第一个pass正常discard模型,第二个pass使用GeometryShader程序绘制面补上破面
Shader "MyShader/GSTest"
{
Properties
{
_Color("MianColor",color)=(1,1,1,1)
_CullPlaneColor("MianColor",color)=(1,1,1,1)
_Value("Value",float)=0.2
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
pass{
//Cull Off 被生成的面盖住了,不需要渲染反面了
CGPROGRAM
#pragma target 4.0
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2g
{
float4 vertex : POSITION;
float4 pos:TEXCOORD0;
float3 nor:NORMAL;
};
fixed4 _LightColor0;
fixed4 _Color;
float _Value;
v2g vert(appdata_base v)
{
v2g o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.pos=v.vertex;
o.nor=v.normal;
return o;
}
fixed4 frag (v2g i) : SV_Target
{
if(i.pos.y>_Value){
discard;
}
//实现简单的Lambert光照
float3 LightDir = normalize(_WorldSpaceLightPos0.xyz);
float3 diffuseColor =_LightColor0*max(dot(i.nor, LightDir), 0);
return _Color*float4(diffuseColor,1);
}
ENDCG
}
Pass
{
CGPROGRAM
#pragma target 4.0
#pragma vertex vert
#pragma fragment frag
#pragma geometry geom
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
};
struct v2g
{
float4 vertex : POSITION;
};
struct g2f
{
float4 vertex : SV_POSITION;
};
float _Value;
fixed4 _CullPlaneColor;
v2g vert(appdata_base v)
{
v2g o;
o.vertex = v.vertex;
return o;
}
void ADD_VERT(float3 v,g2f o,inout TriangleStream<g2f> tristream)
{
o.vertex = UnityObjectToClipPos(v);
tristream.Append(o);
}
void ADD_TRI(float3 p0,float3 p1,float3 p2,g2f o,inout TriangleStream<g2f> tristream)
{
ADD_VERT(p0,o,tristream);
ADD_VERT(p1,o,tristream);
ADD_VERT(p2,o,tristream);
tristream.RestartStrip();
}
void CanclucatePoints(float3 p1,float3 p2,float3 p3,out float3 outp1,out float3 outp2,float value)
{
float kd1=(value-p1.y)/(p2.y-p1.y);
float kd2=(value-p1.y)/(p3.y-p1.y);
outp1=lerp(p1,p2,kd1);
outp2=lerp(p1,p3,kd2);
}
[maxvertexcount(3)]
void geom(triangle v2g IN[3], inout TriangleStream<g2f> tristream)
{
g2f o;
float3 v0 = IN[0].vertex;
float3 v1 = IN[1].vertex;
float3 v2 = IN[2].vertex;
//一个点在平面上面的情况
if(v0.y>_Value&&v1.y<_Value&&v2.y<_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v0,v1,v2,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
if(v0.y<_Value&&v1.y>_Value&&v2.y<_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v1,v2,v0,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
if(v0.y<_Value&&v1.y<_Value&&v2.y>_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v2,v0,v1,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
//===================
//两个点在平面上方的情况
if(v0.y<_Value&&v1.y>_Value&&v2.y>_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v0,v2,v1,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
if(v0.y>_Value&&v1.y>_Value&&v2.y<_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v2,v1,v0,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
if(v0.y>_Value&&v1.y<_Value&&v2.y>_Value)
{
float3 outmp1;
float3 outmp2;
float3 center=float3(0,_Value,0);
CanclucatePoints(v1,v0,v2,outmp1,outmp2,_Value);
ADD_TRI(center,outmp1,outmp2,o,tristream);
}
//============
}
fixed4 frag (g2f i) : SV_Target
{
return _CullPlaneColor;
}
ENDCG
}
}
}