3. 轴指令（omron 机器自动化控制器）——＞MC_MoveAbsolute

已于 2024-09-13 20:14:58 修改
阅读量366 收藏 9
点赞数 12
分类专栏： OMRON NJ/NX系列PLC 指令基准手册 文章标签： 自动化 运维
于 2024-09-13 20:12:44 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_58801558/article/details/142219027
版权

机器自动化控制器——第三章 轴指令 4

MC_MoveAbsolute

  • 指定绝对坐标的目标位置，进行定位。
指令名称FB/
FUN		图形表现ST表现
MC_MoveAbsolute绝对值定位FB描述文本MC_MoveAbsolute_instance (
Axis :=《参数》 ,
Execute :=《参数》 ,
Position :=《参数》 ,
Velocity :=《参数》 ,
Acceleration :=《参数》 ,
Deceleration :=《参数》 ,
Jerk :=《参数》 ,
Direction :=《参数》 ,
BufferMode :=《参数》 ,
Done =>《参数》 ,
Busy =>《参数》 ,
Active =>《参数》 ,
CommandAborted =>《参数》 ,
Error =>《参数》 ,
ErrorID =>《参数》
);

变量

▶输入变量
输入变量名称数据类型有效范围初始值内容
Execute启动BOOLTRUE, FALSEFALSE在上升沿开始指令。
Position目标位置LREAL负数、正数、“0”0指定绝对坐标的目标位置。
单位为[指令单位]。 *1
Velocity目标速度LREAL正数0指定目标速度。*2
单位为[指令单位/s] 。*1
Acceleration加速度LREAL正数或“0”0指定加速度。
单位为[指令单位/s2]。*1
Deceleration减速度LREAL正数或“0”0指定减速度。
单位为[指令单位/s2]。*1
Jerk跃度LREAL正数或“0”0指定跃度。
单位为[指令单位/s3]。*1
Direction方向选择_eMC_
DIRECTION		0: _mcPositiveDirection
1: _mcShortestWay
2: _mcNegativeDirection
3: _mcCurrentDirection
4: _mcNoDirection		0 *3计数模式为[旋转模式]时，指定旋
转方向。
0：指定为正方向
1：指定为附近
2：指定为负方向
3：指定为当前方向
4：无方向指定
BufferMode缓存模式选择_eMC_
BUFFER_
MODE		0: _mcAborting
1: _mcBuffered
2: _mcBlendingLow
3: _mcBlendingPrevious
4: _mcBlendingNext
5: _mcBlendingHigh		0 *3指定多重启动运动指令时的动作。
0：中断
1：等待
2：以低速合并
3：以前一个速度合并
4：以后一个速度合并
5：以高速合并
  • 1.关于指令单位，请参阅“NJ/NX系列CPU单元用户手册运动控制篇(SBCE-363)”或“NY系列工业用平板电脑/工业用台式电脑用户手册运动控制篇(SBCE-379)”的“单位转换设定”。
  • 2.请务必设定目标速度。不作设定就执行动作，将发生异常。
  • 3.有效范围为枚举体的变量，其实际初始值不是数值，而是枚举元素。
▶输入输出变量
输出变量名称数据类型有效范围内容
Done完成BOOLTRUE,
FALSE		指令执行完毕时变为TRUE。
Busy执行中BOOLTRUE,
FALSE		接收指令后变为TRUE。
Active控制中BOOLTRUE,
FALSE		控制中变为TRUE。
CommandAborted执行中断BOOLTRUE,
FALSE		指令中止时，变为TRUE。
Error错误BOOLTRUE,
FALSE		发生异常时变为TRUE。
ErrorID错误代码WORD*1发生异常时，输出错误代码。16#0000为正常。
  • 1.请参阅“A-1错误代码一览(P.A-2)”。

    ► 输出变量的反映时间

变量变为TRUE的时间变为FALSE的时间
Done定位完成后• Execute为TRUE时，与Execute的FALSE同时
• Execute为FALSE时，1个周期后
BusyExecute的上升沿• Done变为TRUE时
• Error变为TRUE时
• CommandAborted变为TRUE时
Active开始指令后• Done变为TRUE时
• Error变为TRUE时
• CommandAborted变为TRUE时
CommandAborted• 利用其它指令多重启动运动指令(中断)，中止本
指令时
• 因发生异常，中止本指令时
• 发生异常过程中，启动本指令时
• MC_Stop指令执行中，启动本指令后		• Execute为TRUE时，与Execute的FALSE同时
• Execute为FALSE时，1个周期后
Error本指令的启动条件或输入参数中含有异常因素时异常已解除时
▶输入输出变量
输入输出变量名称数据类型有效范围内容
Axis轴_sAXIS_REF－指定轴。 *1
  • 1.请使用在SysmacStudio的轴基本设定画面中创建的用户定义变量的轴变量名称(默认“MC_Axis
    ”)或系统定义变量的轴变量名称(_MC_AX[],_MC1_AX[],_MC2_AX[])。

