shader学习之路——平面阴影

模型变换流程：模型->世界->摄像机空间(xyz  1,1,1的立方体)->投影空间 ->屏幕空间

1.压扁   把模型变换到世界空间，使Y轴为0  再把顶点变换到投影空间

为什么不在角色的模型空间进行压扁操作，而是变换到世界空间里，因为角色可能因为各种原因发生旋转（动作等），角色旋转后，压扁的阴影也会跟着转

小提示：如果影子抖动，可能是因为较低位置和地面高度相同所以看起来抖  留一点点距离

2.投影偏移，灯光从侧面照入

偏移方法：在x-z方向上对顶点偏移

3.投影拉长

顶点偏移量跟角色从脚部算起的高度关联    要先进行XZ偏移再进行Y偏移，否则会world.y - shadowoffset.y这个系数永远等于0

world.xz += _shadowoff.xz  * (world.y - shadowoffset.y) 

world.y = _shadowoff.y;

4.由于正反面会渲染两次导致斑驳，可以使用模板测来使片元同一个位置只渲染一次

unity在渲染时候把半透明和不透明队列

半透明：从后往前渲染（靠摄像机的距离）

不透明：从前往后渲染

图形硬件里有三个缓冲区：颜色缓冲区、深度缓冲区、模板缓冲区

Shader "Unlit/ShadowShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _shadowOffset("Shadow Offest(xz),Shadow Offect(Y)",vector) = (0,0,0)
        _ShadowColor("Shadow Color",Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Name "ForwardBase"
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;   
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {

                fixed4 col = tex2D(_MainTex, i.uv);
                return col;
            }
                ENDCG
        }

            Pass
            {
                Name "PlaneShadow"

                Blend SrcAlpha OneMinusSrcAlpha  //混合公式

                //使用模板缓冲区使其只渲染一次  解决正反面都渲染造成的渲染重叠斑驳
                Stencil  //定制模板测试
                {
                    Ref 1//设定的参考值 将来用于与模板缓冲区中的值作比较
                    Comp NotEqual //定义Fef与角膜瓣缓冲区中的值比较操作
                    Pass Replace //当模板测试通过时，根据
                    Fail Keep //如果失败了则保持原来模板值
            }


            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            vector _shadowOffset;
            fixed4 _ShadowColor;

            v2f vert(appdata v)
            {
                v2f o;                
                //士兵的高度值作为阴影便宜的系数   要先做XY的偏移，如果先做Y轴偏移那么worldPos.y - _shadowOffset.y则永远是0
                float4 worldPos = mul(unity_ObjectToWorld, v.vertex);
                worldPos.xz += (worldPos.y - _shadowOffset.y) * _shadowOffset.xz; 
                worldPos.y = _shadowOffset.y; //在世界空间下对模型进行压扁

                o.vertex = mul(unity_MatrixVP, worldPos);//从世界空间转变为投影空间   模型空间->世界空间->相机空间->投影空间->屏幕空间
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return _ShadowColor;
            }
            ENDCG
        }
    }
}

效果：