功能说明

  • 指定绝对坐标的目标位置，进行定位。
  • 在Execute(启动)的上升沿，开始绝对定位的动作。
  • 即使原点未确定也可执行本指令。
  • 可在输入变量中指定Velocity(目标速度)、Acceleration(加速度)、Deceleration(减速度)、Jerk(跃度)。
  • 绝对定位的动作示例如下所示。
    在这里插入图片描述
  • 将加速度、或减速度指定为“0”并启动后，不作加减速而达到目标速度。
  • 加速度为“0”时的动作示例如下所示。
    在这里插入图片描述
  • 需要平稳加减速时指定Jerk(跃度)。
  • 指定Jerk(跃度)后的动作示例如下所示。
    在这里插入图片描述
  • 关于Jerk(跃度)的详情，请参阅“NJ/NX系列 CPU单元 用户手册 运动控制篇(SBCE-363)”或“NY系列 工业用平板电脑/工业用台式电脑 用户手册 运动控制篇(SBCE-379)”。
  • 与指令当前位置相同，指定Position(目标位置)并启动后，轴不发生移动，但是Done(完成)将变为TRUE。
▶指令详情
  • 下面对指令详细说明。
  • 计数模式为[旋转模式]时，通过Direction(方向选择)指定开始定位的方向。
  • 计数模式为[线性模式]时，忽略Direction(方向选择)。
  • Direction(方向选择)为“指定为正方向”时，迎着正方向目标位置进行定位。
  • 指令位置由“50”到“-20”定位时的动作示例如下所示。
    在这里插入图片描述
  • Direction(方向选择)为“指定为负方向”时，迎着负方向目标位置进行定位。
  • 指令位置由“50”到“-20”定位时的动作示例如下所示。
    在这里插入图片描述
  • Direction(方向选择)为“无方向指定”时，迎着环计数器范围内的目标位置进行定位。
  • 因此，移动方向取决于指令当前位置与目标位置的大小关系。
  • 指令位置由“50”到“-20”定位时的动作示例如下所示。
    在这里插入图片描述
  • Direction(方向选择)为“无方向指定”时，可指定超出环计数器上下限设定值范围的Position(目标位置)。
  • 指定了超过环计数器上限设定值的Position( 目标位置) 时，将超出设定值的移动量作为超过后的相对量进行定位。
  • 因此，可实现环多圈定位。
  • 指定了超过环计数器下限设定值的Position(目标位置)时，同样进行定位。
  • 指令当前位置为“-20”、Position(目标位置)指定为“290”时的动作示例如下所示。
    在这里插入图片描述
  • Direction(方向选择)为“指定为附近”时，迎着指令当前位置和目标位置距离较短的方向进行定位。
  • 指令位置由“50”到“-20”定位时的动作示例如下所示。
    在这里插入图片描述
  • 使用注意事项
  • 正方向、负方向移动距离都相同时，动作与“指定为当前方向”时相同。
  • 进行绝对值定位时，请在低于轴参数的[环计数器上限设定值]、及不低于[环计数器下限设定值]的范围内指定目标位置。
  • 否则，将发生“超出目标位置设定范围(错误代码：5478Hex)”错误。
  • 但是，Direction(方向选择)为“无方向指定”时，可指定超出环计数器上下限设定值范围的Position(目标位置)。
  • Direction(方向选择)选择“3: _mcCurrentDirection(指定为当前方向)”时，沿着前一动作的指令方向进行动作。
  • 因此，根据指令组合的不同，可能与前一动作的运动指令的输入发出指令的方向不一致。
  • 使用“3: _mcCurrentDirection(指定为当前方向)”时，请通过轴变量的Dir.Posi(正方向指令中)、以及Dir.Nega(负方向指令中)确认当前方向。

    ► 到位检查

  • 根据轴参数的[到位宽度]、[到位检查时间]的设定，进行本指令的到位检查。
▶时序图
  • 在启动Execute(启动)的同时，Busy(执行中)变为TRUE。
  • 在下一个周期Active(控制中)变为TRUE。
  • 到达Position(目标位置)、定位完成时，Done(完成)变为TRUE。
  • 利用其它指令中止本指令时，CommandAborted(执行中断)变为TRUE，Busy(执行中)、Active(控制中)变为FALSE。
    在这里插入图片描述
▶重启运动指令
  • 在定位动作中变更输入变量，再次将Execute(启动)设为TRUE，可变更本指令的动作。
  • 重启运动指令可变更的输入变量有Position(目标位置)、Velocity(目标速度)、Acceleration(加速度)、Deceleration(减速度)。
  • 重启运动指令的详情，请参阅“NJ/NX系列 CPU单元 用户手册 运动控制篇(SBCE-363)”或“NY系列 工业用平板电脑/工业用台式电脑 用户手册 运动控制篇(SBCE-379)”。
▶多重启动运动指令
  • 多重启动运动指令的详情，请参阅“NJ/NX系列 CPU单元 用户手册 运动控制篇(SBCE-363)”或“NY系列 工业用平板电脑/工业用台式电脑 用户手册 运动控制篇(SBCE-379)”。

    ► 其它指令执行中的本指令启动

  • 对当前正在执行的指令启动本指令，可切换或缓存到本指令。
  • 各轴可缓存到1个。
  • 多重启动时的本指令的动作由BufferMode(缓存模式选择)指定。
缓存模式选择说明
中断立即中止当前正在执行的指令，切换为本指令。
轴的动作方向因指令切换而反转时，根据轴参数中的“反转时动作”进行反转。
等待当前正在执行的指令正常完成后，已缓存的本指令自动启动。
合并
以低速合并
以前一个速度合
并
以后一个速度合
并
以高速合并		以当前正在执行的指令到达目标位置时的速度(中继速度)为启动速度，连续使已缓存的本
指令动作。变更当前正在执行的指令的动作，确保以中继速度到达目标位置。中继速度的
指定方法分为如下4种。
以低速合并当前正在执行的目标速度与已缓存的目标速度中，以速度较低者为中继速度。
以前一个速度合
并		以当前正在执行的目标速度为中继速度。
以后一个速度合
并		以已缓存的本指令的目标速度为中继速度。
以高速合并当前正在执行的目标速度与已缓存的目标速度中，以速度较高者为中继速度。
  • 关于BufferMode(缓存模式选择)，请参阅“NJ/NX系列 CPU单元 用户手册 运动控制篇(SBCE-363)”或“NY系列 工业用平板电脑/工业用台式电脑 用户手册 运动控制篇(SBCE-379)”。

    ► 本指令执行中的其它指令启动

  • 对本指令进行多重启动运动指令时，可选择中断、等待、合并。
▶异常
  • 在执行本指令中发生异常时，Error(错误)变为TRUE，轴停止动作。
  • 可查看ErrorID(错误代码)的输出值，了解发生异常的原因。

    ► 发生异常时的时序图
在这里插入图片描述

    ► 错误代码

  • 关于指令发生的异常，请参阅“A-1 错误代码一览(P.A-2)”。

示例程序1

  • 下面，对基于反复多重启动的定位方法中的示例程序进行说明。
▶参数设定
  • 该示例程序中使用的最少的必要设定如下所示。

    ► 轴参数的设定

    轴种类

轴轴种类
轴1伺服轴

    计数器模式

轴计数器模式
轴1线性模式

    坐标单位选择

轴坐标单位
轴1mm
▶动作示例
  • 利用MC_MoveAbsolute(绝对值定位)指令将BufferMode(缓存模式选择)设为[等待],在多重启动运动指令的同时，移动到最终目标位置。
  • 到达最终目标位置后，请利用MC_ZeroPosition(高速原点复位)指令返回原点。
  • 在之前的指令输出变量“Active(控制中)”为TRUE的状态下进行多重启动。

    ► 动作模式
在这里插入图片描述

1 动作开始开关的 “ON”

  • 在原点开启动作开始开关，则轴1正方向50.00mm定位

2 其次，动作开始开关的 “ON”

  • 接着，每当开启动作开始开关，轴1正方向100.00mm、200.00mm定位，返回原点并停止动作。
▶梯形图

    ► 主要变量

名称数据类型初始值注释
MC_Axis000_sAXIS_REF－轴1的轴变量。
MC_Axis000.MFaultLvl.ActiveBOOLFALSE轴1发生轻度故障等级的异常时变为TRUE。
MC_Axis000.Details.HomedBOOLFALSE轴1为原点确定状态时变为TRUE。
Pwr_StatusBOOLFALSE分配给MC_Power的实例PWR的输出变量Status的变
量。进入伺服ON状态时，该变量变为TRUE。
StartPgBOOLFALSE如果该变量为TRUE，EtherCAT的过程数据通信已
建立，则进入伺服ON状态。

    ► 时序图
在这里插入图片描述

    ► 示例程序
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

在这里插入图片描述
在这里插入图片描述

▶结构文本(ST)

    ► 主要变量

名称数据类型初始值注释
MC_Axis000_sAXIS_REF－轴1的轴变量。
MC_Axis000.MFaultLvl.ActiveBOOLFALSE轴1发生轻度故障等级的异常时变为TRUE。
MC_Axis000.Details.HomedBOOLFALSE轴1为原点确定状态时变为TRUE。
Pwr_StatusBOOLFALSE分配给MC_Power的实例PWR的输出变量Status的变
量。进入伺服ON状态时，该变量变为TRUE。
StartPgBOOLFALSE如果该变量为TRUE，EtherCAT的过程数据通信已
建立，则进入伺服ON状态。
Hm_ExBOOLFALSE该变量由FALSE→TRUE时，启动MC_Home的实例
HM。
Mv_Abs1_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS1。
Mv_Abs2_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS2。
Mv_Abs3_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS3。
Mv_Zero_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveZeroPosition的实例MV_ZERO。
InitFlagBOOLFALSE表示输入参数设定完成。
FALSE时，设定输入参数。输入参数设定完成后，
变为TRUE。

    ► 时序图
在这里插入图片描述

    ► 示例程序

// 未设定输入参数时的处理
IF InitFlag = FALSE THEN
  // MV_ABS1 参数
  Mv_Abs1_Pos := LREAL#50.0;
  Mv_Abs1_Vel := LREAL#10.0;
  Mv_Abs1_Acc := LREAL#1000.0;
  Mv_Abs1_Dec := LREAL#1000.0;
  Mv_Abs1_Dir := _eMC_DIRECTION#_mcNoDirection;

  // MV_ABS2 参数
  Mv_Abs2_Pos := LREAL#100.0;
  Mv_Abs2_Vel := LREAL#20.0;
  Mv_Abs2_Acc := LREAL#1000.0;
  Mv_Abs2_Dec := LREAL#1000.0;
  Mv_Abs2_Dir := _eMC_DIRECTION#_mcNoDirection;
  Mv_Abs2_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // MV_ABS3 参数
  Mv_Abs3_Pos := LREAL#200.0;
  Mv_Abs3_Vel := LREAL#30.0;
  Mv_Abs3_Acc := LREAL#1000.0;
  Mv_Abs3_Dec := LREAL#1000.0;
  Mv_Abs3_Dir := _eMC_DIRECTION#_mcNoDirection;
  Mv_Abs3_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // MV_ZERO 参数
  Mv_Zero_Vel := LREAL#250;
  Mv_Zero_Acc := LREAL#1000.0;
  Mv_Zero_Dec := LREAL#1000.0;
  Mv_Zero_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // 设定输入参数后，将 InitFlag 设为 TRUE
  InitFlag := TRUE;
END_IF;

// 确认 StartPg 为 TRUE，且伺服驱动器处于伺服准备就绪状态，
// 则设为伺服 ON 状态。
// 如果未处于伺服准备就绪状态，则设为伺服 OFF。
IF (StartPg = TRUE) AND (MC_Axis000.DrvStatus.Ready = TRUE) THEN
  Pwr_En := TRUE;
ELSE
  Pwr_En := FALSE;
END_IF;

// 发生轻度故障等级异常时的处理
// 发生异常时的处理 (FaultHandler) 由客户根据装置进行编程。
IF MC_Axis000.MFaultLvl.Active = TRUE THEN
  FaultHandler();
END_IF;

// 在伺服 ON 状态下，且原点未确定时，进行原点复位。
IF (Pwr_Status = TRUE) AND (MC_Axis000.Details.Homed = FALSE) THEN
  Hm_Ex := TRUE;
END_IF;

// 确定原点后，执行 MV_ABS1
IF Hm_D = TRUE THEN
  Mv_Abs1_Ex := TRUE;
END_IF;

// 开始 MV_ABS1 后，多重启动 MV_ABS2
IF Mv_Abs1_Act = TRUE THEN
  Mv_Abs2_Ex := TRUE;
END_IF;

// 开始 MV_ABS2 后，多重启动 MV_ABS3
IF Mv_Abs2_Act = TRUE THEN
  Mv_Abs3_Ex := TRUE;
END_IF;

// 开始 MV_ABS3 后，多重启动 MV_ZERO
IF Mv_Abs3_Act = TRUE THEN
  Mv_Zero_Ex := TRUE;
END_IF;

// MC_Power
PWR(
  Axis := MC_Axis000,
  Enable := Pwr_En,
  Status => Pwr_Status,
  Busy => Pwr_Bsy,
  Error => Pwr_Err,
  ErrorID => Pwr_ErrID
);

// MC_Home
HM(
  Axis := MC_Axis000,
  Execute := Hm_Ex,
  Done => Hm_D,
  Busy => Hm_Bsy,
  CommandAborted => Hm_Ca,
  Error => Hm_Err,
  ErrorID => Hm_ErrID
);

// MC_MoveAbsolute
MV_ABS1(
  Axis := MC_Axis000,
  Execute := Mv_Abs1_Ex,
  Position := Mv_Abs1_Pos,
  Velocity := Mv_Abs1_Vel,
  Acceleration := Mv_Abs1_Acc,
  Deceleration := Mv_Abs1_Dec,
  Direction := Mv_Abs1_Dir,
  Done => Mv_Abs1_D,
  Busy => Mv_Abs1_Bsy,
  Active => Mv_Abs1_Act,
  CommandAborted => Mv_Abs1_Ca,
  Error => Mv_Abs1_Err,
  ErrorID => Mv_Abs1_ErrID
);

MV_ABS2(
  Axis := MC_Axis000,
  Execute := Mv_Abs2_Ex,
  Position := Mv_Abs2_Pos,
  Velocity := Mv_Abs2_Vel,
  Acceleration := Mv_Abs2_Acc,
  Deceleration := Mv_Abs2_Dec,
  Direction := Mv_Abs2_Dir,
  BufferMode := Mv_Abs2_Bm,
  Done => Mv_Abs2_D,
  Busy => Mv_Abs2_Bsy,
  Active => Mv_Abs2_Act,
  CommandAborted => Mv_Abs2_Ca,
  Error => Mv_Abs2_Err,
  ErrorID => Mv_Abs2_ErrID
);

MV_ABS3(
  Axis := MC_Axis000,
  Execute := Mv_Abs3_Ex,
  Position := Mv_Abs3_Pos,
  Velocity := Mv_Abs3_Vel,
  Acceleration := Mv_Abs3_Acc,
  Deceleration := Mv_Abs3_Dec,
  Direction := Mv_Abs3_Dir,
  BufferMode := Mv_Abs3_Bm,
  Done => Mv_Abs3_D,
  Busy => Mv_Abs3_Bsy,
  Active => Mv_Abs3_Act,
  CommandAborted => Mv_Abs3_Ca,
  Error => Mv_Abs3_Err,
  ErrorID => Mv_Abs3_ErrID
);

// MC_MoveZeroPosition
MV_ZERO(
  Axis := MC_Axis000,
  Execute := Mv_Zero_Ex,
  Velocity := Mv_Zero_Vel,
  Acceleration := Mv_Zero_Acc,
  Deceleration := Mv_Zero_Dec,
  BufferMode := Mv_Zero_Bm,
  Done => Mv_Zero_D,
  Busy => Mv_Zero_Bsy,
  Active => Mv_Zero_Act,
  CommandAborted => Mv_Zero_Ca,
  Error => Mv_Zero_Err,
  ErrorID => Mv_Zero_ErrID
);

示例程序2

  • 计数模式为旋转模式时，为了向目标位置定位，自动识别左右哪边较近进行定位。
  • 下面，对工具更换的附近控制中的示例程序进行说明。
▶参数设定
    • 该示例程序中使用的最少的必要设定如下所示。

    ► 轴参数的设定

    轴种类

轴轴种类
轴1伺服轴

    计数器模式

轴计数器模式
轴1旋转模式

    环计数器

轴上限值下限值
轴13600

    坐标单位选择

轴坐标单位
轴1degree
▶动作示例
  • 利用绝对值定位指令的多重启动，在0～360的范围内动作的示例如下所示。
  • 此外，如果当前位置超出0 ～ 360的范围，则返回0。
  • 在之前的指令输出变量“Active(控制中)”为TRUE的状态下进行多重启动。
  • 只有1个指令可执行单轴动作的指令多重启动。
  • 本例中，将BufferMode(缓存模式选择)设为等待，使之多重启动
    在这里插入图片描述
  • 如果指定原点(0)、90、120、290等4个任意位置，则移动到该位置。
  • 此时的旋转方向表现为较近方向。
  • 并且，移动速度为250/s。
  • 在示例程序中，按照指定为附近定位为290→90→120→原点(0)。
▶梯形图
名称数据类型初始值注释
MC_Axis000_sAXIS_REF－轴1的轴变量。
MC_Axis000.MFaultLvl.ActiveBOOLFALSE轴1发生轻度故障等级的异常时变为TRUE。
MC_Axis000.Details.HomedBOOLFALSE轴1为原点确定状态时变为TRUE。
Pwr_StatusBOOLFALSE分配给MC_Power的实例PWR的输出变量Status的变
量。进入伺服ON状态时，该变量变为TRUE。
StartPgBOOLFALSE如果该变量为TRUE，EtherCAT的过程数据通信已
建立，则进入伺服ON状态。

    ► 主要变量
在这里插入图片描述

    ► 示例程序
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

▶结构文本(ST)

    ► 主要变量

名称数据类型初始值注释
MC_Axis000_sAXIS_REF－轴1的轴变量。
MC_Axis000.MFaultLvl.ActiveBOOLFALSE轴1发生轻度故障等级的异常时变为TRUE。
MC_Axis000.Details.HomedBOOLFALSE轴1为原点确定状态时变为TRUE。
Pwr_StatusBOOLFALSE分配给MC_Power的实例PWR的输出变量Status的变
量。进入伺服ON状态时，该变量变为TRUE。
StartPgBOOLFALSE如果该变量为TRUE，EtherCAT的过程数据通信已
建立，则进入伺服ON状态。
Hm_ExBOOLFALSE该变量由FALSE→TRUE时，启动MC_Home的实例
HM。
Mv_Abs1_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS1。
Mv_Abs2_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS2。
Mv_Abs3_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS3。
Mv_Abs4_ExBOOLFALSE该变量由FALSE→TRUE时，启动
MC_MoveAbsolute的实例MV_ABS4。
InitFlagBOOLFALSE表示输入参数设定完成。
FALSE时，设定输入参数。输入参数设定完成后，
变为TRUE。

    ► 时序图
在这里插入图片描述

    ► 示例程序

// 未设定输入参数时的处理
IF InitFlag = FALSE THEN
  // MV_ABS1 参数
  Mv_Abs1_Pos := LREAL#290.0;
  Mv_Abs1_Vel := LREAL#250.0;
  Mv_Abs1_Acc := LREAL#1000.0;
  Mv_Abs1_Dec := LREAL#1000.0;
  Mv_Abs1_Dir := _eMC_DIRECTION#_mcShortestWay;

  // MV_ABS2 参数
  Mv_Abs2_Pos := LREAL#90.0;
  Mv_Abs2_Vel := LREAL#250.0;
  Mv_Abs2_Acc := LREAL#1000.0;
  Mv_Abs2_Dec := LREAL#1000.0;
  Mv_Abs2_Dir := _eMC_DIRECTION#_mcShortestWay;
  Mv_Abs2_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // MV_ABS3 参数
  Mv_Abs3_Pos := LREAL#120.0;
  Mv_Abs3_Vel := LREAL#250.0;
  Mv_Abs3_Acc := LREAL#1000.0;
  Mv_Abs3_Dec := LREAL#1000.0;
  Mv_Abs3_Dir := _eMC_DIRECTION#_mcShortestWay;
  Mv_Abs3_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // MV_ABS4 参数
  Mv_Abs4_Pos := LREAL#0.0;
  Mv_Abs4_Vel := LREAL#250.0;
  Mv_Abs4_Acc := LREAL#1000.0;
  Mv_Abs4_Dec := LREAL#1000.0;
  Mv_Abs4_Dir := _eMC_DIRECTION#_mcShortestWay;
  Mv_Abs4_Bm := _eMC_BUFFER_MODE#_mcBuffered;

  // 设定输入参数后，将 InitFlag 设为 TRUE
  InitFlag := TRUE;
END_IF;

// 确认 StartPg 为 TRUE，且伺服驱动器处于伺服准备就绪状态，
// 则设为伺服 ON 状态。
// 如果未处于伺服准备就绪状态，则设为伺服 OFF。
IF (StartPg = TRUE) AND (MC_Axis000.DrvStatus.Ready = TRUE) THEN
  Pwr_En := TRUE;
ELSE
  Pwr_En := FALSE;
END_IF;

// 发生轻度故障等级异常时的处理
// 发生异常时的处理 (FaultHandler) 由客户根据装置进行编程。
IF MC_Axis000.MFaultLvl.Active = TRUE THEN
  FaultHandler();
END_IF;

// 在伺服 ON 状态下，且原点未确定时，进行原点复位。
IF (Pwr_Status = TRUE) AND (MC_Axis000.Details.Homed = FALSE) THEN
  Hm_Ex := TRUE;
END_IF;

// 确定原点后，执行 MV_ABS1
IF Hm_D = TRUE THEN
  Mv_Abs1_Ex := TRUE;
END_IF;

// 开始 MV_ABS1 后，多重启动 MV_ABS2
IF Mv_Abs1_Act = TRUE THEN
  Mv_Abs2_Ex := TRUE;
END_IF;

// 开始 MV_ABS2 后，多重启动 MV_ABS3
IF Mv_Abs2_Act = TRUE THEN
  Mv_Abs3_Ex := TRUE;
END_IF;

// 开始 MV_ABS3 后，多重启动 MV_ABS4
IF Mv_Abs3_Act = TRUE THEN
  Mv_Abs4_Ex := TRUE;
END_IF;

// MC_Power
PWR(
  Axis := MC_Axis000,
  Enable := Pwr_En,
  Status => Pwr_Status,
  Busy => Pwr_Bsy,
  Error => Pwr_Err,
  ErrorID => Pwr_ErrID
);

// MC_Home
HM(
  Axis := MC_Axis000,
  Execute := Hm_Ex,
  Done => Hm_D,
  Busy => Hm_Bsy,
  CommandAborted => Hm_Ca,
  Error => Hm_Err,
  ErrorID => Hm_ErrID
);

// 绝对值定位(1)
MV_ABS1(
  Axis := MC_Axis000,
  Execute := Mv_Abs1_Ex,
  Position := Mv_Abs1_Pos,
  Velocity := Mv_Abs1_Vel,
  Acceleration := Mv_Abs1_Acc,
  Deceleration := Mv_Abs1_Dec,
  Direction := Mv_Abs1_Dir,
  Done => Mv_Abs1_D,
  Busy => Mv_Abs1_Bsy,
  Active => Mv_Abs1_Act,
  CommandAborted => Mv_Abs1_Ca,
  Error => Mv_Abs1_Err,
  ErrorID => Mv_Abs1_ErrID
);

// 绝对值定位(2)
MV_ABS2(
  Axis := MC_Axis000,
  Execute := Mv_Abs2_Ex,
  Position := Mv_Abs2_Pos,
  Velocity := Mv_Abs2_Vel,
  Acceleration := Mv_Abs2_Acc,
  Deceleration := Mv_Abs2_Dec,
  Direction := Mv_Abs2_Dir,
  BufferMode := Mv_Abs2_Bm,
  Done => Mv_Abs2_D,
  Busy => Mv_Abs2_Bsy,
  Active => Mv_Abs2_Act,
  CommandAborted => Mv_Abs2_Ca,
  Error => Mv_Abs2_Err,
  ErrorID => Mv_Abs2_ErrID
);

// 绝对值定位(3)
MV_ABS3(
  Axis := MC_Axis000,
  Execute := Mv_Abs3_Ex,
  Position := Mv_Abs3_Pos,
  Velocity := Mv_Abs3_Vel,
  Acceleration := Mv_Abs3_Acc,
  Deceleration := Mv_Abs3_Dec,
  Direction := Mv_Abs3_Dir,
  BufferMode := Mv_Abs3_Bm,
  Done => Mv_Abs3_D,
  Busy => Mv_Abs3_Bsy,
  Active => Mv_Abs3_Act,
  CommandAborted => Mv_Abs3_Ca,
  Error => Mv_Abs3_Err,
  ErrorID => Mv_Abs3_ErrID
);

// 绝对值定位(4)
MV_ABS4(
  Axis := MC_Axis000,
  Execute := Mv_Abs4_Ex,
  Position := Mv_Abs4_Pos,
  Velocity := Mv_Abs4_Vel,
  Acceleration := Mv_Abs4_Acc,
  Deceleration := Mv_Abs4_Dec,
  Direction := Mv_Abs4_Dir,
  BufferMode := Mv_Abs4_Bm,
  Done => Mv_Abs4_D,
  Busy => Mv_Abs4_Bsy,
  Active => Mv_Abs4_Act,
  CommandAborted => Mv_Abs4_Ca,
  Error => Mv_Abs4_Err,
  ErrorID => Mv_Abs4_ErrID
);
一半不眠次日si记
关注
专栏目录
3. 轴指令（omron 机器自动化控制器）——＞MC_Home
这个家伙看起来很懒，只想把你留下来哦
09-12 474
MC_Home 变量 ▶输入变量 ▶输出变量 ▶输入输出变量 功能说明 ▶欧姆龙制伺服驱动器1S系列的设定 ▶欧姆龙制伺服驱动器 G5系列的设定 ▶NX系列位置接口单元的设定 ▶原点复位动作模式 ▶正方向极限输入时动作和负方向极限输入时动作 ▶原点复位开始方向 ▶原点检测方向 ▶原点输入屏蔽距离 ▶原点复位补偿值 ▶原点位置偏置 ▶原点复位速度 ▶原点复位接近速度 ▶原点复位补偿速度 ▶指令详情 ▶时序图 ▶重启运动指令 ▶多重启动运动指令 ▶错误代码
3. 轴指令（omron 机器自动化控制器）——＞MC_Power&MC_MoveJog
这个家伙看起来很懒，只想把你留下来哦
09-12 580
使用带绝对值编码器的伺服电机的情况下，在轴切换为可运行状态时，如果处于原点未确定状态，则执行[绝对值编码器原点位置偏置]的补偿，即可变为原点确定状态。此时，中断执行(CommandAborted)动作中的指令，停止动作指令的输出，切换为解除状态。无论Enable(有效)是TRUE还是FALSE，Status(可运行)均输出轴的可运行状态。将Enable(有效)设为FALSE，可解除Axis(轴)指定轴的可运行状态。将Enable(有效)设为TRUE时，Axis(轴)指定的轴进入可运行状态。
3. 轴指令（omron 机器自动化控制器）——＞MC_HomeWithParameter&MC_Move
最新发布
这个家伙看起来很懒，只想把你留下来哦
09-13 333
MC_HomeWithParameter 变量 ▶输入变量 ▶输出变量 功能说明 ▶原点复位动作与原点复位参数的关系 ▶重启运动指令 ▶多重启动运动指令 ▶错误代码 MC_Move 变量 ▶输入变量 ▶输出变量 ▶输入输出变量 功能说明 ▶指令详情 ▶重启运动指令 ▶多重启动运动指令 ▶异常
2. 变量和指令（omron 机器自动化控制器）——2
这个家伙看起来很懒，只想把你留下来哦
09-11 640
Ver.1.09以下版本的CPU单元，如未使用欧姆龙制伺服驱动器1S系列EtherCAT通信内置型及 G5系列EtherCAT通信内置型，需映射操作模式(6060Hex)及操作模式显示(6061Hex)。Ver.1.10 以上版本的 CPU 单元，根据有无操作模式(6060Hex)及操作模式显示 (6061Hex)映射， 动作如下。使用NX系列位置接口单元时，请参阅 “NX系列 位置接口单元 用户手册(SBCE-374)”中的 “I/O入口 映射”。2.伺服驱动器控制模式中的周期性同步速度模式(CSV)。
NC整合控制器 机器自动化控制器 NJ_NY系列样本.pdf
03-19
NC整合控制器是一种集成了数控（NC）功能和可编程逻辑控制器（PLC）功能的机器自动化控制器。此类控制器适用于加工设备的自动化升级，尤其是在产品形状和原材料日益多样化及复杂化的当下，提供了一种解决生产效率和...
机器自动化控制器 NJ_NX系列 启动指南 运动控制篇.pdf
04-15
1. 机器自动化控制器NJ/NX系列启动指南是为首次使用该系列运动控制功能时的操作人员提供的，主要内容包括轴参数设定、单轴定位和双轴直线插补的操作步骤和方法。 2. SysmacStudio是配合NJ/NX系列CPU单元使用的一款...
欧姆龙SysmacNJ系列机器自动化控制器集IPC的先进性和PLC的可靠性为一体.pdf
09-14
欧姆龙Sysmac NJ系列机器自动化控制器是一款融合了工业个人计算机（IPC）的高性能和可编程逻辑控制器（PLC）的稳定性的创新设备。这款控制器是自动化领域的一个重要里程碑，它旨在提供高效、精确和可靠的解决方案，...
欧姆龙_MC运动控制手册
09-25
《欧姆龙_MC运动控制手册》是一份详尽的文档资料，旨在帮助用户深入理解并掌握欧姆龙NJ/NX系列运动控制器的各项功能与应用技巧。通过遵循手册中的指导，用户能够更好地利用PLCopen运动控制规范下的功能块，设计出...
OMRON欧姆龙自动化产品型录（全）.pdf
05-26
欧姆龙的机械自动化控制器系列包括NJ系列产品，这些控制器通常用于机器的控制需求，确保机械运行的精确性和效率。产品样本更新于2020年11月。 2. 机器人统合控制器： 统合控制器是用于机器人系统的控制器，提供整体...
免费SSL证书正在逐渐被淘汰，证书部署自动化的发展趋势即将到来！
石宗昊的博客
09-09 1048
谷歌最新的提议将SSL证书有效期缩短为7天，,提议是否落实，就要看其他的browser是否同意了，目前还没有任何提交讨论的实际行动，但不排除，Chrome进行 “政策更新”，作为 Chrome 根程序的要求，来单方面强制执行此更改。而且，做浏览器的怎么会馋CA赚的钱，除了Mozilla，这家比较特殊以外，其他自己业务早就赚翻天了，做浏览器的都是大公司，不在意这点的，安全考量确实有必要。但实际上，CA/B的信息没有意义，因为整个SSL体系是由B来说了算的，CA说白了就是参与方，象征性的投票。
基于深度学习的自动化产品设计
weixin_42605076的博客
09-07 796
基于深度学习的自动化产品设计通过结合生成模型、强化学习和仿真技术，实现了产品设计流程的高效化和智能化。这种方法为工业、建筑、时尚等多个领域带来了创新的可能性，同时也面临着数据、效率和信任度等方面的挑战。随着深度学习技术的不断发展和成熟，自动化产品设计将在更多领域中发挥重要作用，并促进更智能、更创新的设计实践。
JAMA network open|自动化定量评估胃肠道肿瘤中三级淋巴结构的机器学习模型｜文献精析·24-09-07
罗小罗同学的博客
09-07 1010
这篇文章报道了一种基于机器学习模型的自动化方法，用于在常规组织病理学图像中检测和分类胃肠道癌症中的三级淋巴结构，并验证了其与患者生存预后的关联。在这项多中心诊断/预后研究中，开发了一种基于机器学习的计算工具，用于自动化检测和定量评估常规H&E幻灯片上的TLSs，并证实了其在胃肠癌中的生存率关联。提出的TLSs评分系统可能补充现有的分期系统，并在风险分层中发挥作用。未来的前瞻性验证研究可能会确认这些结果的重复性和广泛适用性。一作&通讯。
sqli-labs靶场自动化利用工具——第10关
转瞬都有的博客
09-12 417
熟悉并掌握sqli-labs靶场的小伙伴可以看过来了，这里是针对每一关sqli-labs靶场的自动化利用工具，本章节将讲述第10关的POC。注意我的Sqli-Labs靶场搭建在我的本机。
sqli-labs靶场自动化利用工具——第13关
转瞬都有的博客
09-12 496
熟悉并掌握sqli-labs靶场的小伙伴可以看过来了，这里是针对每一关sqli-labs靶场的自动化利用工具，本章节将讲述第13关的POC。注意我的Sqli-Labs靶场搭建在我的本机。
模型训练如何实现自动化输出评估报告、模型、特种平台
LDC，公众号【轻松学编程】
09-08 636
模型训练如何实现自动化输出评估报告、模型、特种平台 1、设置模型初始准确率期望值与训练轮数 2、多个分类器多线程训练 3、获取特征并随机划分训练集与测试集 4、保存模型、评估报告、特征与对应的训练数据主键（id）
代理IP中的API接口：解锁高效与自动化的网络访问新方式
2301_80761287的博客
09-06 1263
在代理IP中，API接口特指代理IP提供商提供的接口，它允许用户通过编程的方式访问和使用代理IP服务。代理IP中的API接口作为连接用户与代理IP服务的桥梁，不仅简化了代理IP的使用流程，还提高了代理IP的使用效率和自动化程度。未来随着技术的不断进步和应用的不断拓展，我们有理由相信代理IP的API接口将为用户带来更加便捷、高效、安全的网络访问体验。更换代理IP：在使用代理IP访问目标网站时，如果当前的代理IP被封禁或无法连接，用户可以通过API接口自动更换代理IP。三、代理IP API接口的应用场景。
Ansible中的角色管理：如何组织和重用自动化任务
2401_85639015的博客
09-06 1364
通过使用Ansible角色，用户能够将自动化任务模块化、组织化，并提高代码的可重用性。角色不仅简化了Playbook的编写和维护，还能在团队协作中发挥重要作用。在实践中，遵循最佳实践、完善文档和测试，并利用Ansible Galaxy共享角色，将极大地提升自动化管理的效率。通过系统性地学习和应用Ansible角色，用户将能够构建出更为健壮和灵活的自动化解决方案。
【Vue3】自动化路由配置：Vue3与unplugin-vue-router的完美结合
一位前行者的博客
09-12 1099
unplugin-vue-router是一个构建时插件，它能够根据Vue组件文件自动生成路由配置。这意味着开发者无需手动编写冗长的路由代码，只需遵循约定创建组件文件，路由配置就会自动完成。尽管unplugin-vue-router提供了强大的自动路由功能，但在某些情况下你可能需要添加自定义路由。这可以通过扩展自动生成的routes数组来实现。unplugin-vue-router插件通过构建时的钩子函数，动态生成Vue Router的代理模块和路由配置，简化了路由管理的工作。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

一半不眠次日si记

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值